HDF5SaveGroup

Share icon

Can someone elaborate be a detailed syntax to make a single hdf file using three simple waves a, b, and c in igor pro?  The output hdf5 name I wouldlike to obtain is 'output.h5'.   I have seen a function HDF5SaveGroup to do this. However, I am not sure of the detailed syntax of this function. Can someone give me a simple example that I can directly copy and run in Igor pro? I am using Igor 7.

Thanks much in advance.  

 

Here is an slightly modified version of the DemoSaveWave example function from the help for HDF5SaveData:

// Example: Make/O/N=5 wave0=p, wave1=p+1, wave2=p+2
// DemoSaveWaves(wave0, wave1, wave2)
Function DemoSaveWaves(w0, w1, w2)
    Wave w0, w1, w2
 
    Variable result = 0 // 0 means no error
    
    Variable fileID
    HDF5CreateFile/P=HDF5Data /O /Z fileID as "Test.h5"
    if (V_flag != 0)
        Print "HDF5CreateFile failed"
        return -1
    endif
    
    HDF5SaveData /O /Z w0, fileID
    if (V_flag != 0)
        Print "HDF5SaveData failed on w0"
        result = -1
    endif
    
    HDF5SaveData /O /Z w1, fileID
    if (V_flag != 0)
        Print "HDF5SaveData failed on w1"
        result = -1
    endif
    
    HDF5SaveData /O /Z w2, fileID
    if (V_flag != 0)
        Print "HDF5SaveData failed on w2"
        result = -1
    endif
 
    HDF5CloseFile fileID
    
    return result
End

To see the rest of the help for HDF5SaveData, execute:

DisplayHelpTopic "HDF5SaveData"

Use HDF5SaveGroup to save all of the contents of a data folder. To see the help for HDF5SaveGroup, execute:

DisplayHelpTopic "HDF5SaveGroup"

If you are not familiar with data folders, execute:

DisplayHelpTopic "Data Folders"

If you have not already done the first half of the Igor guided tour, execute:

DisplayHelpTopic "Getting Started"

If you have not already done the HDF5 guided tour, execute:

DisplayHelpTopic "HDF5 Guided Tour"

 

 

 

June 8, 2023 at 07:52 pm - Permalink