XPS data from Phy Multipak

function FileLoader(Key, base, skip)       
    string key                  // keyword after which a spectrum begins
    string base                 // base name for spectra       
    variable skip               // line to skip after keyword
   
    variable refNum
    Open/D/R/F="*.csv"/M="Select SPE-CSV File" refNum
    string filePath = S_fileName
    Open/R refNum as filepath
   
    Make/FREE/O/T/N=0 w
   
    variable i =0      
    do
        string line
        FReadLine refNum, line
       
        if( strlen(line) == 0 )                         // end of file
            break                                       // exit do-while loop
        endif
       
        line = RemoveEnding(line, "\r")
               
        InsertPoints i, 1, w
       
        w[i] = line
        i+=1           
           
    while( 1 )
    Close refNum
   
   
    i=0
    variable  filenum = 0
       
    for(i=0; i<numpnts(w); i+=1)
       
        if(cmpstr(w[i], key) == 0)
            i+=skip
            Make/O/N=(numpnts(w)) $base + num2str(filenum)
            wave ww = $base + num2str(filenum)
            ww = NaN
        endif
       
        string ThisLine = w[i]
        variable strStart = strsearch(ThisLine, ",", 0)+1
        ww[i] = str2num(ThisLine[strStart, inf])
           
        if(strlen(w[i]) == 0)
            filenum +=1
            WaveTransform zapNaNs ww
        endif  
    endfor
end

FileLoader("Area5", "data", 4)

Function ImportXPS()

    //get file
    variable refNum
    Open/D/R/F="*.csv"/M="Select SPE-CSV File" refNum
    string filePath = S_fileName
    Open/R refNum as filepath
 
    Make/O/T/N=0 w
    Make/O/N=0 SpectraStart
 
    variable i,j =0    
    do
        string line
        FReadLine refNum, line
 
        if( strlen(line) == 0 )                         // end of file
            break                                       // exit do-while loop
        endif
 
        line = RemoveEnding(line, "\r")
 
        InsertPoints i, 1, w
        //check to see if it is the start of a new spectra and note the line number
        if(stringmatch(line,"*Area*")==1)
            InsertPoints j, 1, SpectraStart
            SpectraStart[j] = i
            j +=1
        endif
        w[i] = line
        i+=1           
 
    while( 1 )
    Close refNum
   
    //make individual spectra
    variable SpectraIndex,index,offset
   
   
    For(SpectraIndex=0;SpectraIndex<numpnts(SpectraStart);SpectraIndex +=1)
   
        //Read in data
        Make/O/N=(0,2) DataIn
        offset = spectrastart[spectraindex]+4
        index=0
        Do
            if(strlen(w[(offset+index)])==0)
                break
            endif
            insertpoints index,1, Datain
            DataIn[index][0] = str2num(stringfromlist(0,w[(offset+index)],","))
            DataIn[index][1] = str2num(stringfromlist(1,w[(offset+index)],","))
            index +=1
//          print index
        while(1)
        //Make Spectra with Name
        Make/O/N=(dimsize(datain,0)) $w[spectraStart[spectraIndex]+2]
        Wave DataOut = $w[spectraStart[spectraIndex]+2]
        Dataout[]=Datain[p][1]
        //Set wave Scaling
        SetScale/I x, datain[0][0], datain[dimsize(datain,0)-1],  dataout
    EndFor
End

#pragma rtGlobals=3     // Use modern global access method and strict wave access.

Function ImportXPS_bin()
//Read .spe files from Phy Multipak XPS
    Variable vFileRef
    Variable vIndex = 0
    Variable vLoc
    Variable vNumSpectra
    Variable vPointsInSpectrum
    Variable vReadVal
    String sFilePath
    String sLine
    String sSpectrumWaveName
   
//Get name/path to file to open
    Open/D/R/F="Multipak Files (*.spe):.spe;"/M="Select SPE-CSV File" vFileRef
    sFilePath = S_fileName
    if( StrLen( S_fileName ) == 0 )
        return -1   //user cancelled file selection
    endif
   
    Open/R vFileRef as sFilePath
   
//Text Header
    Make/O/T/N=0 wHeader
 
//Read the File Header one line at at time; read terminates on LF/CR combinations, per the help file
//In this case the terminator is LF
    Do
        FReadLine vFileRef, sLine
        FStatus vFileRef
        if( V_filePos > V_logEOF )
            print "Attempting to read past end of file"
            return -1   //attempting to read past end of file
        endif
 
        sLine = RemoveEnding( sLine, "\r" )
 
        InsertPoints vIndex, 1, wHeader
        wHeader[vIndex] = sLine    
    //get number of spectra in file from header containing
        if( stringmatch( sLine,"NoSpectralReg:*" ) == 1 )
            vLoc = strsearch( sLine, ":", 0 )
            vNumSpectra = str2num( sLine[vLoc + 1, inf ] )
            print "Number of Spectra in file: ", vNumSpectra
        endif

        //End of header is given by "EOFH" string; quit when this is found
        if( stringmatch( sLine,"EOFH" ) == 1 )
            print "End of header found"
            FStatus vFileRef
            print "Current file position: ", V_filePos
            break
        endif
        vIndex += 1        
    While( 1 )

//Binary headers
    //brief (16 bytes) header; seems to be 4 4 byte unsigned integer values, second valued may give number of spectra
    //otherwise the purpose of this part is not clear
    Make/O/N=4 wBinHeader_1
    //each spectrum gets 24 unsigned 4 byte integers; fifth value is number of points in corresponding spectrum
    Make/O/N=( 24 * vNumSpectra ) wSpectraHeader     
    //read the binary headers
    FBinRead/B=0/F=3/U vFileRef, wBinHeader_1
    FStatus vFileRef
    print "Current file position after bin header read: ", V_filePos
    FBinRead/B=0/F=3/U vFileRef, wSpectraHeader
    FStatus vFileRef
    print "Current file position after spectra header read: ", V_filePos

//Mystery value at end of each spectrum...
    //4 byte floating value at end of spectrum; don't know what it is for; read it anyway
    Make/O/N=( vNumSpectra ) wMysteryBytes 
   
//load each spectrum into a separate wave
    for( vIndex = 0; vIndex < vNumSpectra; vIndex += 1 )
    //name for spectrum wave; name is "wSpectrum_" plus number corresponding to position in file
        sprintf sSpectrumWaveName, "wSpectrum_%02d", vIndex + 1
        print sSpectrumWaveName
    //get number of points to load for the spectrum
        vPointsInSpectrum = wSpectraHeader[ 5 + vIndex * 24 ]
    //make the wave for the current spectrum
        Make/O/N=( vPointsInSpectrum ) $sSpectrumWaveName
        Wave wSpectrum = $sSpectrumWaveName
    //read spectrum; format is 64 bit float    
        FBinRead/B=0/F=5 vFileRef, wSpectrum
//deal with 4 bytes at end of a spectrum; either read into wave just for this or skip
//code for skipping is commented out
    //read 4 bytes at end of spectrum, interpret at 32 bit float
        FBinRead/B=0/F=4 vFileRef, vReadVal
        wMysteryBytes[ vIndex ] = vReadVal
//  //next 4 bytes have unknown purpose, skip for now
//      FStatus vFileRef
//      FSetPos vFileRef, V_filePos + 4
    endfor
   
    Close vFileRef
End

Function MyLoadSPE()

    LoadPHISPE()
    setscale/I ...
    killwaves/Z ....
    return 0
end