Function to get an Axis Label

if (stringmatch(oneLine, "\tLabel " + axisname + "*"))

Function/S GetAxisLabel(gname, axisname)
    String gname, axisname
 
    String grecreation = WinRecreation(gname, 0)
    String oneLine
    String labelStr = ""
    String part1, part2
 
    Variable i=0
    do
        oneLine = StringFromList(i, grecreation, "\r")
        String regexp = "^\\tLabel "+axisname+" \\\"(.*)\\\""
        SplitString/E=regexp oneLine, labelStr
        if (strlen(labelStr) > 0)
            break;
        endif
        i += 1
    while(strlen(oneLine) > 0)
 
    return labelStr
end

#include <Axis Utilities>

/ Returns the text of the axis label.
// If optional parameter SuppressEscaping is non-zero, extra backslashes ("\\" is required
// to include a single backslash in a quoted string) are removed
// so that the result is a string suitable to be passed directly to the Label operation.
Function/S AxisLabelText(graphName, axisName, [SuppressEscaping])
    String graphName, axisName
    Variable SuppressEscaping
   
    if (ParamIsDefault(SuppressEscaping))
        SuppressEscaping = 0
    endif
   
    String axisLabel=""
    String info= WinRecreation(graphName,0)
    Variable start= strsearch(info, "Label "+axisName, 0)
    if( start >= 0 )
        start = strsearch(info, "\"", start)+1
        Variable theEnd= strsearch(info, "\"", start)-1
        axisLabel= info[start,theEnd]
    endif
    if (SuppressEscaping)
        start = 0
        do
            start = strsearch(axisLabel, "\\\\", start) // search for double backslash
            if (start >= 0)
                string newLabel = axisLabel[0,start-1]
                newLabel += axisLabel[start+1, strlen(axisLabel)-1]
                axisLabel = newLabel
            else
                break
            endif
        while(1)
    endif
    return axisLabel
End

•make junk=x;display junk
•Label bottom "one line\ranother line"
•print AxisLabelText("graph0", "bottom")
  one line\ranother line
•Label left "Left Axis Label"
•print AxisLabelText("graph0", "bottom")
  one line\ranother line
•print AxisLabelText("graph0", "left")
  Left Axis Label

Function/S ReturnLabelForAxis(GraphName, AxisName)
    string GraphName, AxisName
    //string function, returns label for graph + axis specified
    //want to get label for axis here, example of expected labels :
    //Label left "Intensity [arb]"
    //Label bottom "Q [A\\S-1\\M]"
    string OldClipb = GetScrapText()
    PutScrapText WinRecreation(GraphName, 0)
    Grep /E={AxisName,0}/Q/LIST "Clipboard"
    string MyAxisLabel = S_value[strsearch(S_value, "\"", 0)+1, strsearch(S_value, "\"", strlen(S_value)-1,1 )-1]
    MyAxisLabel = ReplaceString("\\\\", MyAxisLabel, "\\")
    PutScrapText OldClipb
    return MyAxisLabel
end