Name of wave and wave scalling

String xName = StringFromList(0, S_waveNames);  // S_waveNames is set by LoadWave
String yName = StringFromList(1, S_waveNames);  // S_waveNames is set by LoadWave
Wave xw = $xName  // Create wave reference for X wave
Wave yw = $yName  // Create wave reference for Y wave
Variable x0 = xw[0]
Variable dx = xw[1] - xw[0]
SetScale/P x x0, dx, "units", yw  // Change "units" to whatever is appropriate for your data
KillWaves xw  // We no longer need the X wave

SetDataFolder root:ARGUS:Load_Files 
FolderName=FolderName+stFileName+stFileName1
Open/R/P=$FolderName RefNum
FReadLine/N=45 RefNum, NameCoreLevel
Close RefNum
end

#pragma rtGlobals=3     // Use modern global access method and strict wave access.
 
// Add an item to Igor's Load Waves submenu (Data menu)
Menu "Load Waves"
    "Load Sergey Text File...", LoadSergeyTextFile("", "")
    "Load All Sergey Text Files In Folder...", LoadAllSergeyTextFiles("")
End
 
Function GetWaveNames(refNum, xName, yName)
    Variable refNum
    String &xName               // Output
    String &yName               // Output
    
    xName = "tempXWave"             // X wave will be killed after scaling is set on y wave
    
    String text, format
    
    // Read file name from first line of file
    FReadLine refNum, text              // Read first line
    format = "# Transition %[^/]"       // Skips "# Transition " reads text until slash"
    sscanf text, format, yName          // Extract y wave name
    
    // Clean up y wave name so it is a standard Igor name as liberal names are harder to program with
    yName = CleanupName(yName, 0)
        
    return 0
End
 
//  LoadSergeyTextFile(pathName, fileName)
//  Loads y wave into current data folder.
//  NOTE: If the wave already exists in the current data folder, it is overwritten.
//  pathName is the name of an Igor symbolic path or "".
//  fileName is one of the following:
//      The name of a file in the folder designated by pathName.
//      A partial path from the folder designated by pathName to the file to be loaded.
//      A full path to the file to be loaded.
//      "" to get an Open File dialog.
//  The required file name extension is ".txt".
Function LoadSergeyTextFile(pathName, fileName)
    String pathName         // Igor symbolic path name or "" for dialog.
    String fileName             // file name, partial path and file name, or full path or "" for dialog.
    
    Variable err
 
    // This puts up a dialog if the pathName and fileName do not specify a file.
    String message = "Select a Sergey text file"
    Variable refNum
    String fileFilters = "Sergey Text Files (*.txt):.txt;"
    Open /R /Z=2 /P=$pathName /F=fileFilters /M=message refNum as fileName
    
    // Save outputs from Open in a safe place.
    err = V_Flag
    String fullPath = S_fileName
 
    if (err != 0)
        return err          // -1 means user canceled.
    endif
    
    String xName, yName
    err = GetWaveNames(refNum, xName, yName)
    // Print xName, yName   // For debugging only
 
    Close refNum
 
    if (err != 0)
        return err          // Error in GetWaveNames 
    endif
    
    String columnInfoStr = ""
    columnInfoStr += "N='" + xName + "';"
    columnInfoStr += "N='" + yName + "';"
    
    // Load the data using Load General Text (/G)
    LoadWave /G /A /O /D /B=columnInfoStr /Q fullPath
 
    Wave xWave = $xName
    Wave yWave = $yName
    
    // Set X scaling
    Variable x0 = xWave[0]
    Variable dx = xWave[1] - xWave[0]
    SetScale/P x x0, dx, "nm", yWave    // Change "nm" to whatever is appropriate for your data
    
    KillWaves/Z xWave                   // X wave is no longer needed
    
    Printf "Loaded %s\r", yName
 
    return 0            // Zero signifies no error. 
End
 
//  LoadAllSergeyTextFiles(pathName)
//  Loads all .txt into the current data folder.
//  NOTE: If a wave already exists, it is overwritten.
//  See LoadSergeyTextFile documentation above for details.
Function LoadAllSergeyTextFiles(pathName)
    String pathName // Name of an Igor symbolic folder created by Misc->NewPath
    
    if (strlen(pathName) == 0)
        String message = "Select a directory containing only Sergey data files"
        NewPath/O/M=message SergeyDataPath      // This displays a dialog in which you can select a folder
        if (V_flag != 0)
            return V_flag                           // -1 means user canceled
        endif
        pathName = "SergeyDataPath"
    endif
    
    Variable err = 0
 
    String fileName
    Variable i = 0
    do
        fileName = IndexedFile($pathName, i, ".txt")
        if (strlen(fileName) == 0)
            break                                       // No more files
        endif
    
        err = LoadSergeyTextFile(pathName, fileName)
        if (err != 0)
            return err
        endif
    
        i += 1
    while(1)
    
    return 0
End