#pragma TextEncoding = "UTF-8"
#pragma rtGlobals=3		// Use modern global access method and strict wave access.
#pragma version=1.00
#pragma IgorVersion = 7.0
#include <WaveSelectorWidget>

// written by tony.withers@uwo.ca

// This code replicates a small subset of the functionality of the Global Analysis package 
// (Analysis > Global Fit). The purpose is to add some user interface tweaks to make it 
// easer to set up a fit, at the expense of hardwiring to a specific kind of fit.

// For fitting n pseudovoigt peaks to each of N waves.
// Amplitude is unique to each peak, but each set of 
// N peaks has constant position, width and shape parameters.

//                USAGE
// Run "New Multi-Wave Fit" from macros menu.
// Select multiple waves to fit. 
// Waves must have equal numbers of points and x scaling
// (may be relaxed in future version, ask me if you need this)
// Expand graph x axis to desired fitting range.
// Use peak editor panel to add and delete peaks.
// The width, shape and amplitude parameters are related to width, 
// shape and amplitude as explained in help for VoigtFunc.
// Command (or control) click to add a peak at x position of mouse cursor.
// Mouse-over peaks and click to select; use mouse to move peak position, 
// mousewheel up-down to adjust amplitude, mousewheel left-right to adjust shape,
// shift + mousewheel up-down to adjust width parameter
// By default new peaks are constrained to have positive amplitude. Adjust as required.
// Fit parameters can be saved and loaded. 
// Data waves are not saved with fit, so data waves must exist when reloading a fit.
// MultiWaveFit will OVERWRITE waves starting with MF_ in the same data folder as your data waves!
// 

Menu "Macros"
	"New Multi-Wave Fit...", /Q, MF_StartNewMultiWaveFit()
end

// start from scratch
function MF_StartNewMultiWaveFit()
	NewDataFolder/O root:Packages
	NewDataFolder/O root:Packages:MultiFit
	
	DFREF dfr = root:Packages:MultiFit
	
	wave /SDFR=dfr /WAVE w_MFlist
	wave /SDFR=dfr w_settings, w_coeff, w_hold
	wave /SDFR=dfr /T t_min, t_max
	if(waveexists(w_MFlist))
		if (numpnts(w_MFlist)&&numpnts(w_coeff))
			// save previous parameter set
			DFREF savDFR=GetDataFolderDFR()
			SetDataFolder dfr
			string newDF=uniquename("MFsave", 11, 0)
			newdatafolder $newDF
			DFREF newDFR=$newDF
			duplicate w_Settings newDFR:w_Settings
			duplicate w_MFlist newDFR:w_MFlist
			duplicate w_coeff newDFR:w_coeff
			duplicate w_hold newDFR:w_hold
			duplicate t_min newDFR:t_min
			duplicate t_max newDFR:t_max
			
			SetDataFolder savDFR	
		endif
	endif
	
	make /o/n=0/WAVE dfr:w_MFlist
	make /o/n=0 dfr:w_toFit, dfr:w_theFit
	make /o/n=0/D dfr:w_coeff
	make /o/n=0 dfr:w_hold
	make /o/n=0/T dfr:t_max, dfr:t_min
	make /o /n=5 dfr:w_mouse=0
	make /o /n=20 dfr:w_Settings /wave=w_settings
	w_Settings=0
	
	setdimlabel 0, 0, null, w_Settings
	setdimlabel 0, 1, xmin, w_Settings
	setdimlabel 0, 2, xmax, w_Settings
	setdimlabel 0, 3, specPnts, w_Settings
	setdimlabel 0, 4, numWaves, w_Settings
	setdimlabel 0, 5, numPeaks, w_Settings
	// for future use
	setdimlabel 0, 6, oneWidth, w_Settings
	setdimlabel 0, 7, oneShape, w_Settings
	w_Settings[%null]=nan
	
	dowindow /k MFGraph
		
	// kill peak waves
	variable index=0
	do
		wave /z w=WaveRefIndexedDFR(dfr, index)
		if (!WaveExists(w))
			break
		endif
		if (stringmatch (nameofwave(w), "peak*"))
			killwaves /z w
			if (waveexists(w)) // failed to kill
				index+=1
			endif
		else
			index+=1
		endif
	while (1)
		
	MF_makeWaveSelectorPanel()
end

// run this once a list of fit waves has been prepared
function MF_setupMultiWaveFit()	
	// set up fit waves
	MF_createFitWaves()
	MF_updateFitWaves()
	
	// plot graph
	MF_makeMFGraph()
	MF_makePeakEditor()
end

// this function OVERWRITES waves starting with MF_
function MF_createFitWaves()
	DFREF dfr = root:Packages:MultiFit
	wave /SDFR=dfr /WAVE w_MFlist
	wave /SDFR=dfr w_coeff
	
	variable numWaves, waveNum, numPeaks, peakNum
	string s_peakname
	
	numWaves=numpnts(w_MFlist)
	numPeaks=dimsize(w_coeff, 0)/(numWaves+3)
	
	for (waveNum=0;waveNum<numWaves;waveNum+=1)
		DFREF dfr2=GetWavesDataFolderDFR(w_MFlist[waveNum])
		duplicate /o w_MFlist[waveNum] dfr2:$"MF_"+nameofwave(w_MFlist[waveNum]) /wave=w
		w=0
		
		for (peakNum=0; peaknum<numPeaks; peakNum+=1)
			s_peakName="peak"+num2str(peakNum+1)+"_"+num2str(waveNum+1)
			duplicate /o w_MFlist[waveNum] dfr:$s_peakName /wave=w
			w=0
		endfor
	endfor	
end

// update all of the (N*n) peak waves and the fit for each spectrum
function MF_updateFitWaves()
	DFREF dfr = root:Packages:MultiFit
	wave /SDFR=dfr /WAVE w_MFlist
	wave /SDFR=dfr w_settings, w_coeff
	
	variable numWaves, numPeaks, waveNum, peakNum
	variable p0, x0, width, shape, amp
	numWaves=numpnts(w_MFlist)
	numPeaks=dimsize(w_coeff, 0)/(numWaves+3)
	string s_peakName=""
	for (waveNum=0;waveNum<numWaves;waveNum+=1)
		DFREF dfr2=GetWavesDataFolderDFR(w_MFlist[waveNum])
		wave w=dfr2:$"MF_"+nameofwave(w_MFlist[waveNum])
		w=0
		for (peakNum=0;peakNum<numpeaks;peakNum+=1)
			// add peak to fit wave
			p0=peakNum*(numWaves+3)
			x0=w_coeff[p0]
			width=w_coeff[p0+1]
			shape=w_coeff[p0+2]
			amp=w_coeff[p0+3+waveNum]	
			w+=amp*VoigtFunc(width*(x-x0),shape)	
			
			// update peak wave
			s_peakName="peak"+num2str(peakNum+1)+"_"+num2str(waveNum+1)
			wave w_peak=dfr:$s_peakName
			w_peak=amp*VoigtFunc(width*(x-x0),shape)	
		endfor		
	endfor	
	w_settings[%numWaves]=numWaves
	
end

function MF_makeMFGraph()
	DFREF dfr = root:Packages:MultiFit
	wave /SDFR=dfr /WAVE w_MFlist
	wave /SDFR=dfr w_coeff, w_settings
	
	variable v_left=200, v_top=45, v_right=850, v_bottom=650
	doWindow MFgraph
	if (v_flag)
		getwindow MFgraph wsizeRM	
	endif	
	doWindow /K MFGraph
	Display /W=(v_left,v_top,v_right,v_bottom) /N=MFGraph as "Multi-Wave Fit Graph"
	variable numWaves=numpnts(w_MFlist)
	variable numPeaks=dimsize(w_coeff, 0)/(numWaves+3)
	
	variable waveNum, peakNum, ax_min, ax_max
	string s_ax
	for (waveNum=0;waveNum<numWaves;waveNum+=1)
		s_ax="axis"+num2str(waveNum+1)
		AppendToGraph /L=$s_ax w_MFlist[waveNum]
		ModifyGraph freePos($s_ax)={0,kwFraction}
		ax_min=waveNum*(0.95/numWaves+0.05/(numWaves-1))
		ax_max=(waveNum+1)*0.95/numWaves+waveNum*0.05/(numWaves-1)
		ModifyGraph axisEnab($s_ax)={ax_min,ax_max}
		
		// append fit wave
		DFREF dfr2=GetWavesDataFolderDFR(w_MFlist[waveNum])
		wave w=dfr2:$"MF_"+nameofwave(w_MFlist[waveNum])
		AppendToGraph /L=$s_ax w
		ModifyGraph rgb($nameofwave(w))=(0,0,65535)
		
		for(peakNum=0; peakNum<numPeaks; peakNum+=1)
			wave w=dfr:$"peak"+num2str(peakNum+1)+"_"+num2str(waveNum+1)
			AppendToGraph /L=$s_ax w
			ModifyGraph rgb($nameofwave(w))=(2,39321,1)
		endfor
		
	endfor
	
	if (abs(w_settings[%xmax]-w_settings[%xmin])>0)
		setaxis /W=MFgraph bottom, w_settings[%xmin], w_settings[%xmax]
	endif
	
	SetWindow MFGraph hook(pkdrag)=MF_graphHook
end

function MF_doFit()
	// set up the fit
	DFREF dfr = root:Packages:MultiFit
	wave /SDFR=dfr /WAVE w_MFlist
	wave /SDFR=dfr w_settings, w_coeff, w_toFit, w_theFit, w_hold
	wave /T /SDFR=dfr t_max, t_min
	variable numWaves, numPeaks, waveNum, peakNum
	
	getaxis /W=MFGraph/Q bottom
	
	// these aren't totally accurate - based on graph axis, not wave points
	w_settings[%xmin]=v_min
	w_settings[%xmax]=v_max
	
	numWaves=numpnts(w_MFlist)
	numPeaks=dimsize(w_coeff, 0)/(numWaves+3)
	
	redimension /N=0 w_toFit
	for (wavenum=0;wavenum<numWaves;waveNum+=1)
		// be careful with point order here...
		duplicate /o /R=(w_settings[%xmin],w_settings[%xmax]) w_MFlist[waveNum] dfr:w_temp /wave=w_temp
		if (DimDelta(w_temp, 0)<0)
			reverse w_temp
		endif
		
		concatenate /NP {w_temp}, dfr:w_toFit
	endfor
	
	// get real values for min and max
	// we're assuming all the data waves have identical scaling
	
	w_settings[%xmin]=pnt2x(w_temp, 0)
	w_settings[%xmax]=pnt2x(w_temp, numpnts(w_temp)-1)
	
	setscale /P x, 0, 1, w_toFit // make sure W_toFit has point scaling
	w_settings[%specPnts]=numpnts(w_temp)
	w_settings[%numWaves]=numWaves	
	w_settings[%numPeaks]=numPeaks	
	
	// probably don't need this wave, but useful for checking
	duplicate /o w_toFit w_theFit
	
	// counstruct hold string
	string s_hold=""
	variable i
	for (i=0;i<numpnts(w_hold);i+=1)
		s_hold+=num2str(w_hold[i])
	endfor
	
	// construct constraints wave
	make /o /N=0 /T dfr:t_constraints /wave=t_c
	for (i=0;i<numpnts(w_hold);i+=1)
		if (w_hold[i]==0)
			if(strlen(t_min[i]))
				insertpoints numpnts(t_c), 1, t_c
				t_c[numpnts(t_c)-1]="K"+num2str(i)+">"+t_min[i]
			endif
			
			if(strlen(t_max[i]))
				insertpoints numpnts(t_c), 1, t_c
				t_c[numpnts(t_c)-1]="K"+num2str(i)+"<"+t_max[i]
			endif
		endif
	endfor
		
	// should be ready to do fit...
	
	FuncFit/NTHR=0 /H=s_hold  MF_fitNPeaks w_coeff w_toFit /D /C=t_c
	
	MF_updateFitWaves()
	
	// just for checking:
	w_theFit=MF_fitNPeaks(w_coeff, p)
	
	variable p0, x0, width, shape, amp, wl, wg		
	
	for(peakNum=0;peakNum<numPeaks;peaknum+=1)
		p0=peakNum*(numWaves+3)
		x0=w_coeff[p0]
		width=w_coeff[p0+1]
		shape=w_coeff[p0+2]
		wg=sqrt(ln(2))/width
		wl=shape/width
		
		print "peak:", peaknum+1
		print "  position:", x0	
		print "  shape:", shape
		print "  Gaussian width:", wg	
		print "  Lorentzian width:", wl 
		print "  Voigt width:", wl/2 + sqrt( wl^2/4 + wg^2)
		
		variable a_tot=0, h_tot=0
		for(wavenum=0;wavenum<numWaves;waveNum+=1)		
			amp=w_coeff[p0+3+waveNum]		
			a_tot+= amp*sqrt(pi)/width			
			printf "  %s height: %g\r", nameofwave(w_MFlist[waveNum]), amp*VoigtFunc(0,shape)				
		endfor
		
		for(wavenum=0;wavenum<numWaves;waveNum+=1)		
			amp=w_coeff[p0+3+waveNum]		
			printf "  %s area:  %g  (%1.0f%%)\r", nameofwave(w_MFlist[waveNum]), amp*sqrt(pi)/width, 100*amp*sqrt(pi)/width/a_tot		
		endfor
	endfor	
end

// fit function to fit n pseudovoight peaks to each of N
// waves. Amplitude is unique to each
// peak, but each set of N peaks has constant position, 
// width and shape parameters
//  
// make sure concatenated wave has x scaling by point
function MF_fitNPeaks(wave w_coeff, variable pnt) : FitFunc
	// pnt is point number in concatenated wave
	
	DFREF dfr = root:Packages:MultiFit
	wave /SDFR=dfr w_Settings
	
	variable xmin=w_Settings[%xmin]
	variable xmax=w_Settings[%xmax]
	variable specpointstotal=w_Settings[%specPnts]
	
	variable specpt=mod(pnt, specpointstotal)
	variable x = xmin+(xmax-xmin)*(specpt/(specpointstotal-1))
		
	// each set of N peaks has coefficients 
	// x0, width, shape, amp1, amp2,... ampN
	// so w_coeff should have n*(N+3) points
	wave /SDFR=dfr/WAVE  w_MFlist
	variable numWaves=dimsize(w_MFlist, 0)
	variable numPks=dimsize(w_coeff, 0)/(numWaves+3)
	variable peaknum, wavenum
	
	wavenum=floor(pnt/specpointstotal)
	
	variable p0
	variable y, x0, width, shape, amp
	
	for (peaknum=0;peaknum<numpks; peaknum+=1)
		p0=peaknum*(numWaves+3)
		x0=w_coeff[p0]
		width=w_coeff[p0+1]
		shape=w_coeff[p0+2]
		amp=w_coeff[p0+3+waveNum]
		
		y+= amp*VoigtFunc(width*(x-x0),shape)
		
	endfor
	
	return y
end

// called from wave selector.
function MF_start()
	string s_selection=WS_SelectedObjectsList("MFwaveSelector", "MFlistbox")
	if (strlen(s_selection)==0)
		dowindow /K MFwaveSelector
		return 0
	endif
	
	DFREF dfr = root:Packages:MultiFit
	wave /SDFR=dfr /WAVE w_MFlist
	redimension /N=(itemsinlist(s_selection)) w_MFlist
	w_MFlist=$stringfromlist(p, s_selection)
	dowindow /K MFwaveSelector
	MF_setupMultiWaveFit()
end


function MF_deletePeak(peakNum)
	variable peakNum
	
	DFREF dfr = root:Packages:MultiFit
	wave /SDFR=dfr w_coeff, w_hold, w_settings
	wave /SDFR=dfr /T t_max, t_min
	wave /SDFR=dfr /WAVE w_MFlist
	variable numWaves=numpnts(w_MFlist)
	variable numPeaks=dimsize(w_coeff, 0)/(numWaves+3)

	variable waveNum, p0
	controlinfo /W=MFgraph#MF_peakPanel popSpec
	waveNum=v_value	
					
	p0=(peakNum-1)*(numWaves+3)
	
	deletepoints p0, numWaves+3, w_coeff, w_hold, t_max, t_min
	w_settings[%numPeaks]	=numPeaks-1
	
	// now we have numPeaks-1 peaks, so delete highest numbered peak waves
	string s_peakName
	variable i
	for (i=0;i<numWaves;i+=1)
		s_peakName="peak"+num2str(numPeaks)+"_"+num2str(i+1)
		removefromgraph /W=MFgraph /Z $s_peakName
		killwaves /Z dfr:$s_peakName
	endfor
	// then update all the peak waves
	MF_updateFitWaves()
	// and select a peak
	peakNum=max(peakNum-1,1)
	
	MF_setControls(peakNum, waveNum)
end



// could maintain a 2D wave for peak coeffs 
// and build 1D coeff wave prior to fit
function MF_addPeak([pos, width, shape, amp])
	variable pos, width, shape, amp
	
	DFREF dfr = root:Packages:MultiFit
	wave /SDFR=dfr w_coeff, w_hold, w_settings
	wave /SDFR=dfr /T t_max, t_min
	wave /SDFR=dfr /WAVE w_MFlist
	
	variable Nwaves=numpnts(w_MFlist)
	variable numPeaks=numpnts(w_coeff)/(Nwaves+3)
	
	insertpoints numpnts(w_coeff), Nwaves+3, w_coeff, w_hold, t_max, t_min
	numPeaks+=1
	// pnt number for first new coeff
	variable pnt=(numPeaks-1)*(Nwaves+3)
	
	// set default values for constraints 
	t_min[pnt+1,pnt+5]="0" // keep all parameters other than position positive
	
	
	getaxis /Q /W=MFgraph bottom
	if (ParamIsDefault(pos))
		w_coeff[pnt]=v_min+0.5*(v_max-v_min)/numPeaks
	else
		w_coeff[pnt]=pos
	endif
	
	pnt+=1
	if (ParamIsDefault(width))
		w_coeff[pnt]=sqrt(ln(2))/(0.01*abs(V_max-v_min))
	else
		w_coeff[pnt]=width
	endif
	
	pnt+=1
	if (ParamIsDefault(shape))
		w_coeff[pnt]=1
	else
		w_coeff[pnt]=shape
	endif
	
	variable i
	getaxis /Q /W=MFgraph bottom
	for(i=0;i<Nwaves;i+=1)
		pnt+=1
		if (ParamIsDefault(amp))
			w_coeff[pnt]=0.5*(wavemax(w_MFlist[i], v_min, v_max)-wavemin(w_MFlist[i], v_min, v_max))
		else
			w_coeff[pnt]=amp
		endif
	endfor
	
	string s_peakName
	for (i=0;i<Nwaves;i+=1)
		s_peakName="peak"+num2str(numPeaks)+"_"+num2str(i+1)
		duplicate /o w_MFlist[i] dfr:$s_peakName
		removefromgraph /W=MFgraph /Z $s_peakName
		appendtograph /W=MFgraph /L=$("axis"+num2str(i+1)) dfr:$s_peakName
		ModifyGraph /W=MFgraph rgb($s_peakName)=(2,39321,1)
	endfor
	
	w_settings[%numPeaks]+=1		
	MF_updateFitWaves()	
end

// sets controls to operate on selected peak
// whichWave, whichPeak numbered from 1
function MF_setControls(whichPeak, whichWave)
	variable whichPeak, whichWave
	
	DFREF dfr = root:Packages:MultiFit
	wave /SDFR=dfr w_coeff, w_hold
	wave /SDFR=dfr /T t_max, t_min
	wave /SDFR=dfr /WAVE w_MFlist
	variable numWaves=numpnts(w_MFlist)
	
	PopupMenu popPeak win=MFgraph#MF_peakPanel,mode=whichPeak,value= MF_peakPopList()
	PopupMenu popSpec win=MFgraph#MF_peakPanel,mode=whichWave,value= MF_specPopList()
	
	if (numpnts(w_hold)==0) // no peaks added yet
		return 0
	endif
	
	variable p0=(numWaves+3)*(whichPeak-1)
	SetVariable setX win=MFgraph#MF_peakPanel, value=w_coeff[p0]
	CheckBox check0 win=MFgraph#MF_peakPanel, value=w_hold[p0]
	SetVariable setmin0 win=MFgraph#MF_peakPanel, value=t_min[p0]
	SetVariable setmax0 win=MFgraph#MF_peakPanel, value=t_max[p0]
	
	SetVariable setWidth win=MFgraph#MF_peakPanel, value=w_coeff[p0+1]
	CheckBox check1 win=MFgraph#MF_peakPanel, value=w_hold[p0+1]
	SetVariable setmin1 win=MFgraph#MF_peakPanel, value=t_min[p0+1]
	SetVariable setmax1 win=MFgraph#MF_peakPanel, value=t_max[p0+1]
	
	SetVariable setShape win=MFgraph#MF_peakPanel, value=w_coeff[p0+2]
	CheckBox check2 win=MFgraph#MF_peakPanel, value=w_hold[p0+2]
	SetVariable setmin2 win=MFgraph#MF_peakPanel, value=t_min[p0+2]
	SetVariable setmax2 win=MFgraph#MF_peakPanel, value=t_max[p0+2]
	
	SetVariable setAmp win=MFgraph#MF_peakPanel, value=w_coeff[p0+2+whichWave]
	CheckBox check3 win=MFgraph#MF_peakPanel, value=w_hold[p0+2+whichWave]
	SetVariable setmin3 win=MFgraph#MF_peakPanel, value=t_min[p0+2+whichWave]
	SetVariable setmax3 win=MFgraph#MF_peakPanel, value=t_max[p0+2+whichWave]
	

	
	// highlight selected peak
	ModifyGraph /W=MFgraph/Z lsize=1
	string s_peakName="peak"+num2str(whichPeak)+"_"+num2str(whichWave)
	ModifyGraph /W=MFgraph/Z lsize($s_peakName)=2	
end

function MF_makePeakEditor()
	DFREF dfr = root:Packages:MultiFit
	wave /SDFR=dfr w_coeff, w_hold
	wave /SDFR=dfr /T t_max, t_min
	wave /SDFR=dfr /WAVE w_MFlist
	
	variable numWaves=numpnts(w_MFlist)
	variable numPeaks=dimsize(w_coeff, 0)/(numWaves+3)
	
	killwindow /Z MFgraph#MF_peakPanel
	NewPanel /N=MF_peakPanel /HOST=MFgraph /EXT=1 /W=(380, 0, 0, 250) as "Peak Editor"
	SetDrawLayer UserBack
	DrawText 255,45,"hold"
	DrawText 292,45,"min"	
	DrawText 340,45,"max"	
	SetVariable setX,pos={119.00,50.00},size={119.00,14.00},bodyWidth=80,proc=MF_SetVarProc,title="position"
	SetVariable setWidth,pos={130.00,84.00},size={108.00,14.00},bodyWidth=80,proc=MF_SetVarProc,title="width"
	SetVariable setWidth,limits={0,inf,0.01}
	SetVariable setShape,pos={129.00,118.00},size={109.00,14.00},bodyWidth=80,proc=MF_SetVarProc,title="shape"
	SetVariable setShape,limits={0,inf,1}
	SetVariable setAmp,pos={110.00,153.00},size={128.00,14.00},bodyWidth=80,proc=MF_SetVarProc,title="amplitude"	
	PopupMenu popSpec,pos={18.00,153.00},size={80.00,23.00},proc=MF_PopMenu,title="spectrum"
	PopupMenu popSpec,mode=1,popvalue="1",value= MF_specPopList()
	PopupMenu popPeak,pos={161.00,15.00},size={76.00,23.00},proc=MF_PopMenu,title="peak"
	PopupMenu popPeak,mode=1,value= MF_peakPopList()
	CheckBox check0,pos={261.00,50.00},size={15.00,16.00},proc=MF_CheckProc,title=""
	CheckBox check1,pos={261.00,84.00},size={15.00,16.00},proc=MF_CheckProc,title=""
	CheckBox check2,pos={261.00,118.00},size={15.00,16.00},proc=MF_CheckProc,title=""
	CheckBox check3,pos={261.00,153.00},size={15.00,16.00},proc=MF_CheckProc,title=""

	
	SetVariable setmin0, pos={287.00,50.00},size={40.00,14.00},bodyWidth=40,proc=MF_SetTxtVarProc,title=" "
	SetVariable setmin1, pos={287.00,84.00},size={40.00,14.00},bodyWidth=40,proc=MF_SetTxtVarProc,title=" "
	SetVariable setmin2, pos={287.00,118.00},size={40.00,14.00},bodyWidth=40,proc=MF_SetTxtVarProc,title=" "
	SetVariable setmin3, pos={287.00,153.00},size={40.00,14.00},bodyWidth=40,proc=MF_SetTxtVarProc,title=" "
	SetVariable setmax0, pos={335.00,50.00},size={40.00,14.00},bodyWidth=40,proc=MF_SetTxtVarProc,title=" "
	SetVariable setmax1, pos={335.00,84.00},size={40.00,14.00},bodyWidth=40,proc=MF_SetTxtVarProc,title=" "
	SetVariable setmax2, pos={335.00,118.00},size={40.00,14.00},bodyWidth=40,proc=MF_SetTxtVarProc,title=" "
	SetVariable setmax3, pos={335.00,153.00},size={40.00,14.00},bodyWidth=40,proc=MF_SetTxtVarProc,title=" "
	
	
	Button buttonDelete,pos={89.00,14.00},size={50.00,20.00},title="Delete", proc=MF_ButtonProc
	Button buttonFit,pos={225.00,210.00},size={50.00,20.00},proc=MF_ButtonProc,title="Fit!"
	Button buttonLoad,pos={49.00,210.00},size={55.00,20.00},title="Load...", proc=MF_ButtonProc
	Button buttonSave,pos={137.00,210.00},size={55.00,20.00},title="Save...", proc=MF_ButtonProc
		
	// set values corresponding to first peak of first spectrum
	MF_setControls(1, 1)
end


function MF_makeWaveSelectorPanel()
	doWindow /K MFwaveSelector
	NewPanel /W=(55,55,294,440)/K=1/N=MFwaveSelector as "Multi-Wave Selector"
	
	SetDrawLayer UserBack
	SetDrawEnv fsize= 14
	DrawText 25,30,"Choose waves to fit:"
	
	ListBox MFlistbox,pos={20, 40},size={200, 285}
	// set up wave selector widget to allow one selection
	MF_singleSelector()
		
	Button buttonStart,pos={92.00,343.00},size={50.00,20.00},proc=MF_ButtonProc,title="Do It"
end

function MF_singleSelector()
	MakeListIntoWaveSelector("MFwaveSelector", "MFlistbox",content=WMWS_Waves,selectionMode=WMWS_SelectionSingle, listoptions="DIMS:1")
	WS_OpenAFolderFully("MFwaveSelector", "MFlistbox", getdatafolder(1))
	WS_SetNotificationProc("MFwaveSelector", "MFlistbox", "MF_OneWaveProc" , isExtendedProc=1)
end

// initial selection must be saved in global string before switching to multiSelector
// filter function will ensure that we get waves with equal numbers of points
function MF_multiSelector()	
	DFREF dfr = root:Packages:MultiFit	
	SVAR s_selection=dfr:s_selection
	
	if (itemsinlist(s_selection)==0)	
		MF_singleSelector()
		return 0
	endif
	
	wave w=$s_selection
	if (waveexists(w)==0) // not trying to select a wave
		return 0
	endif
	
	MakeListIntoWaveSelector("MFwaveSelector", "MFlistbox",content=WMWS_Waves,selectionMode=WMWS_SelectionNonContiguous, nameFilterProc="MF_filter", listoptions="DIMS:1")	
	WS_OpenAFolderFully("MFwaveSelector", "MFlistbox", GetWavesDataFolder($s_selection, 1 )  )
	WS_SelectAnObject("MFwaveSelector", "MFlistbox", s_selection, OpenFoldersAsNeeded=1)
	// selection may get deselected by immediate mouseup event!	
	WS_SetNotificationProc("MFwaveSelector", "MFlistbox", "MF_ManyWavesProc" , isExtendedProc=1)
end

function MF_filter(aName, contents)
	String aName		// object name with full data folder path
	Variable contents	// content code as described for the content parameter
	
	DFREF dfr = root:Packages:MultiFit	
	SVAR s_selection=dfr:s_selection
	
	if (itemsinlist(s_selection))
		return (dimsize($aName, 0)==dimsize($stringfromlist(0,s_selection), 0))
	endif
	
	return 1
end

function MF_OneWaveProc(SelectedItem, EventCode, OwningWindowName, ListboxControlName)
	String SelectedItem			// string with full path to the item clicked on in the wave selector
	Variable EventCode			// the ListBox event code that triggered this notification
	String OwningWindowName	// String containing the name of the window containing the listbox
	String ListboxControlName	// String containing the name of the listbox control	
	
	DFREF dfr = root:Packages:MultiFit	
	string /g dfr:s_selection 
	SVAR s_selection=dfr:s_selection
	s_selection=SelectedItem
	
	MF_multiSelector()	
end

function MF_ManyWavesProc(SelectedItem, EventCode, OwningWindowName, ListboxControlName)
	String SelectedItem			// string with full path to the item clicked on in the wave selector
	Variable EventCode			// the ListBox event code that triggered this notification
	String OwningWindowName	// String containing the name of the window containing the listbox
	String ListboxControlName	// String containing the name of the listbox control
	
	// it's possible to deselect the wave that was selected programmatically when switching to the multi-select widget.
	// check the global variable - if it's set, make sure wave is selected and clear it.
	
	DFREF dfr = root:Packages:MultiFit	
	string /g dfr:s_selection 
	SVAR s_selection=dfr:s_selection
	
	wave w=$s_selection
	if (waveexists(w))
		WS_SelectAnObject("MFwaveSelector", "MFlistbox", s_selection, OpenFoldersAsNeeded=1)	
	endif
	s_selection=""
	
	string s_list=WS_SelectedObjectsList("MFwaveSelector", "MFlistbox")

	if (itemsinlist(s_list)==0) // deselected everything - revert to single wave selector with all 1D waves available
		MF_singleSelector()
	endif
end


function MF_save()
	DFREF dfr = root:Packages:MultiFit
	
	wave /SDFR=dfr /WAVE w_MFlist
	wave /SDFR=dfr w_settings, w_coeff, w_hold
	wave /SDFR=dfr /T t_min, t_max
	if(waveexists(w_MFlist))
		if (numpnts(w_MFlist)&&numpnts(w_coeff))	
			// save current parameter set
			DFREF savDFR=GetDataFolderDFR()
			SetDataFolder dfr
			string newDF=uniquename("MFsave", 11, 0)
			prompt newDF, "Save as"
			doPrompt "Save fit", newDF
			if (v_flag)
				return 0
			endif
			
			if(CheckName(newDF, 11))
				doAlert 1, newDF+" already exists.\rOverwrite?"
				if(v_flag==2)
					SetDataFolder savDFR
					return 0
				endif
			endif
			newdatafolder/o $newDF
			DFREF newDFR=$newDF
			duplicate /o dfr:w_Settings newDFR:w_Settings
			duplicate /o dfr:w_MFlist newDFR:w_MFlist
			duplicate /o dfr:w_coeff newDFR:w_coeff
			duplicate /o dfr:w_hold newDFR:w_hold
			duplicate /o dfr:t_min newDFR:t_min
			duplicate /o dfr:t_max newDFR:t_max
			
			SetDataFolder savDFR	
		else
			doAlert 0, "nothing to save"
		endif
	endif
end

function MF_load()
	DFREF dfr = root:Packages:MultiFit
	variable folders=CountObjectsDFR(dfr, 4)
	if (folders==0)
		doalert 0, "no saved fits"
		return 0
	endif
	
	variable i
	string dfList=""
	for (i=0;i<folders;i+=1)
	 	dfList+=GetIndexedObjNameDFR(dfr, 4, i)+";"
	endfor
	variable n
	prompt n, "select saved fit", popup dfList
	doprompt  "Multi-Wave Fit Loader", n 
	
	if (V_flag)
		return 0
	endif
	
	DFREF dfrSav = root:Packages:MultiFit:$stringfromlist(n-1, dfList)
	
	if (DataFolderRefStatus(dfrSav))
		wave /SDFR=dfrSav w_settings, w_coeff, w_hold
		wave /SDFR=dfrSav /T t_min, t_max
		wave /SDFR=dfrSav /WAVE w_MFlist
		for (i=0;i<numpnts(w_MFlist);i+=1)
			if (waveexists(w_MFlist[i])==0)
				doalert(0), "cannot find "+nameofwave(w_MFlist[i])
				return 0
			endif
		endfor
		
		duplicate /o w_Settings dfr:w_Settings
		duplicate /o w_MFlist dfr:w_MFlist
		duplicate /o w_coeff dfr:w_coeff
		duplicate /o w_hold dfr:w_hold
		duplicate /o t_min dfr:t_min
		duplicate /o t_max dfr:t_max
		
		MF_setupMultiWaveFit()	
		
		
		
	endif	
end


// ---------------------- control proc fuctions ------------------------

Function MF_ButtonProc(ba) : ButtonControl
	STRUCT WMButtonAction &ba

	switch( ba.eventCode )
		case 2: // mouse up
			// click code here
			strswitch(ba.ctrlName)
				case "buttonStart":
					MF_start()
					break
				case "buttonDelete":
					variable peakNum
					controlinfo /W=MFgraph#MF_peakPanel popPeak
					peakNum=v_value	
					MF_deletePeak(peakNum)
					break
				case "buttonFit":
					MF_doFit()
					break
				case "buttonLoad":
					MF_Load()
					break
				case "buttonSave":
					MF_Save()
					break
			endswitch

			break
		case -1: // control being killed
			break
	endswitch

	return 0
End

Function MF_CheckProc(cba) : CheckBoxControl
	STRUCT WMCheckboxAction &cba
	
	switch( cba.eventCode )
		case 2: // mouse up
			Variable checked = cba.checked
			
			// figure out which point in w_hold to alter
			DFREF dfr = root:Packages:MultiFit
			wave /SDFR=dfr w_hold
			
			wave /SDFR=dfr /WAVE w_MFlist
			variable Nwaves=numpnts(w_MFlist)

			variable waveNum, peakNum, p0				
			controlinfo /W=MFgraph#MF_peakPanel popPeak
			peakNum=v_value		
		
			controlinfo /W=MFgraph#MF_peakPanel popSpec
			waveNum=v_value
			
			p0=(peaknum-1)*(Nwaves+3)
			strswitch (cba.ctrlName)
				case "check0":
					w_hold[p0]=checked
					break
				case "check1":
					w_hold[p0+1]=checked
					break
				case "check2":
					w_hold[p0+2]=checked
					break
				case "check3":
					w_hold[p0+2+waveNum]=checked
					break
			endswitch
			
		case -1: // control being killed
			break
	endswitch

	return 0
End

Function MF_SetVarProc(sva) : SetVariableControl
	STRUCT WMSetVariableAction &sva

	switch( sva.eventCode )
		case 1: // mouse up
		case 2: // Enter key
		case 3: // Live update
			Variable dval = sva.dval
			String sval = sva.sval
			
			DFREF dfr = root:Packages:MultiFit
			wave /SDFR=dfr w_coeff, w_theFit
			
			w_theFit=MF_fitNPeaks(w_coeff, p)
			MF_updateFitWaves()
			
			break
		case -1: // control being killed
			break
	endswitch

	return 0
End

Function MF_SetTxtVarProc(sva) : SetVariableControl
	STRUCT WMSetVariableAction &sva

	switch( sva.eventCode )
		case 1: // mouse up
		case 2: // Enter key
		case 3: // Live update
			Variable dval = sva.dval
			String sval = sva.sval
			
			DFREF dfr = root:Packages:MultiFit
			wave /T /SDFR=dfr t_max, t_min
			
			variable num=str2num(sval)
			wave /T t=sva.svWave
			if (numtype(num)==0)
				t[sva.rowIndex]=num2str(num)
			else
				t[sva.rowIndex]=""
			endif
			
			break
		case -1: // control being killed
			break
	endswitch

	return 0
End

Function MF_PopMenu(pa) : PopupMenuControl
	STRUCT WMPopupAction &pa

	switch( pa.eventCode )
		case 2: // mouse up
			Variable popNum = pa.popNum
			String popStr = pa.popStr
			
			DFREF dfr = root:Packages:MultiFit
			wave /SDFR=dfr w_coeff, w_hold, w_settings
			wave /SDFR=dfr /WAVE w_MFlist
			variable Nwaves, numPeaks
			Nwaves=numpnts(w_MFlist)
			numPeaks=numpnts(w_coeff)/(Nwaves+3)
			
			if (cmpstr(pa.popStr, "add")==0)
				MF_addPeak()
				// set popmenu to new peak
				numPeaks+=1
				PopupMenu popPeak win=MFgraph#MF_peakPanel,mode=numPeaks,value= MF_peakPopList()	
			endif
	
			variable waveNum, peakNum			
			controlinfo /W=MFgraph#MF_peakPanel popPeak
			peakNum=v_value		
		
			controlinfo /W=MFgraph#MF_peakPanel popSpec
			waveNum=v_value	
			
			MF_setControls(peakNum, waveNum)
					
			break
		case -1: // control being killed
			break
	endswitch

	return 0
End

function/S MF_peakPopList()
	DFREF dfr = root:Packages:MultiFit
	wave /SDFR=dfr w_coeff
	wave /SDFR=dfr /WAVE w_MFlist
	
	variable numWaves=numpnts(w_MFlist)
	variable numPeaks=dimsize(w_coeff, 0)/(numWaves+3)
	variable i
	string s_peaks=""
	for(i=1;i<=numPeaks;i+=1)
		s_peaks+=num2str(i)+";"
	endfor
	s_peaks+="add;"
	return s_peaks
end

function /S MF_specPopList()
	DFREF dfr = root:Packages:MultiFit
	wave /SDFR=dfr /WAVE w_MFlist
	
	variable numWaves=numpnts(w_MFlist)
	variable i
	string s_waves=""
	for(i=1;i<=numWaves;i+=1)
		s_waves+=num2str(i)+";"
	endfor
	return s_waves
end


// ----------------------- hook functions --------------------------
// hook to handle peak editing
Function MF_graphHook(s)
	STRUCT WMWinHookStruct &s
	
	DFREF dfr = root:Packages:MultiFit	
	wave /SDFR=dfr w_coeff, w_mouse, w_settings
	
	Variable hookResult = 0	// 0 if we do not handle event, 1 if we handle it.		
	string foo, tname
	variable waveNum, peakNum, p0
	variable oldx, oldy, newx, newy, delx, dely
	
	switch(s.eventCode)
		case 3: //mousedown
			
		case 4:	// mousemoved event
			
			if (w_mouse[0]) // we've already grabbed a peak
				
				peakNum=w_mouse[1]
				p0=(peakNum-1)*(w_settings[%numWaves]+3)
				oldx=w_mouse[3]
				oldy=w_mouse[4]
				newx=AxisValFromPixel("MFgraph", "bottom", s.mouseloc.h)
				newy=AxisValFromPixel("MFgraph", "axis"+num2str(peakNum), s.mouseloc.v)
				
				// newy is offset when axis is not drawn full range - don't use y coords			
				getaxis /Q/W=MFgraph bottom
				if ( newx > min(v_max, v_min) && newx < max(v_max, v_min) )
					delx=newx-oldx
					if (numtype(delx)==0)
						w_coeff[p0]+=delx
						w_mouse[3]=newx
					endif
				endif
				
				MF_updateFitWaves()
				
				hookresult=0 // won't be able to drag to offset!
			else
				foo=TraceFromPixel(s.mouseloc.h,s.mouseloc.v, "WINDOW:MFgraph;DELTAX:4;DELTAY:4;")

				if (strlen(foo))
					tname=StringByKey("TRACE", foo)
					if(stringMatch(tname, "peak*") && waveexists(dfr:$tname))
						sscanf tname, "peak%d_%d", peakNum, waveNum
						MF_setControls(peakNum, waveNum)
					endif
				endif
			endif
			

			break
		case 5: // mouseup	
		
			if (GetKeyState(0)^2^0)	
				MF_addPeak(pos=AxisValFromPixel("MFgraph", "bottom", s.mouseloc.h))
				break
			endif	

			if(w_mouse[0]==1)
				w_mouse[0]=0
				ModifyGraph /W=MFgraph rgb($"peak"+num2str(w_mouse[1])+"_"+num2str(w_mouse[2]))=(2,39321,1)
			else //choosing a peak to edit			
				foo=TraceFromPixel(s.mouseloc.h,s.mouseloc.v, "WINDOW:MFgraph;DELTAX:4;DELTAY:4;")
				if (strlen(foo))
					tname=StringByKey("TRACE", foo)
					if(stringMatch(tname, "peak*") && waveexists(dfr:$tname))
						sscanf tname, "peak%d_%d", peakNum, waveNum
						MF_setControls(peakNum, waveNum)
						newx=AxisValFromPixel("MFgraph", "bottom", s.mouseloc.h)
						newy=AxisValFromPixel("MFgraph", "axis"+num2str(peakNum), s.mouseloc.v) 
						w_mouse={1, peakNum, waveNum, newx, newy}
						ModifyGraph /W=MFgraph rgb($"peak"+num2str(peakNum)+"_"+num2str(waveNum))=(65535,0,52428)
						getaxis /Q/W=MFgraph bottom
						setaxis /W=MFgraph bottom, v_min, v_max
						getaxis /Q/W=MFgraph $"axis"+num2str(waveNum)
						setaxis /W=MFgraph $"axis"+num2str(waveNum), v_min, v_max
						
						
						hookResult = 1		
					endif
				endif			
			endif
			
			break
		case 22:  // mousewheel
		
			if (w_mouse[0]) // we've already grabbed a peak
				
				
				
				peakNum=w_mouse[1]
				p0=(peakNum-1)*(w_settings[%numWaves]+3)
				
				// use scroll left/right to adjust shape
				if(!(GetKeyState(0)&2^2))
					if (s.wheelDx>0)
						w_coeff[p0+2]*=1.05
					elseif(s.wheelDx<0)
						w_coeff[p0+2]*=0.95
					endif
				endif
					
						
				// use scroll up/down to adjust amplitude
				// shift+scroll to adjust width 
				// shift key turns Dy into Dx, so take account of this!
				if(GetKeyState(0)&2^2)
					if (s.wheelDx>0)
						w_coeff[p0+1]*=1.05
					elseif(s.wheelDx<0)
						w_coeff[p0+1]*=0.95
					endif
				else
					if (s.wheelDy>0)
						w_coeff[p0+2+w_mouse[2]]*=1.05			
					elseif (s.wheelDy<0)
						w_coeff[p0+2+w_mouse[2]]*=0.95
					endif
				endif
				
				MF_updateFitWaves()
				hookresult=1 
			endif

			break
		case 1: // deactivate
			if (w_mouse[0])
				w_mouse[0]=0
				ModifyGraph /W=MFgraph rgb($"peak"+num2str(w_mouse[1])+"_"+num2str(w_mouse[2]))=(2,39321,1)
			endif
			break
	endswitch
	return hookResult	// If non-zero, we handled event and Igor will ignore it.
End