Prettify code

#pragma TextEncoding="UTF-8"
#pragma rtGlobals=3
#pragma IgorVersion=8
#pragma IndependentModule=Prettify
#pragma version=1.5

#if (NumberByKey("BUILD", IgorInfo(0)) < 36043)
#define -- error please update to a later nightly build
#endif

// https://www.wavemetrics.com/user/tony

// To prettify selected code: cmd-5 (Mac), ctrl-5 (Windows)

Constant kMinWordLengthDefault = 3

Menu "Edit"
    "Prettify Clipboard Code", /Q, PutScrapText Prettify#PrettifyCode(GetScrapText())
    "Prettify Selected Code/5", /Q, PrettifySelection()
End

Function PrettifySelection()
   
    String strScrap = GetScrapText()
    PutScrapText ""
    DoIgorMenu "Edit" "Copy"
    PutScrapText PrettifyCode(GetScrapText())
    DoIgorMenu "Edit" "Paste"
    PutScrapText strScrap // leave clipboard state unchanged
End

// Returns a string with known function and operation names case-corrected.
// Commented and quoted text is ignored. Trailing whitespace is eradicated.
// Blocks of code representing proc pictures are ignored, provided that the
// selection starts before the Picture keyword.
Function /S PrettifyCode(String strText, [string eol, string ignoreList, string customList, variable minWordLength])
   
    if(strlen(strText)==0)
        return ""
    endif
   
    if(ParamIsDefault(eol))
        eol = "\r"
    endif
   
    if(ParamIsDefault(ignoreList))
        ignoreList = ""
    endif

    if(ParamIsDefault(customList))
        customList = ""
    endif
   
    if(ParamIsDefault(minWordLength))
        minWordLength = kMinWordLengthDefault
    endif
   
    String strList = FunctionList("*",";","") + OperationList("*",";","")
    String keyWords="End;EndMacro;EndStructure;Function;Macro;Picture;Proc;Structure;Window;"
    // keyWords+="#if;#endif;#ifdef;#ifndef;#include;#pragma;#undef;" // can't match these as whole words
    keyWords+="Constant;DoPrompt;GalleryGlobal;hide;IgorVersion;IndependentModule;Menu;ModuleName;MultiThread;"
    keyWords+="Override;Popup;ProcGlobal;Prompt;root;rtGlobals;static;Strconstant;Submenu;TextEncoding;ThreadSafe;version;"
    String subtypes="ButtonControl;CameraWindow;CDFFunc;CheckboxControl;CursorStyle;DrawUserShape;FitFunc;"
    subtypes+="GizmoPlot;Graph;GraphMarquee;GraphStyle;GridStyle;Layout;LayoutMarquee;LayoutStyle;ListBoxControl;"
    subtypes+="Panel;PopupMenuControl;SetVariableControl;SliderControl;TabControl;Table;TableStyle;"
    String objectRefs="DFREF;FUNCREF;NVAR;STRUCT;SVAR;WAVE;"
    String flowControl="AbortOnRTE;AbortOnValue;break;case;catch;continue;default;do;else;elseif;endfor;endif;"
    flowControl+="endswitch;endtry;for;if;return;strswitch;switch;try;while;"
    strList+=keyWords+subtypes+objectRefs+flowControl

    // remove words in ignoreList, substitute or add words in customList
    strList = RemoveFromList(ignoreList, strList, ";", 0)
    strList = RemoveFromList(customList, strList, ";", 0) + customList
    WAVE /T wList = ListToTextWave(strList, ";")
    // remove words with fewer than kMinWordLength characters
    Variable i
    for(i=numpnts(wList)-1; i>=0; i-=1)
        if(strlen(wList[i]) < minWordLength)
            DeletePoints i, 1, wList
        endif
    endfor
   
    Variable endsWithReturn = (cmpstr(strText[strlen(strText)-1], eol) == 0)
    WAVE /T wText = ListToTextWave(strText, eol)
    Variable lastLine = numpnts(wText) - 1
    wText += SelectString(p<(lastLine) || endsWithReturn, "", eol)

    Make/FREE/N=(DimSize(wText, 0)) wIgnore

    CreateMask(wText, wIgnore, "Picture", "End")
    CreateMask(wText, wIgnore, "Window", "EndMacro")

    Multithread wText = PrettifyLine(wText, wList, wIgnore, eol)
    wfprintf strText, "%s", wText
    return strText
End

/// Creates a mask wave in wIgnore
///
/// wIgnore will have 1 if the line should be ignored, 0 otherwise
Function CreateMask(WAVE/T wText, WAVE wIgnore, string beginStr, string endStr)

    string beginRegExp = "(?i)^\s*\\Q" + beginStr + "\\E\b"
    string endRegExp = "(?i)^\s*\\Q" + endStr + "\\E\b"
    Variable vLine, i, numLines

    numLines = DimSize(wText, 0)

    // create a mask for lines that should not be altered
    Grep /Q/INDX/E=beginRegExp wText
    WAVE W_Index
   
    for (i=0;i<numpnts(W_Index);i+=1)
        vLine=w_Index[i]+1 // the line that starts the Picture binary as ASCII
        if(vLine>numLines)
            break
        endif
        do
            wIgnore[vLine]=1
            vLine+=1
        while(vLine<numLines && GrepString(wText[vLine],endRegExp)==0)
    endfor
End

// strLine should include \r if one was present in input text
threadsafe Function /S PrettifyLine(String strLine, WAVE /T wordList, Variable ignore, string eol)

    string nonWhitespace, whitespace

    if(ignore)
        return strLine
    endif
   
    WAVE /B mask = QuoteAndCommentMask(strLine)
    String strCode="", word=""
    int bytes = -1, len=numpnts(mask)
    // find position of last unmasked character in line
    Duplicate /free mask rmask
    Reverse mask /D=rmask
    FindValue /I=0 rmask // find first 0 in reversed mask wave
    if(v_value==-1) // entire line is masked
        strCode=""
    else
        strCode=strLine[0,len-1-v_value]
    endif
    // strCode should contain any code but no commented text

    do // loop through words in line
        SplitString /E="([[:alnum:]]+)(.*)" strCode, word, strCode
        FindValue /TEXT=word/TXOP=4/Z wordList
        if(V_value > -1)
            strLine = ReplaceWord(word, strLine, wordList[V_value], mask)
        endif
    while(strlen(strCode))

    SplitString/E=("^(?U)(.*)([[:space:]]*)$") strLine, nonWhitespace, whitespace
   
    return nonWhitespace + eol
End

ThreadSafe Function /WAVE QuoteAndCommentMask(String strLine)
       
    Variable startByte, endByte, len
    len=strlen(strLine)
    Make /B/free/N=(len) mask=0
    startByte=0
    do
        startByte=strsearch(strLine, "\"", startByte)
        if(startByte==-1) // no more quoted text before end of strLine
            break
        endif
        endByte=startByte
        do
            endByte=strsearch(strLine, "\"", endByte+1)
            if(endByte==-1)
                endByte=len-1
                break
            endif
            // endByte is possible end of quote
            // remove escaped backslashes!
            strLine[startByte,endByte]=ReplaceString("\\\\", strLine[startByte,endByte], "  ")
        while(cmpstr(strLine[endByte-1], "\\")==0) // ignore escaped quotes
        // found end of quote
        mask[startByte, endByte]=1
        startByte=endByte+1
    while(1) // look for next quoted text
    // quoted text is now masked
    startByte=0
    do
        startByte=strsearch(strLine, "//", startByte)
        if(startByte==-1) // no comment before end of strLine, we're done
            return mask
        endif
        if(mask[startByte]==1)
            startByte+=1
            continue
        endif
        // startByte is start of comment
        mask[startByte,len-1]=1
        return mask
    while(1)
End

// Wrapper for ReplaceString, replaces whole words
// characters inStr[i] where mask[i]==1 are ignored
ThreadSafe Function /S ReplaceWord(replaceThisWord, inStr, withThisWord, mask)
    String replaceThisWord, inStr, withThisWord
    WAVE /B mask
   
    String substring=""
    Variable startByte=0, endByte=0

    do // loop through matches
        startByte = strsearch(inStr, replaceThisWord, endByte, 2)
        if(startByte == -1)
            return inStr
        endif
        endByte = startByte + strlen(replaceThisWord)
        if(mask[startbyte]==1)
            continue
        endif
        substring = inStr[startByte-1, endByte+1] // will be clipped to 0, strlen(inStr)
        // check that match is whole word
        if(GrepString(substring, "(?i)\\b" + replaceThisWord + "\\b"))
            substring = ReplaceString(replaceThisWord, substring, withThisWord)
        endif
        inStr = inStr[0, startByte-2] + substring + inStr[endByte+2, Inf]
    while(1)
End

Function/S LoadFile(string fullPath)

    variable fnum
    string data

    Open/R/Z=1 fnum as fullPath

    FStatus fnum
    data = ""
    data = PadString(data, V_logEOF, 0x20)
    FBinRead fnum, data
    Close fnum
   
    return data
End

Function WriteFile(string fullPath, string contents)
   
    variable fnum
   
    Open/Z fnum as fullPath
    FBinWrite fnum, contents
    Close fnum
End

Function/S GetIgorStylePath(string path)

    return ParseFilepath(5, path, ":", 0, 0)
End

Function PrettifyFolder(string folder, [string eol, string customList, string ignoreList, variable minWordLength])

    string files, file, contents, contentsPretty
    variable numFiles, i
       
    if(ParamIsDefault(eol))
        eol = "\r"
    endif
   
    if(ParamIsDefault(ignoreList))
        ignoreList = ""
    endif

    if(ParamIsDefault(customList))
        customList = ""
    endif
   
    if(ParamIsDefault(minWordLength))
        minWordLength = kMinWordLengthDefault
    endif

    folder = GetIgorStylePath(folder)

    NewPath/O/Q tempFolder, folder
   
    files = IndexedFile(tempFolder, -1, ".ipf")
    numFiles = ItemsInList(files)
    for(i = 0; i < numFiles; i += 1)
        file = folder + ":" + StringFromList(i, files)
        contents = LoadFile(file)
        contentsPretty = Prettify#PrettifyCode(contents, eol = eol, customList = customList, ignoreList = ignoreList, minWordLength = minWordLength)
        WriteFile(file, contentsPretty)
    endfor
   
    KillPath/Z tempFolder
End

if(GrepString(strLine, "\S[[:blank:]]+\r$"))

if(GrepString(strLine, "^[[:space:]]*$"))
  return strLine
endif