Extracting contents of table's target cell?

Menu "Macros"
    // For convenience in testing GetSelectedTableNumericValue
    "Print Selected Table Numeric Value/1", /Q, Print GetSelectedTableNumericValue("")
End
 
// This works only if the table contains only 1D waves and only if
// the data column from each wave is selected. If the index column for
// a wave is selected, it returns the corresponding data value.
Function GetSelectedTableNumericValue(tableName)
    String tableName    // "" for top table
    if (strlen(tableName) == 0)
        tableName = WinName(0, 2)
    endif
    if (WinType(tableName) != 2)
        return NaN      // Not a table
    endif
    
    GetSelection table, $tableName, 7
    if (V_Flag == 0)    // No selection?
        return NaN      // Should not happen
    endif
    
    // First selected table row, zero-based
    Variable firstSelectedRow = V_startRow
    
    // First selected table column, zero-based
    Variable firstSelectedColumn = V_startCol
    
    // Name of first selected column (e.g. wave0.d)
    String columnName = StringFromList(0, S_Selection)
    
    String wName        // Strip, e.g., ".d" from column name to get wave name
    SplitString/E="(.*)\..*$" columnName, wName 
    
    // Path to first selected wave's data folder
    String dfPath = StringFromList(0, S_dataFolder)
    
    String fullDFPath = dfPath + wName  
    Wave/Z w = $fullDFPath
    if (!WaveExists(w))
        return NaN      // An empty cell is selected
    endif
    if (WaveType(w,1) != 1)
        return NaN      // Not a numeric wave
    endif
    
    Variable value = w[firstSelectedRow]
    return value
End

Function TableWindowHook(s)
    STRUCT WMWinHookStruct &s
    
    Variable hookResult = 0 // 0 if we do not handle event, 1 if we handle it.
    
    String message = ""
    
    Wave tableHookWave
    Variable value = tableHookWave[0]
 
    switch(s.eventCode)
        case 3: // Mouse down event
            Printf "Mouse down event, value=%g\r", value
            break
        case 5: // Mouse up event
            Printf "Mouse up event, value=%g\r", value
            break
        case 8: // Modified event - sent to graph and notebook windows only
            Printf "Modified event, value=%g\r", value
            break
    endswitch
    
    return hookResult       // If non-zero, we handled event and Igor will ignore it.
End
 
Function DemoTableWindowHook()
    DoWindow/F TableEventsTable                     // Does table exist?
    if (V_flag == 0)
        // Create table
        Make/O/N=3 tableHookWave = p
        Edit /N=TableEventsTable tableHookWave as "Table Events"
 
        // Install hook
        SetWindow TableEventsTable, hook(MyHook)=TableWindowHook
    endif
End

Function DemoTableDependency()
    DoWindow/F TableDependencyTable                 // Does table exist?
    if (V_flag == 0)
        // Create table
        Make/O/N=3 tableDependencyWave = p
        Edit /N=TableDependencyTable tableDependencyWave as "Table Dependency"
        
        // Set dependency
        SetFormula tableDependencyWave, "root:tableDependencyWave + CheckTableDependencyWave()"
    endif
End
 
Function CheckTableDependencyWave()
    // Print "In CheckTableDependencyWave"
    
    Wave w = root:tableDependencyWave
    // Print w
    
    Variable numPoints = numpnts(w)
    Variable i
    for(i=0; i<numPoints; i+=1)
        Variable val = w[i]
        if (val<0 || val>9)
            Printf "Point %d of tableDependencyWave is out of range - must be 0 to 9\r", i
        endif
    endfor
    
    return 0
End

function doCheck(w)
    wave w
    
    // keep wave points within bounds
    w=max(10*q,min(w, 10*(q+1)),0)
    return 1
end

•make /n=(10,4) tablewave=p+10*q
•edit tablewave
•make /n=1 dependencywave
•dependencywave:=doCheck(tablewave)

#pragma IgorVersion=8.02    // for ModifyTable entryMode and TableHook events 24 ("tableEntryAccepted") and 25 ("tableEntryCancelled").
 
function Func_TableHook(STRUCT WMWinHookStruct &s, string &parentWindowName)
    Variable hookResult = 0                         // 0 if we do not handle event, 1 if we handle it.
 
    switch(s.eventCode)
        case 24: // tableEntryAccepted in Igor 8.02+
            Print s.eventName   // "tableEntryAccepted"
            Func_WorkPosTableBoundsCheck()
            break
        case 25: // tableEntryCancelled in Igor 8.02+
            Print s.eventName   // "tableEntryCancelled"
            break
        default:
            break
    endswitch
    return hookResult
end

ModifyTable/W=demoPanel#tSeqPos entryMode=0 // query
Print "table entry text = \""+S_Value+"\""

#pragma IgorVersion=8.02
 
Macro MakeTableHookExample()
    make/O/N=(20,20) twod=p*q
    make/O/N=20 short=gnoise(1)
    Edit/N=Table0 short, twod
    SetWindow kwTopWin,hook(myhook)=Func_TableHook
    DoAlert 0, "Try editing any value, look at history output"
End
 
function Func_TableHook(STRUCT WMWinHookStruct &s)
    Variable hookResult = 0 // 0 if we do not handle event, 1 if we handle it.
 
    strswitch(s.eventName)
        case "tableEntryAccepted":
            ModifyTable/W=$s.winName entryMode=0 // query, result in S_Value
            Print "accepted: "+S_Value
            GetSelection table, $s.winName, 1+2+4
            // 1    Sets V_startRow, V_startCol, V_endRow, V_endCol based on the selected cells in the table.
            //      The top/left cell, not including the Point column, is (0, 0).
            // 2    Sets S_selection to a semicolon-separated list of column names.
            // 4    Sets S_dataFolder to a semicolon-separated list of data folders, one for each column.
            Print V_StartRow, V_StartCol, S_Selection, S_DataFolder
            break
        default:
            break
    endswitch
    return hookResult
End