Read some specific line of the data file

// ReadThisLine(pathName, filePath, whichLine, data)
// Reads specified line number from file. Text is returned via data parameter.
// pathName is the name of an Igor symbolic path (see "Symbolic Paths" help topic).
// filePath is a file name, partial path or full path.
// If filePath is a full path then pathName can be "".
// The function result is 0 if the line was found, non-zero otherwise.
// Because the data is returned through a pass-by-reference parameter,
// this function can not be called from the command line. It must be
// called from another function.
// Example:
//  String data
//  Variable err = ReadThisLine("Igor", "License Agreement.txt", 2, data)
//  Print data
Function ReadThisLine(pathName, filePath, whichLine, data)
    String pathName     // Name of Igor symbolic path
    String filePath         // File name, partial path or full path
    Variable whichLine      // 0-based line number
    String& data            // Output
   
    data = ""
   
    Variable refNum

    Open /R /P=$pathName refNum as filePath
   
    Variable lineNumber = 0
    do
        String tmpData
        FReadLine refNum, tmpData
        if (strlen(tmpData) == 0)
            return -1           // Error - end of file
        endif
        if (lineNumber == whichLine)
            data = tmpData
            return 0            // Success
        endif
        lineNumber += 1
    while(1)
End

Function DemoReadThisLine()
    String data
    Variable err = ReadThisLine("Igor", "License Agreement.txt", 2, data)
    Print err, data
End

        if (strlen(tmpData) == 0)
            close refNum
            return -1           // Error - end of file
        endif
        if (lineNumber == whichLine)
            data = tmpData
            close refNum
            return 0            // Success
        endif