Searching characters through a string

Here is what I came up with:

Function ExtractFormula(Wave in)
    String searchFor = "^[cC][0-9][hH][0-9][oO][0-9]"
    
    String wList
    wfprintf wList, "%s;", in
    
    String strResult = GrepList(wList,searchFor)
    Wave/T wResult = ListToTextWave(strResult,";")
    Duplicate/O wResult, $(NameOfWave(in)+"_out")
End

Adjust the Grep string 'searchFor' to match your desired chemical formula.

With chemical formula in proper syntax (capitalization), the search string can be shortened to this:

"^[CHO0-9]+\\b"

this allows for longer chain hydrocarbons (ie. x, y, or p >9, otherwise in the original regex it should be 1-9 or [0-9]+), and for formulae like CH3COOH.

and before someone else points it out,

"^[CHO0-9]+$"

is shorter!

These are amazing insights and they did the job! Thank you so much, chozo, jjweimer and tony! I deeply appreciate your taking out time to respond, and thoughts. 

@chozo Doesn't the Wave input need to be Wave/T?

It was working without declaring wave/T for the input. Doesn't a function input accepts both numeric and text waves or is that considered a 'bug'?

Huh. I guess wfprintf is one of those baffling Igor inconsistencies. In fact, of course, wfprintf needs to work with any wave type, so it probably determines the wave's type at run-time.

And if you want to avoid the list conversion and just return the result as free wave:

Function/WAVE ExtractFormula(Wave/T in)
    String searchFor = "^[CHO0-9]+$"
    
    Make/FREE/T/N=0 result
    Grep/E=searchFor in as result
    
    return result
End

It's always interesting to see how a problem gets successively ground down to the bare minimum here in the forum. I was somehow under the impression that Grep is only for files. Good to learn a new trick.