#pragma rtGlobals=1		// Use modern global access method.
//#pragma IndependentModule=DependencyAnalyzer

Menu "Analysis"
	"Analyze Procedure Dependencies",/Q,InitDependencyAnalyzer()
End

Function ComputeDependencies([dependsOn,dependedOn,sort_results])
	String dependsOn,dependedOn
	Variable sort_results
	NewDataFolder /O root:Packages
	NewDataFolder /O/S root:Packages:DependencyAnalyzer
	String procedures=WinList("*",";","WIN:128")
	if(ParamIsDefault(dependsOn))
		dependsOn=procedures
	endif
	if(ParamIsDefault(dependedOn))
		dependedOn=procedures
	endif
	Variable i,j
	Make /o/T/n=0 AllFunctions=""
	Variable num_proc_files=ItemsInList(procedures)
	// Get a list of functions defined in each procedure file.  
	for(i=0;i<num_proc_files;i+=1)
		String proc_file=StringFromList(i,procedures)
		//String cmd="print num2str(3)+FunctionList(\"*\",\";\",\"WIN:"+proc_file+"\")"
		//Execute cmd
		//print cmd
		String defined_functions=FunctionList("*",";","WIN:"+proc_file)
		proc_file=CleanupName("PF_"+RemoveEnding(proc_file,".ipf"),1)
		Make /o/T/n=(ItemsInList(defined_functions)) $proc_file=StringFromList(p,defined_functions)
		Concatenate /NP/T {$proc_file}, AllFunctions
	endfor
	// Get a list of functions used in each procedure file.  
	Variable num_depends=ItemsInList(dependsOn)
	Variable num_depended=ItemsInList(dependedOn)
	Make /o/n=(num_depends,num_depended) DependencyCounts=NaN
	Make /o/T/n=(num_depends,num_depended) DependencyDetails=""
	SetDrawLayer /W=DependencyAnalyzerPanel /K ProgBack
	DrawText /W=DependencyAnalyzerPanel 215,255,"0%"
	DoUpdate
	for(i=0;i<num_depends;i+=1)
		String proc_file1=StringFromList(i,dependsOn)
		proc_file1=CleanupName(RemoveEnding(proc_file1,".ipf"),1)
		for(j=0;j<num_depended;j+=1)
			String proc_file2=StringFromList(j,dependedOn)
			proc_file2=CleanupName(RemoveEnding(proc_file2,".ipf"),1)
			Variable count=0
			String details=""
			DependencyCount(proc_file1,proc_file2,count,details)
			DependencyCounts[i][j]=count
			DependencyDetails[i][j]=details
		endfor
		SetDrawLayer /W=DependencyAnalyzerPanel /K ProgBack
		DrawText /W=DependencyAnalyzerPanel 215,255,num2str(round((i+1)*100/num_depends))+"%"
		DoUpdate
	endfor
	SortDependencies(dependsOn,dependedOn,sort_results)
	DisplayDependencies()
End

Function DependencyCount(proc_file1,proc_file2,dependency_count,dependency_list)
	String proc_file1,proc_file2
	Variable &dependency_count
	String &dependency_list
	Wave /T AllFunctions
	Wave /T DefinedFunctions1=$("PF_"+proc_file1)
	Wave /T DefinedFunctions2=$("PF_"+proc_file2)
	Variable i,j
	for(i=0;i<numpnts(DefinedFunctions1);i+=1) // For each function defined by the first procedure file.  
		String defined_function1=DefinedFunctions1[i]
		String function_text=ProcedureText(defined_function1,0)
		Make /o/T/n=(ItemsInList(function_text,"\r")) FunctionText=StringFromList(p,function_text,"\r")
		DeletePoints 0,1,FunctionText // Exclude function title.  
		// Exclude comment lines.  Not yet implemented.  
		for(j=0;j<numpnts(FunctionText);j+=1)
			
		endfor
		// Find number of calls to functions definied by the second procedure file.   
		for(j=0;j<numpnts(DefinedFunctions2);j+=1)
			String defined_function2=DefinedFunctions2[j]
			Make /o/T/n=0 MatchingLines
			Grep /E=(defined_function2+"\(") FunctionText as $"MatchingLines"
			Wave /T MatchingLines
			Variable called=numpnts(MatchingLines)>0
			dependency_count+=called
			if(called)
				dependency_list+=defined_function1+" calls "+defined_function2+";"
			endif
		endfor
	endfor
	KillWaves /Z FunctionText,MatchingLines
	return 1
End

Function SortDependencies(depends_On,depended_On,do_sort)
	String depends_On,depended_On
	Variable do_sort
	Wave DependencyCounts
	Wave /T DependencyDetails
	Variable i,num_depends=ItemsInList(depends_On),num_depended=ItemsInList(depended_On)
	
	// Depended on.  
	Make /o/n=(num_depended) NumDependencies=NaN,DependencyIndex=p
	WaveStats /Q/M=1 DependencyCounts
	Variable total_depend=V_avg*V_npnts
	for(i=0;i<num_depended;i+=1)
		Duplicate /o/R=[][i,i] DependencyCounts $"DependedOn"; Wave DependedOn
		Redimension /n=(numpnts(DependedOn)) DependedOn
		Variable tiebreak=sum(DependedOn)/(total_depend-DependedOn[i])
		DependedOn=DependedOn>0
		NumDependencies[i]=sum(DependedOn)+tiebreak
	endfor
	if(do_sort)
		Sort /R NumDependencies,DependencyIndex
	endif
	String sorted_procedures=""
	for(i=0;i<ItemsInList(depended_on);i+=1)
		sorted_procedures+=StringFromList(DependencyIndex[i],depended_on)+";"
	endfor
	MatrixSort(DependencyCounts,1,DependencyIndex)
	LabelDependencies(DependencyCounts,sorted_procedures,1)
	TextMatrixSort(DependencyDetails,1,DependencyIndex)
	LabelDependencies(DependencyDetails,sorted_procedures,1)
	
	// Depends on.  
	Make /o/n=(num_depends) NumDependencies=NaN,DependencyIndex=p
	for(i=0;i<num_depends;i+=1)
		Duplicate /o/R=[i,i][] DependencyCounts $"DependOn"; Wave DependOn
		Redimension /n=(numpnts(DependOn)) DependOn
		tiebreak=sum(DependOn)/(total_depend-DependOn[i])
		DependOn=DependOn>0
		NumDependencies[i]=sum(DependOn)+tiebreak
	endfor
	if(do_sort)
		Sort /R NumDependencies,DependencyIndex
	endif
	sorted_procedures=""
	for(i=0;i<ItemsInList(depends_on);i+=1)
		sorted_procedures+=StringFromList(DependencyIndex[i],depends_on)+";"
	endfor
	MatrixSort(DependencyCounts,0,DependencyIndex)
	LabelDependencies(DependencyCounts,sorted_procedures,0)
	TextMatrixSort(DependencyDetails,0,DependencyIndex)
	LabelDependencies(DependencyDetails,sorted_procedures,0)
	KillWaves /Z NumDependencies,DependencyIndex,DependedOn,DependOn
End

Function LabelDependencies(DependencyCounts,proc_names,dim)
	Wave DependencyCounts
	String proc_names
	Variable dim
	Variable i,num_proc_files=ItemsInList(proc_names)
	for(i=0;i<num_proc_files;i+=1)
		String proc_file1=StringFromList(i,proc_names)
		proc_file1=RemoveEnding(proc_file1,".ipf")
		SetDimLabel dim,i,$proc_file1,DependencyCounts
	endfor
End

Function MatrixSort(MatrixToSort,dim,SortIndex)
	Wave MatrixToSort
	Variable dim
	Wave SortIndex
	Variable i
	Duplicate /o MatrixToSort SortedMatrix
	for(i=0;i<numpnts(SortIndex);i+=1)
		Variable index=SortIndex[i]
		if(dim==0) // Rows.  
			SortedMatrix[i][]=MatrixToSort[index][q]
		elseif(dim==1) // Columns.  
			SortedMatrix[][i]=MatrixToSort[p][index]
		endif
	endfor
	MatrixToSort=SortedMatrix
	KillWaves /Z SortedMatrix
End

Function TextMatrixSort(MatrixToSort,dim,SortIndex)
	Wave /T MatrixToSort
	Variable dim
	Wave SortIndex
	Variable i
	Duplicate /o/T MatrixToSort SortedMatrix
	for(i=0;i<numpnts(SortIndex);i+=1)
		Variable index=SortIndex[i]
		if(dim==0) // Rows.  
			SortedMatrix[i][]=MatrixToSort[index][q]
		elseif(dim==1) // Columns.  
			SortedMatrix[][i]=MatrixToSort[p][index]
		endif
	endfor
	MatrixToSort=SortedMatrix
	KillWaves /Z SortedMatrix
End

Function DisplayDependencies()
	SetDataFolder root:Packages:DependencyAnalyzer
	Wave DependencyCounts
	Wave /T DependencyDetails
	//print "---"
	Variable i,j
	Variable rows=dimsize(DependencyCounts,0)
	Variable columns=dimsize(DependencyCounts,1)
	DoWindow /K DependencyAnalyzerResults
	NewPanel /K=1 /N=DependencyAnalyzerResults /W=(100,100,225+columns*30,225+rows*25) as "Dependencies"
	SetDrawEnv textxjust=1,textyjust=1,save
	SetDrawEnv textrot=90,fstyle=2
	DrawText 10,25+rows*20/2,"Calls"
	SetDrawEnv textrot=0,fstyle=2
	DrawText 40+columns*25/2,12,"Called"
	Duplicate /o DependencyCounts DependencyCountListSelections
	Make /o/T/n=(rows,columns+1) DependencyCountsText="\JC"+num2str(DependencyCounts[p][q])
	DependencyCountsText[][columns]="\f01"+GetDimLabel(DependencyCounts,0,p)
	DependencyCountListSelections=0
	ListBox DependencyCountList, pos={30,25}, fsize=12,font="Arial",selWave=DependencyCountListSelections,listWave=DependencyCountsText, mode=0,proc=ShowFunctionDependencies
	Variable max_width=0
	for(i=0;i<rows;i+=1)
		String depends_on=GetDimLabel(DependencyCounts,0,i)
		max_width=max(max_width,FontSizeStringWidth("Arial",10,1,depends_on))
		
		for(j=0;j<columns;j+=1)
			String depended_on=GetDimLabel(DependencyCounts,1,j)
			if(i==0)
				SetDrawEnv textrot=90,fname="Arial",fsize=12,fstyle=1,textxjust=1,textyjust=2
				DrawText 42+j*25,30+18.5*rows,depended_on
				ListBox DependencyCountList,widths+={20}
			endif
			Variable cyclic=0
			if(FindDimLabel(DependencyCounts,0,depended_on)!=-2 && FindDimLabel(DependencyCounts,1,depends_on)!=-2) // If both procedure files were analyzed as callers and callees.  
				cyclic=DependencyCounts[%$depends_on][%$depended_on] && DependencyCounts[%$depended_on][%$depends_on] && !StringMatch(depends_on,depended_on)
				DependencyCountsText[i][j]=SelectString(cyclic,"","\K(65535,0,0)")+DependencyCountsText[i][j] // Bold and color red cyclic dependencies.  
			endif
			if(StringMatch(depends_on,depended_on))
				DependencyCountsText[i][j]=SelectString(DependencyCounts[i][j],"","\f02")+DependencyCountsText // Italicize remaining dependencies.  
			else
				DependencyCountsText[i][j]=SelectString(DependencyCounts[i][j],"","\f01")+DependencyCountsText // Bold remaining dependencies.  
			endif
		endfor
	endfor
	MoveWindow /W=DependencyAnalyzerResults 100,100,120+columns*25+max_width,225+rows*25
	ListBox DependencyCountList,fsize=12,size={columns*25+max_width+40,rows*18.5},widths+={max_width}
	SetDataFolder root:
End

Function ShowFunctionDependencies(lb) : ListBoxControl
	STRUCT WMListboxAction &lb
	if(lb.eventCode<0)
		return 0
	endif
	SetDataFolder root:Packages:DependencyAnalyzer
	Wave DependencyCounts
	if(!DependencyCounts[lb.row][lb.col])
		return 0
	endif
	String details=GetDependencyDetails(lb.row,lb.col)
	DoWindow /K DependencyAnalyzerDetails
	Variable height=min(ItemsInList(details)*25,400)
	NewPanel /N=DependencyAnalyzerDetails /K=1/W=(100,100,400,100+height)
	Make /o/T/n=(ItemsInList(details)) FunctionDependencies=StringFromList(p,details)
	ListBox DependencyCountList, pos={10,10}, size={280,height-10}, listWave=FunctionDependencies, mode=0,proc=GoToFunction
	SetDataFolder root:
End

Function GoToFunction(lb) : ListBoxControl
	STRUCT WMListboxAction &lb
	if(lb.eventCode<0)
		return 0
	endif
	Variable caller_index=lb.row-1
	Wave DependencyCounts=root:Packages:DependencyAnalyzer:DependencyCounts
	String caller_proc= GetDimLabel(DependencyCounts,0,caller_index)
	String caller_function=StringFromList(0,lb.ListWave[lb.row]," ")
	SVar all_procedures=root:Packages:DependencyAnalyzer:all_procedures
	String candidate_caller_procs=ListMatch(all_procedures,caller_proc+".ipf")+ListMatch(all_procedures,caller_proc)
	caller_proc=StringFromList(0,candidate_caller_procs) 
	DisplayProcedure /W=$(caller_proc) caller_function
End

Function /S GetDependencyDetails(i,j)
	Variable i,j
	Wave DependencyCounts=root:Packages:DependencyAnalyzer:DependencyCounts
	Wave /T DependencyDetails=root:Packages:DependencyAnalyzer:DependencyDetails
	String details="\f01"+GetDimLabel(DependencyCounts,0,i)+" -> "+GetDimLabel(DependencyCounts,1,j)
	details+=";"+DependencyDetails[i][j]
	return details
End

Function InitDependencyAnalyzer()
	DoWindow /K DependencyAnalyzerPanel
	NewDataFolder /O root:Packages
	NewDataFolder /O/S root:Packages:DependencyAnalyzer
	String /G all_procedures=WinList("*",";","WIN:128")
	NewPanel /K=1/N=DependencyAnalyzerPanel/W=(100,100,550,505) as "Dependency Analyzer"
	SelectProcFiles()
End

Function SelectProcFiles()
	SetDataFolder root:Packages:DependencyAnalyzer
	SVar all_procedures
	Make /o/T/n=(ItemsInList(all_procedures)) AllProcs=StringFromList(p,all_procedures)
	Make /o/n=(numpnts(AllProcs)) ProcSelections1,ProcSelections2
	SetDrawEnv textxjust=1,save
	DrawText 225,20,"Check to see if functions from..."
	SetDrawEnv fstyle=4
	DrawText 100,50,"These procedure files"
	DrawText 225,50,"call functions from"
	SetDrawEnv fstyle=4
	DrawText 350,50,"These procedure files"
	
	ListBox Callers pos={25,55},size={150,320},listWave=AllProcs,selWave=ProcSelections1,mode=4
	ListBox Callees pos={275,55},size={150,320},listWave=AllProcs,selWave=ProcSelections2,mode=4
	ProcSelections1=1 // Select All
	ProcSelections2=1 
	Button SelectAll1 pos={55,380},size={80,20},title="Select All",proc=SelectProcFilesButtons
	Button SelectAll2 pos={305,380},size={80,20},title="Select All",proc=SelectProcFilesButtons
	Button Compute pos={200,200},size={50,20},title="Compute",proc=SelectProcFilesButtons
	Checkbox SortCounts pos={188,225}, value=1, title="Sort Results"
End

Function SelectProcFilesButtons(ctrlName) : ButtonControl
	String ctrlName
	Wave ProcSelections1=root:Packages:DependencyAnalyzer:ProcSelections1
	Wave ProcSelections2=root:Packages:DependencyAnalyzer:ProcSelections2
	strswitch(ctrlName)
		case "Compute":
			Variable i
			String callers="",callees=""
			Wave /T AllProcs=root:Packages:DependencyAnalyzer:AllProcs
			for(i=0;i<numpnts(ProcSelections1);i+=1)
				if(ProcSelections1[i] & 1)
					callers+=AllProcs[i]+";"
				endif
				if(ProcSelections2[i] & 1)
					callees+=AllProcs[i]+";"
				endif
			endfor
			ControlInfo SortCounts
			ComputeDependencies(dependsOn=callers,dependedOn=callees,sort_results=V_Value)
			break
		case "SelectAll1":
			Wave ProcSelections1=root:Packages:DependencyAnalyzer:ProcSelections1
			ProcSelections1=1
			break
		case "SelectAll2":
			
			ProcSelections2=1
			break
	endswitch
End