For Loop to remove errors from multiple files

ChrLie wrote:

actually, regardless, whether the task is to replace NaN's by zero's or to set negative values to NaN's:
I was just curious which 1-liner runs faster:

w = (NumType(w)==2) ? 0 : w

(assuming the task is NaN's to 0) runs about twice as fast compared to

w = SelectNumber(numtype(w) == 2, w,0)  

ChrLie wrote:

I'm not entirely sure if I understood correctly, but it could be that you are trying to remove NaN's from your data?
If so, and your "files" were actually waves then you could execute the following function:

function RemoveNaNs(list)
    string list
   
    variable i
    string nextwave = ""
   
    do
        nextwave = stringfromlist(i, list)
        if (strlen(nextwave) == 0)
            break
        endif
       
        wave w = $nextwave
        w = SelectNumber(numtype(w) == 2, w,0)         
    i += 1
    while(1)
end

say, if your waves of interest were named w1, w2, w3 you would execute:

RemoveNaNs("w1;w2;w3")

from the command line. In case of more waves you can use the WaveList - command to get a string of all the waves.

"NumType" in the above code identifies NaN's and SelectNumber can be used here a bit like an if-statement.

I hope this points into the right direction!
Cheers

C

chozo wrote:

Ok, first things first: You may want to put future code in <igor> </igor> tags, to make the code better readable by highlighting.

So now lets look at the first step of iterating through your files. You solution may work, but is very hardcoded to the specific case with the exact wave names (better call them 'waves', because 'files' make you think of stuff saved on the hard drive instead of loaded data in Igor) and count of your waves. How about a way to process the waves on demand for this simple task? I would do this by utilizing the execute command button in the data browser. Like so:

Function remove_errors(my_wave)
wave my_wave
//do stuff with my_wave here
End

Now you can select all the waves you need to process and hit the 'Exec. Cmd.' button. Write 'remove_errors(%s)' in there and hit Ok (%s is a placeholder where the actual wave name will be pasted). All waves you have selected will be processed with you function. No need for loops and hardcoding wave names (leave that until you have really complicated tasks, and even then hardcoding stuff can always be avoided).

Now to the actual task of inserting NaNs. This is quickly done in one line. Just use 'my_wave = my_wave[p]<0 ? NaN : my_wave[p]', to replace all values smaller than zero with NaN. This expression is a shortcut for an if-else statement. You may want to read more about it in the help browser, but here is what it basically does: The equation automatically goes through all points of the wave; no need for a loop. The current point is expressed by the counter p. First cones a question: Is the current point <0? The answer decides if the value before (here NaN) or after the ':' is picked. The full function will look like this then:

Function remove_errors(my_wave)
wave my_wave
my_wave = my_wave[p]<0 ? NaN : my_wave[p]
End

thunderstruck71 wrote:

function remove_wave_errors(wave1)
wave wave1
variable i,j=numpnts(wave1)
    for (i=0;i<j;i+=1)
        if(wave1[i]<0)
        wave1[i]=NAN
        endif
    endfor
end

aclight wrote:

thunderstruck71 wrote:

function remove_wave_errors(wave1)
wave wave1
variable i,j=numpnts(wave1)
    for (i=0;i<j;i+=1)
        if(wave1[i]<0)
        wave1[i]=NAN
        endif
    endfor
end

This will work, but as chozo pointed out before, this will be much faster:

function remove_wave_errors(wave1)
    wave wave1
    wave1 = wave1[p] < 0 ? NaN : wave1[p]
end

If you're going to be doing much coding, it's best to get familiar with wave assignment statements sooner rather than later, because they are faster and will make coding a lot easier. For more information, execute the following command on Igor's command line:

DisplayHelpTopic "Waveform Arithmetic and Assignment"

thunderstruck71 wrote:

Thanks. One of the reasons I needed a function like the on I've got working is because I'll potentially be doing it over and over with lots of data, so although highlighting the files and using the Exec Cmd button is quick, long term being able to execute the function will knock some time off the task.

thunderstruck71 wrote:

...
Thanks. One of the reasons I needed a function like the on I've got working is because I'll potentially be doing it over and over with lots of data, so although highlighting the files and using the Exec Cmd button is quick, long term being able to execute the function will knock some time off the task.