arrow plot of wind data

hrodstein wrote:

Wind barb plots are not well explained in the Igor documentation. Here is an explanation of how to do it.

You need to create an XY plot in markers mode.

Then you turn on barb mode (really arrow mode) using "ModifyGraph arrowMarker", passing to it a wave that specifies the length, angle and number of barbs for each point.

If you want to color-code the wind barbs, you turn color as f(z) mode using "ModifyGraph zColor", passing to it a wave that specifies the color for each point.

Here is an example:

// Make XY data
Make/O xData = {1, 2, 3}, yData = {1, 2, 3}
Display yData vs xData                // Make graph
ModifyGraph mode(yData) = 3        // Marker mode

// Make a barb data wave to control the length, angle and number of barbs for each point.
// To control the number of barbs, column 2 must have a column label of WindBarb
Make/O/N=(3,3) barbData    // Controls barb length, angle and number of barbs
SetDimLabel 1, 2, WindBarb, barbData    // Set column label to WindBarb
Edit /W=(439,47,820,240) barbData

// Put some data in barbData
barbData[0][0]= {20,25,30}    // Column 0: Barb lengths in points
barbData[0][1]= {0.523599,0.785398,1.0472}        // Column 1: Barb angle in radians
barbData[0][2]= {10,20,30}    // Column 2: Wind speed from 0 (no barbs) to 40 (4 barbs)

// Set trace to arrow mode to turn barbs on
ModifyGraph arrowMarker(yData) = {barbData, 1, 10, 1, 1}

// Make an RGB color wave
Make/O/N=(3,3) barbColor
Edit /W=(440,272,820,439) barbColor

// Store some colors in the color wave
barbColor[0][0]= {65535,0,0}        // Red
barbColor[0][1]= {0,65535,0}        // Green
barbColor[0][2]= {0,0,65535}        // Blue

// Turn on color as f(z) mode
ModifyGraph zColor(yData)={barbColor,*,*,directRGB,0}

Execute the commands one-by-one to get an understanding of how it works.

You can eliminate the barbColor wave by using a color table lookup instead of a color wave. The various color as f(z) modes are explained under
"Setting Trace Properties from an Auxiliary (Z) Wave":

DisplayHelpTopic "Setting Trace Properties from an Auxiliary (Z) Wave"

You will need a solid understanding of Igor. If you have not already done it or you have forgotten, do the first half of the Igor Getting started documentation (Help->Getting Started).

Quote:

The script you list is too complicated in my application. I only want to make a simple vector plot as shown in the attachment.