#pragma TextEncoding = "UTF-8"
#pragma rtGlobals=3		// Use modern global access method and strict wave access.

// generic text file (GTF) loader
// by tony.withers@uwo.ca
// GUI for choosing files to load and editing the names of waves to be created.
// this version assumes one wave per file.

// 21 Nov 2017 adapted for itx files. not tested.

menu "Macros" // a better place to put this would be in the Load Waves menu.
	"Load lots of itx files...", /Q, MakeGTFLoaderPanel()
end

function MakeGTFLoaderPanel()
	dowindow /k GTFLoaderPanel
	NewDataFolder /O root:Packages
	NewDataFolder /O root:Packages:GTF
	DFREF dfr=root:Packages:GTF
	
	make /o /n=(0,2)/T dfr:w_newList /WAVE=w_newList
	make /o/W/U /n=(3,5) dfr:w_color/WAVE=w_color
	w_color={{0,0,0},{65535,0,0},{0,65535,0},{0,0,65535},{0,65535,65535}}
	MatrixTranspose w_color	// easier to enter as 3 rows, 5 cols	
	make /o /n=(0,2,3) dfr:w_selection /WAVE=w_selection
	SetDimLabel 2,1,backColors,w_selection	// define plane 1 as background colors
	SetDimLabel 2,2,foreColors,w_selection
	
	make /o /n=2 /T dfr:w_titles /wave=w_titles
	w_titles={"file","output"}
	
	string /G dfr:s_edit=""
	
	NewPanel /K=1/N=GTFLoaderPanel/W=(20,20,710,380) as "GTF Loader"
	ModifyPanel /W=GTFLoaderPanel fixedSize=1, noedit=1

	button buttonSelectFiles win=GTFLoaderPanel, pos={10,10},size={80,20},title="select files",  proc=GTFButtons
	setvariable setvarLen win=GTFLoaderPanel, fsize=12, pos={450,10},size={230,20},title="character limit for wave names:",value=_NUM:29, limits={10,29,1}, proc=GTFSetvar
	ListBox listboxOut,win=GTFLoaderPanel, mode=9, selwave=w_selection, titlewave=w_titles, pos={10, 40},size={670, 280}, editstyle=1
	ListBox listboxOut,win=GTFLoaderPanel, colorwave=w_color, listwave=w_newList,widths={50,50}, fsize=12, proc=GTFListBox, userColumnResize=1
	Button buttonDoIt win=GTFLoaderPanel,pos={630,330},size={50,20},title="Do It",  proc=GTFButtons
	Button buttonCancel win=GTFLoaderPanel,pos={560,330},size={60,20},title="Cancel",  proc=GTFButtons
end

function GTFSetVar(s) : SetVariableControl
	STRUCT WMSetVariableAction &s
	
	if(s.eventCode==-1)
		return 0
	endif
	
	if(stringmatch(s.ctrlName, "setvarLen"))
		GTFSanityCheck()
	endif
	
end

function GTFButtons(ba)
	STRUCT WMButtonAction &ba
	
	DFREF dfr=root:Packages:GTF	
	wave /T w_newList=dfr:w_newList
	wave w_selection=dfr:w_selection
	wave w_color=dfr:w_color
	variable i
	
	switch( ba.eventCode )
		case 2: // mouse up		
			if(stringmatch(ba.ctrlName, "buttonSelectFiles"))	
				
				// ***** edited to select itx files: ******
				String fileFilters = "Data Files (*.itx):.itx;"
				open /D/R/F=fileFilters/MULT=1 refnum
				
				if(strlen(S_fileName)==0)
					return 0
				endif
				
				redimension /N=(itemsinlist(S_fileName,"\r"), 2) w_newList
				w_newList[][0]=stringfromlist(p,S_fileName,"\r")
				w_newList[][1]=parsefilepath(3, stringfromlist(p,S_fileName,"\r"), ":", 0,0)
				w_newList[][1]=selectstring (strlen(w_newList[p][1])>28, w_newList[p][1], (w_newList[p][1])[0,27])
				w_newList[][1]=cleanupname(w_newList[p][1],0)	
				redimension /n=(itemsinlist(S_fileName,"\r"),3,3) w_selection
				w_selection[][1][0]=2
				
				GTFSanityCheck()
			elseif(stringmatch(ba.ctrlName, "buttonDoIt"))		
				for(i=0;i<dimsize(w_newList, 0);i+=1)
					
					// ***** this stuff edited for loading itx files ********
					LoadWave/T  w_newList[i][0] // will throw up a dialog if we're attempting to overwrite a wave
					if(V_flag==0)
						continue
					endif
					
					string s_wave=StringFromList(0,s_wavenames)
					wave w=$s_wave
					if (cmpstr(s_wave, w_newList[i][1]))
						duplicate /o w $w_newList[i][1] // we've already given warning that waves will be overwritten here
						killwaves /Z w
					endif
					
				endfor
				dowindow /k GTFLoaderPanel			
			elseif(stringmatch(ba.ctrlName, "buttonCancel"))				
				dowindow /k GTFLoaderPanel
			endif
			break
		case -1: // control being killed
			break
	endswitch

	return 0
end

function GTFListBox(lba) : ListBoxControl
	STRUCT WMListboxAction &lba

	Variable row = lba.row
	Variable col = lba.col
	WAVE/T/Z listWave = lba.listWave
	WAVE/Z selWave = lba.selWave
	
	DFREF dfr=root:Packages:GTF
	SVAR s_edit=dfr:s_edit
	
	switch( lba.eventCode )
		case -1: // control being killed
			break
		case 1:
			selWave[][1][0]=selWave & ~1
			// stop edit when cell loses focus
			// so that bg color is visible
			break
		case 6: // begin edit
			s_edit=listWave[row][col]
			break
		case 7: // finish edit
			if(col==1)
				listWave[row][col]=CleanupName( listWave[row][col],0)			
				GTFSanityCheck()	
			endif
			break
	endswitch

	return 0
end

// check for name conflicts and highlight problematic names
function GTFSanityCheck()

	DFREF dfr=root:Packages:GTF	
	wave /T listWave=dfr:w_newList
	wave selWave=dfr:w_selection
	
	variable i,j,i_max=dimsize(listWave, 0)
	
	selWave[][1][%backcolors]=0
	
	// truncate names
	controlinfo /W=GTFLoaderPanel setvarLen
	listWave[][1]=selectstring(strlen(listWave[p][1])>v_value, listWave[p][1], (listWave[p][1])[0,v_value-1])
	
	for (i=0; i<i_max; i+=1)
		for (j=i+1; j<i_max; j+=1)
			if (stringmatch(listWave[i][1], listWave[j][1]))
				selWave[i][1][%backcolors]=1
				selWave[j][1][%backcolors]=1
			endif
		endfor
		if(waveexists($listWave[i][1]))
			selWave[i][1][%backcolors]=1
		endif
	endfor	
end