#pragma rtGlobals=3		// Use modern global access method and strict wave access.

// March 6, 2013
// Author: Andrew Achkar, University of Waterloo
// Version history: v1 - initial release, known issues: does not deal appropriately with multiple instances of same wave, textbox or other objects appearing on graphs being merged 

// mergeGraphs(winL,[styleFrom,printCmds]) takes the graphs listed in winL and creates execution code to generate a single graph window containing all traces in the original window list winL
// The optional styleFrom string instructs the function which window to copy the "style" settings from. 
// This excludes all individual trace settings and focuses on the appearance of the axes and the window itself.
// If styleFrom is left default, the first graph in winL is used to create appearance code
// Set printCmds=1 if you want to output the generated macros in a new notebook
Function mergeGraphs(winL,[styleFrom,printCmds]) 
	String winL, styleFrom
	Variable printCmds
	
	If(ParamIsDefault(styleFrom))
		styleFrom = StringFromList(0,winL)
	endif
	
	Variable i, numWins = ItemsInList(winL)
	String disp_cmds = "Window " + UniqueName("Graph",6,0) + "() : Graph \r \tPauseUpdate; Silent 1\t\t// building window...\r"
	String style_cmds = "Proc  " + UniqueName("Graph",6,0) + "Style() : Graph \r \tPauseUpdate; Silent 1\t\t// modifying window...\r"
	
	style_cmds += styleOnlyMacro(styleFrom)
	
	For(i=0;i<numWins;i+=1)
		disp_cmds += returnWindowStr(StringFromList(i,winL),i)
		style_cmds +=  getRecreationsFromTraceInfoList(getTraceInfoListFromWin(StringFromList(i,winL))) 
	endfor
	
	disp_cmds += "\r EndMacro"
	style_cmds += "\r EndMacro"
	
	if(printCmds==1)
		String name = UniqueName("Notebook",10,0)  
		Execute "NewNotebook /F=0 /N=" + name 
		Notebook $name text= disp_cmds + "\r\r" + style_cmds
	endif
	
	Execute /Q disp_cmds
	Execute /Q style_cmds
End

// This function returns the string containing all commands required to display the traces in the window win
// It uses WinRecreation(win,0), but strips away all commands irrelevant to the displaying of data
// It is aware of its place in the loop used to generate multiple commands and treats the case n=0 differently than n>0
// The reason for this is that for n>0 all Display commands need to be replaced by AppendToGraph 
Function /S returnWindowStr(win,n)
	String win	// Name of the window to recreate 
	Variable n	// n'th window being merged

	String line, win_cmd = "", win_rec=WinRecreation(win,0)
	Variable i, a, b, c, d, e, f
	
	for(i=0;i<ItemsInList(win_rec,"\r");i+=1)
		line = StringFromList(i,win_rec,"\r")
		
		// Instead of Display command use AppendToGraph,
		// Strip away window size defined by /W command
		if(n>=1 && strsearch(line, "Display",0) != -1 )
			line = RemoveByKey("/W",ReplaceString("Display", line , "AppendToGraph"),"=", " ")
		endif
		
		//Boolean variables that track whether line contains certain strings
		a=strsearch(line, "Window",0) == -1
		b=strsearch(line, "ModifyGraph",0) == -1
		c=strsearch(line, "ShowInfo",0) == -1
		d=strsearch(line, "PauseUpdate",0) == -1
		e=strsearch(line, "EndMacro",0) == -1
		f=strsearch(line, "fldrSav0",0) != -1
		
		//Change fldrSav0 string created by WinRecreation
		if(f)
			line = ReplaceString("fldrSav0", line, "fldrSav" + num2str(n))
		endif
		
		//Only take commands that involve generating plots
		If(a && b && c && d && e)
			win_cmd += line + "\r"
		endif
		
	endfor
	
	return win_cmd
End


// This function returns the TraceInfo for all traces in the window win, seperated by the character ^
// It also adds YWAVE and YWAVEDF to the usual TraceInfo output  
Function /S getTraceInfoListFromWin(win)
	String win

	String traceInfoList="", traceList = TraceNameList(win, ";", 1)
	Variable i, numTraces = ItemsInList(traceList)
	
	For(i=0;i<numTraces;i+=1)
		traceInfoList += "YWAVE:" + StringFromList(i,traceList) + ";"
		traceInfoList +=  "YWAVEDF:" + GetWavesDataFolder(WaveRefIndexed(win, i,1), 1 ) + ";" 
		traceInfoList += TraceInfo(win, StringFromList(i,traceList), 0) 
		traceInfoList += "^"
	EndFor	

	return traceInfoList
End

 // This function parses the string traceInfoList generated by getTraceInfoListFromWin(win) to return a style recreation macro
 // This generated code is verbose in the sense that all ModifyGraph commands are specifically pointed to the appropriate wave instead of the short-form notation often used
 Function /S getRecreationsFromTraceInfoList(traceInfoList)
	String traceInfoList
	
	String saveDF = GetDataFolder(1)

	Variable i, numTraces = ItemsInList(traceInfoList, "^")
	String recreationsList="", traceName
	Variable stringStop
	
	for(i=0;i<numTraces;i+=1)
		traceName =  StringByKey("YWAVE", StringFromList(i,traceInfoList,"^")) 
		stringStop = strsearch(StringFromList(i,traceInfoList,"^"),";RECREATION:",0)
		recreationsList += "\tSetDataFolder " + StringByKey("YWAVEDF", StringFromList(i,traceInfoList,"^")) + ";\r"
		recreationsList += modifyRecList(ReplaceString("(x)",StringFromList(i,traceInfoList,"^")[stringStop+strlen(";RECREATION:"),Inf], "(" + traceName + ")" ))
		recreationsList += "\tSetDataFolder " + saveDF + ";\r"
	endfor

	return recreationsList
End

// This utility parses the compact RECREATION string generated by TraceInfo and converts it into ModifyGraph /Z commands formatted for clear legibility 
Function /S modifyRecList(recreationsList)
	String recreationsList
	
	Variable i, numRecreateCmds = ItemsInList(recreationsList, ";")
	String modList =""
	
	for(i=0;i<numRecreateCmds;i+=1)
		modList += "\tModifyGraph /Z " + StringFromList(i,recreationsList) + "\r"
	endfor
	
	//print modList
	return modList	
End

// This function returns a macro containing only style commands relevant to the appearance of a given window and not specific to any of the traces it contains
// For instance, it will provide code to copy the ticks, grid, mirroring, labels, fonts, font sizes, etc. of a given window 
Function /S styleOnlyMacro(win)
	String win
	
	String styleStr="", winRecStr =  WinRecreation(win,1)
	String wantedFeatures = "grid;tick;zero;mirror;lowTrip;highTrip;fSize;gridStyle;minor;major;prescaleExp;standoff;btLen;btThick;stLen;stThick;ftLen;ftThick;ttLen;ttThick;gridStyle;manTick;manMinor;font;gridRBG;Label;"
	String line, feature
	
	Variable i,j, numFeatures = ItemsInList(wantedFeatures), numLines = ItemsInList(winRecStr,"\r")
	
	for(i=0;i<numLines;i+=1)
		for(j=0;j<numFeatures;j+=1)
			line = StringFromList(i,winRecStr,"\r")
			feature = StringFromList(j,wantedFeatures)
			
			if(strsearch(line, feature,0) != -1)
				styleStr += line + "\r"
				break;
			endif
		endfor
	endfor
	
	return styleStr
	
End