Help wth linear combination analysis

julien wrote:

Since you know Sa and Sb you can define functions based on them

function Sa_function(x)
variable x
wave Sa=root:Sa //that is the wave where you have Sa
return Sa(x)
end

same thing for Sb.
And then you use them to define your fit function. You can use "new fit function" and it will generate the following code in your procedure window:

Function New_fit_func(w,x) : FitFunc
    Wave w
    Variable x
 
    //CurveFitDialog/ These comments were created by the Curve Fitting dialog. Altering them will
    //CurveFitDialog/ make the function less convenient to work with in the Curve Fitting dialog.
    //CurveFitDialog/ Equation:
    //CurveFitDialog/ f(x) = k*Sa(x)+(1-k)*Sb(x)
    //CurveFitDialog/ End of Equation
    //CurveFitDialog/ Independent Variables 1
    //CurveFitDialog/ x
    //CurveFitDialog/ Coefficients 1
    //CurveFitDialog/ w[0] = k
 
    return w[0]*Sa_function(x)+(1-w[0])*Sb_function(x)
End

You have only one fit parameter (w[0]).
That should do it.

Julien

function Sa_function(x)
variable x
wave Sa=root:Sa 
return Sa(x)
end
 
function Sb_function(x)
variable x
wave Sb=root:Sb 
return Sb(x)
end
 
 
Function LinearCombo(w,x) : FitFunc
    Wave w
    Variable x
 
    //CurveFitDialog/ These comments were created by the Curve Fitting dialog. Altering them will
    //CurveFitDialog/ make the function less convenient to work with in the Curve Fitting dialog.
    //CurveFitDialog/ Equation:
    //CurveFitDialog/ f(x) = k*Sa(x)+(1-k)*Sb(x)
    //CurveFitDialog/ 
    //CurveFitDialog/ End of Equation
    //CurveFitDialog/ Independent Variables 1
    //CurveFitDialog/ x
    //CurveFitDialog/ Coefficients 1
    //CurveFitDialog/ w[0] = k
 
    return w[0]*Sa(x)+(1-w[0])*Sb(x)
    
End

jtigor wrote:

You should post a copy of your code, so we can help debug it.

Please enclose the code between igor code tags so it displays correctly. These are "igor" and "/igor" surrounded by <>.

LJ0630 wrote:

    return w[0]*Sa(x)+(1-w[0])*Sb(x)
    

    return w[0]*Sa_function(x)+(1-w[0])*Sb_function(x)
    

julien wrote:

At the end of your code defining the fit function you have:

LJ0630 wrote:

    return w[0]*Sa(x)+(1-w[0])*Sb(x)
    

These are not the names of the defined functions.

You should have:

    return w[0]*Sa_function(x)+(1-w[0])*Sb_function(x)
    

Sa and Sb are the waves' names, not the functions' names.

julien wrote:

I assume then that you have a wave to give the x_scaling and that you display your data (picture you gave) doing:

display wave_y vs wave_x

If your wave giving the x axis is monotonic (I suspect it is since you talk about wavelength) you might succeed using the following to define your functions

function Sa_function(x)
variable x
wave Sa=root:Sa 
wave Sa_xwave=root:Sa_xwave //this is the wave where you store the x-scaling
Findlevel  Sa_xwave, x
return Sa(V_levelX)
end

That said, I would strongly suggest that you resample your data using interpolation, in order to have evenly spaced data points. That is what I usually do to deal with nm/eV.
That will make things much easier.

johnweeks wrote:

FindLevel does a linear search through a wave. As long as the X values are monotonic, this should be faster:

Function getInterpY(Variable xx)
 
    WAVE Sa_X, Sa
    Variable pointWithFraction = BinarySearchInterp(Sa_X, xx)
    return Sa[pointWithFraction]
end

John Weeks
WaveMetrics, Inc.
support@wavemetrics.com