New book about programming Igor

#pragma moduleName = NeuNet

static constant N =70
static constant low = 0
static constant high = 1
static constant width = 0.01


static function teach(M)
   
    variable M              // number of parameter sets for training
    variable i
                                                           
    make /o/d/n=(M,2) TrainingParameters       
    wave par = TrainingParameters
           
    // for simplicity, use random parameters in a reasonable range
    // first column: amplitude
    // second column: position
    // then, each row contains a full parameter set
    par[][0]=0.1 + 0.8*(0.5+enoise(0.5))                //[0.1 ; 0.9]
    par[][1]=0.5 + enoise(0.45)                 //[0.05 ; 0.95]
   
    // generate the curves of the training parameters
    make /o/d/n=(M,N) TrainingCurves           
    wave tc = TrainingCurves
    SetScale /I y, low, high, tc            // note the normalization to [0,1]
   
    // store them in rows, not in columns
    for (i=0; i<M; i+=1)       
        tc[i][] = par[i][0]*exp(-(y-par[i][1])^2/width)
    endfor
   
    //now the neural network will learn the
    //connection between parameters and curveshape

    NeuralNetworkTrain nhidden=50, input=tc ,output=par
   
    // the result of this learning process will be saved in two
    // waves M_weights1 and M_weights2
    // these waves contain all the necessary information for running the network

end


static function run()
   
    // ------------
    // make an arbitrary test curve
    make /o/d/n=(N) sampleWave            // number of points has to be the same as
                                                                 // in the training set!
    wave sW = sampleWave
    SetScale /I x,low,high, sW
   
    // neural networks are better with interpolating rather then extrapolating:
    // use smaller ranges than in the training set
    variable randomHeight = 0.2 + 0.6*(0.5+enoise(0.5))     //[0.2 ; 0.8]
    variable randomLoc = 0.5 + enoise(0.25)             //[0.25 ; 0.75]
   
    sW = randomHeight*exp(-(x-randomLoc)^2/width)
    sw += gnoise(0.01)

    // ------------
    // make references to the output waves of the training session
    wave W1 = M_weights1
    wave W2 = M_weights2
   
    // run the neural network
    NeuralNetworkRun input=sW, weightsWave1=W1, weightsWave2=W2
   
    // ------------
    // draw the result
    // the wave W_NNResults is automatically created by the neural network
    wave NNRes = W_NNResults  
   
    make /D /O /N=(N) NNCurve
    wave NNC = NNCurve
    SetScale /I x,low, high, NNC
   
    NNC = NNRes[0]*exp(-(x-NNRes[1])^2/width)
   
end


static function show()

    // call this function only after NeuNet#run() was active at least once
    // so all waves are actually there

    wave sW = sampleWave
    wave NNC = NNCurve
   
    Display sW
    AppendToGraph NNC
   
end