Copying selected data from one wave into a new wave

Function Test()
    // make some test data
    Make/O/N=10 wData={5,3,4,5,6,2,1,7,0,9}
    // copy to a 'result' wave
    Duplicate/O wData,wFilteredData
    // use conditional to set certain values to NaN
    wFilteredData[] = wFilteredData[p]>5 ? wFilteredData[p] : NaN
    // remove the NaNs
    WaveTransform zapNaNs wFilteredData
    // display the data in a table
    Edit wData,wFilteredData
End

Make/N = (numpnts(tWave)) nWave
nWave = str2num(tWave[p])

function convert(tWave, threshold)
    wave/T twave
    variable threshold
    
    Make/O/N=(numPnts(twave)) nwave
    nwave = str2num(twave[p])
    
    nwave = nwave>threshold ? nwave : NaN
    WaveTransform zapNaNs nwave 
end

Function Test()
    // make some test data
    Make/O/N=10 wData={5,3,4,5,6,2,1,7,0,9}
    // extract values > 5
    Extract wData, wFilteredData, wData > 5
    // display the data in a table
    Edit wData,wFilteredData
End

Function Test()
    // make some test data
    Make/O/N=10 wData={5,3,4,5,6,2,1,7,0,9}
    // extract values > 5
    Extract wData, wFilteredData, wData > 5
    // display the data in a table
    Edit wData,wFilteredData
End

function speed1(w)
    wave w
    variable num = StartmsTimer 
    
    Duplicate/O w nw
    Multithread nw = w > 3 ? w : NaN
    Wavetransform zapNaNs nw
    print Stopmstimer(num)/1e6
end
 
function speed2(w)
    wave w
    variable num = StartmsTimer 
    
    Extract/O w, nw, w > 3
    print Stopmstimer(num)/1e6
end

•make/N=1e7 test = enoise(5)
•speed1(test)
  0.509921
•speed2(test)
  1.08944