#pragma rtGlobals=3		// Use modern global access method and strict wave access.

//Version 2.0
//-Added Color options

//\\\\\\\\\\\\\\\\\\\\\\\\\\\\\3D Panel Functions\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\
//\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\
Function menu_slice_panel()
	String sw
	Prompt sw, "Data Wave:",popup,"NONE;"+WaveList("!aux*",";","DIMS:3")
	
	DoPrompt "3D Data Wave",sw
	
	if (V_FLAG)
		return -1 //User Canceled
	endif
	
	if(cmpstr(sw,"NONE"))
		Wave w=$(NameofWave($sw))
		CreateSlicePanel(w)
	endif
end

Function CreateSlicePanel(w)		
	wave w
	
	setdatafolder root:
	
	variable nr, nc, nl,xi,yi,zi,dx,dy,dz
	string wnamestr,window_name
	string cmdstr
	
	nr = DimSize(w, 0)
	nc = DimSize(w, 1)
	nl = DimSize(w, 2)
	xi=DimOffset(w,0)
	yi=DimOffset(w,1)
	zi=DimOffset(w,2)
	dx=DimDelta(w,0)
	dy=DimDelta(w,1)
	dz=DimDelta(w,2)
	
	wnamestr = NameOfWave(w)
	
	Make /N=(nr,nc)/O $wnamestr + "a"	
	WAVE sla = $wnamestr + "a"
	Make /N=(nl,nc)/O $wnamestr + "b"
	WAVE slb = $wnamestr + "b"
	Make /N=(nr,nl)/O $wnamestr + "c"
	WAVE slc = $wnamestr + "c"
	
	Make/N=10 /O $(wNameStr + "slc")		
	WAVE cslc = $(wNameStr + "slc")
	cslc[2]=zi
	cslc[3]=xi
	cslc[6]=yi
	cslc[9]=DimOffset($wnamestr,1)
	
	Setscale/p x DimOffset(w, 0), DimDelta(w, 0), WaveUnits(w, 0), sla, slc		
	Setscale/p x DimOffset(w, 2), DimDelta(w, 2), WaveUnits(w, 2), slb
	Setscale/p y DimOffset(w, 1), DimDelta(w, 1), WaveUnits(w, 1), sla, slb
	Setscale/p y DimOffset(w, 2), DimDelta(w, 2), WaveUnits(w, 2), slc
	
	sprintf cmdstr, "%s[p][q][%s[0][0]]", wNameStr, wNameStr+"slc"			
	SetFormula sla , cmdstr
		
	sprintf cmdstr, "%s[%s[1][0]][q][p]", wNameStr, wNameStr+"slc"
	SetFormula slb , cmdstr

	sprintf cmdstr, "%s[p][%s[4][0]][q]", wNameStr, wNameStr+"slc"
	SetFormula slc , cmdstr
	
	window_name="sp_"+wnamestr
	Display/N=$window_name/W=(200, 200, 700,500)/K=1 as ("Slice Panel "+wnamestr)
	
	AppendImage sla
	AppendImage /b=bb slb
	AppendImage /b=bc /R slc
	ModifyImage '' ctab= {*,*,Grays,0}
	ModifyImage ''#1 ctab= {*,*,Grays,0}
	ModifyImage ''#2 ctab= {*,*,Grays,0}
	ModifyGraph axisEnab(bottom)={0,0.3},axisEnab(bb)={0.33,0.63};DelayUpdate
	ModifyGraph axisEnab(bc)={0.66,1},freePos(bb)=0,freePos(bc)=0;DelayUpdate
	ModifyGraph lblPos(bb)=40,lblPos(bc)=40
	
	ControlBar 48
	//Pixel
	SetVariable setvar0 pos={5,4},size={120,16},title="By Pixel: Scan",limits={0,nl-1,1},value=cslc[0],proc=csl_control_fun_var
	SetVariable setvar1 pos={128,4},size={75,16},title="Kx",limits={0,nr-1,1},value=cslc[1],proc=csl_control_fun_var
	SetVariable setlevel0 pos={212,4},size={90,16},title="Level",limits={0,nc-1,1},value=cslc[4],proc=csl_control_fun_var
	SetVariable setrange0 pos={337,4},size={90,16},title="Range",limits={0,nr-1,1},value=cslc[5],proc=csl_control_fun_var
	//Units
	SetVariable setvar2,pos={14,27},size={111,16},title="By Units: Tilt",limits={zi,zi+(nl-1)*dz,dz},value= cslc[2],proc=csl_control_fun_var
	SetVariable setvar3,pos={128,27},size={75,16},title="Kx",limits={xi,xi+(nr-1)*dx,dx},value= cslc[3],proc=csl_control_fun_var
	SetVariable setlevel1,pos={205,27},size={97,16},title="Energy",limits={yi,yi+(nc-1)*dy,0.005},value= cslc[6],proc=csl_control_fun_var
	SetVariable setrange1,pos={307,27},size={120,16},title="Range (meV)",limits={0,(nc-1)*1000*dy,1000*dy},value= cslc[7],proc=csl_control_fun_var

	SetVariable setFL pos={438,27},size={77,16},bodyWidth=60,title="EF",limits={-inf,inf,dy},value=cslc[8],proc=csl_control_fun_var
	Button export_button pos={442,4},size={70,20},title="Export",proc=csl_control_fun_but
	setvariable setvarwname pos={1,1},size={70,20},title="wname",value=_STR:wnamestr,disable=1
	
	
	//Color Options
	CheckBox checkinverse,pos={625,7},size={33,14},title="Inv",value= 0,proc=proc_check_3Dslc
	PopupMenu popupcolor,pos={519,4},size={100,21},bodyWidth=100,proc=proc_popup_3Dslc
	PopupMenu popupcolor,mode=1,value= #"\"*COLORTABLEPOPNONAMES*\""
	SetVariable setvarmax,pos={591,27},size={69,16},bodyWidth=45,title="Max",proc=proc_setvar_3Dslc
	SetVariable setvarmax,value= _NUM:100
	SetVariable setvarmin,pos={520,27},size={66,16},bodyWidth=45,title="Min",proc=proc_setvar_3Dslc
	SetVariable setvarmin,value= _NUM:0
	
	ShowInfo/W=$window_name
	Cursor/M/H=1/C=(65535,65535,0) A
	Cursor/M/H=1/C=(0,65535,65535) B
End

Function proc_setvar_3Dslc(sv) : SetVariableControl
	STRUCT WMSetVariableAction &sv
	
	if(sv.eventCode==2||sv.eventCode==1)
		string wdname=sv.win,color,wname
		
		variable maxval,minval,mn,mx,imax,imin,checked
		
		ControlInfo/W=$wdname setvarmax
		maxval=V_Value
		ControlInfo/W=$wdname setvarmin
		minval=V_Value
		ControlInfo/W=$wdname popupcolor
		color=S_Value
		ControlInfo/W=$wdname setvarwname
		wname=S_Value
		ControlInfo/W=$wdname checkinverse
		checked=V_Value
		
		ImageStats/M=1 $(wname+"a")
		imin=V_min
		imax=V_max
		mx=imin+(imax-imin)*(maxval/100)
		mn=imin+(imax-imin)*(minval/100)		
		ModifyImage/W=$wdname $(wname+"a") ctab={mn,mx,$color,checked}
		ImageStats/M=1 $(wname+"b")
		imin=V_min
		imax=V_max
		mx=imin+(imax-imin)*(maxval/100)
		mn=imin+(imax-imin)*(minval/100)		
		ModifyImage/W=$wdname $(wname+"b") ctab={mn,mx,$color,checked}
		ImageStats/M=1 $(wname+"c")
		imin=V_min
		imax=V_max
		mx=imin+(imax-imin)*(maxval/100)
		mn=imin+(imax-imin)*(minval/100)		
		ModifyImage/W=$wdname $(wname+"c") ctab={mn,mx,$color,checked}
	endif
End

Function proc_popup_3Dslc(pu) : PopupMenuControl
	STRUCT WMPopupAction &pu
	
	if(pu.eventCode==2)
		string wdname=pu.win,color,wname
		
		variable maxval,minval,mn,mx,imax,imin,checked
		
		ControlInfo/W=$wdname setvarmax
		maxval=V_Value
		ControlInfo/W=$wdname setvarmin
		minval=V_Value
		ControlInfo/W=$wdname popupcolor
		color=S_Value
		ControlInfo/W=$wdname setvarwname
		wname=S_Value
		ControlInfo/W=$wdname checkinverse
		checked=V_Value
		
		ImageStats/M=1 $(wname+"a")
		imin=V_min
		imax=V_max
		mx=imin+(imax-imin)*(maxval/100)
		mn=imin+(imax-imin)*(minval/100)		
		ModifyImage/W=$wdname $(wname+"a") ctab={mn,mx,$color,checked}
		ImageStats/M=1 $(wname+"b")
		imin=V_min
		imax=V_max
		mx=imin+(imax-imin)*(maxval/100)
		mn=imin+(imax-imin)*(minval/100)		
		ModifyImage/W=$wdname $(wname+"b") ctab={mn,mx,$color,checked}
		ImageStats/M=1 $(wname+"c")
		imin=V_min
		imax=V_max
		mx=imin+(imax-imin)*(maxval/100)
		mn=imin+(imax-imin)*(minval/100)		
		ModifyImage/W=$wdname $(wname+"c") ctab={mn,mx,$color,checked}
	endif
End

Function proc_check_3Dslc(cb) : CheckBoxControl
	STRUCT WMCheckboxAction &cb
	
	if(cb.eventCode==2)
		string wdname=cb.win,color,wname
		variable checked=cb.checked
		
		variable maxval,minval,mn,mx,imax,imin
		
		ControlInfo/W=$wdname setvarmax
		maxval=V_Value
		ControlInfo/W=$wdname setvarmin
		minval=V_Value
		ControlInfo/W=$wdname popupcolor
		color=S_Value
		ControlInfo/W=$wdname setvarwname
		wname=S_Value
		
		ImageStats/M=1 $(wname+"a")
		imin=V_min
		imax=V_max
		mx=imin+(imax-imin)*(maxval/100)
		mn=imin+(imax-imin)*(minval/100)		
		ModifyImage/W=$wdname $(wname+"a") ctab={mn,mx,$color,checked}
		ImageStats/M=1 $(wname+"b")
		imin=V_min
		imax=V_max
		mx=imin+(imax-imin)*(maxval/100)
		mn=imin+(imax-imin)*(minval/100)		
		ModifyImage/W=$wdname $(wname+"b") ctab={mn,mx,$color,checked}
		ImageStats/M=1 $(wname+"c")
		imin=V_min
		imax=V_max
		mx=imin+(imax-imin)*(maxval/100)
		mn=imin+(imax-imin)*(minval/100)		
		ModifyImage/W=$wdname $(wname+"c") ctab={mn,mx,$color,checked}
	endif
End

Function csl_control_fun_but(B_Struct) : ButtonControl
	STRUCT WMButtonAction &B_Struct
	
	SetDataFolder root:
	variable len,i
	string window_name=B_Struct.win
	string wname=window_name[3]
	len=strlen(B_Struct.win)
	for(i=4;i<len;i+=1)
		wname[i-3]=window_name[i]
	endfor
	
	if(B_Struct.eventCode==2)
		String out_wave=(wname+"_Img_2D"),wv_list,in_wave
		wv_list=wname+"a;"+wname+"b;"+wname+"c"
		Prompt in_wave, "Wave Image:",popup,wv_list
		Prompt out_wave,"New Name"
		DoPrompt "Export Image",in_wave,out_wave
	
		if(V_FLAG)
			return -1//User canceled
		endif
		
		Make/O/N=(DimSize($in_wave,0),DimSize($in_wave,1)) $out_wave
		Wave ow=$out_wave,iw=$in_wave
		SetScale/P x, DimOffset($in_wave,0),DimDelta($in_wave,0),WaveUnits($in_wave,0) ow
		SetScale/P y, DimOffset($in_wave,1),DimDelta($in_wave,1),WaveUnits($in_wave,1) ow
		ow=iw[p][q]
		create_2d_panel(wname_pass=NameofWave(ow),wave_change=2)
	elseif(B_Struct.eventCode==-1)
		RemoveImage/W=$window_name/Z $(wname+"a")
		RemoveImage/W=$window_name/Z $(wname+"b")
		RemoveImage/W=$window_name/Z $(wname+"c")
		KillWaves/Z $(wname+"a"),$(wname+"b"),$(wname+"c")
		KillWaves/Z $(wname+"slc")
	endif
end

Function csl_control_fun_var(SV_Struct):SetVariableControl
	STRUCT WMSetVariableAction &SV_Struct
	
	if((SV_Struct.eventCode==2)||(SV_Struct.eventCode==1))
		variable len,i
		string window_name=SV_Struct.win
		string wname=window_name[3]
		String ctrl=SV_Struct.ctrlName
		variable val=SV_Struct.dval
		len=strlen(SV_Struct.win)
		for(i=4;i<len;i+=1)
			wname[i-3]=window_name[i]
		endfor
		
		if(!cmpstr(ctrl[0,7],"setrange"))
			fs_reconstruction(wname,window_name,val,ctrl)
		elseif(!cmpstr(ctrl,"setFL"))
			set_fermi_level(wname,window_name,val)
		elseif(!cmpstr(ctrl[0,5],"setvar"))
			setvar_fun(wname,val,ctrl)
		elseif(!cmpstr(ctrl[0,7],"setlevel"))
			set_level_c(wname,val,ctrl)
		endif
	endif
end

Function setvar_fun(wname,val,ctrl)
	String wname
	Variable val
	String ctrl
	
	Variable num,aux
	Wave cslc=$(wname+"slc")//clsc[n];0=scan,1=kx pixel,2=tilt,3=kx units
	
	num=str2num(ctrl[6])
	Switch(num)
		Case 0://Scan
			cslc[2]=(DimOffset($wname,2)+val*DimDelta($wname,2))
			Break
		Case 1://Kx pixel
			cslc[3]=(DimOffset($wname,0)+val*DimDelta($wname,0))
			Break
		Case 2://Tilt
			cslc[0]=round((val-DimOffset($wname,2))/DimDelta($wname,2))
			Break
		Case 3://Kx Units
			cslc[1]=round((val-DimOffset($wname,0))/DimDelta($wname,0))
			Break
	endswitch
end

Function set_level_c(wname,val,ctrl)
	String wname
	Variable val
	String ctrl
	
	wave cslc=$(wname+"slc")
	String cmdstr
	Variable num=str2num(ctrl[8])
	
	if(num==1)
		cslc[4]=round((val-DimOffset($(wname+"a"),1))/DimDelta($(wname+"a"),1))
	else
		cslc[6]=DimOffset($(wname+"a"),1)+val*DimDelta($(wname+"a"),1)
	endif
	sprintf cmdstr, "%s[p][%s[4][0]][q]", wname, wname+"slc"
	SetFormula $(wname+"c") , cmdstr
end

Function set_fermi_level(wname,window_name,val)
	String wname
	String window_name
	Variable val
	
	Wave cslc=$(wname+"slc")
	
	SetScale/P y,DimOffset($wname,1)-val,DimDelta($wname,1),WaveUnits($wname,1) $(wname+"a")
	SetScale/P y,DimOffset($wname,1)-val,DimDelta($wname,1),WaveUnits($wname,1) $(wname+"b")
	ControlInfo/W=$window_name setlevel1
	cslc[6]=V_Value-val
	SetVariable/Z setlevel1 win=$window_name,limits={DimOffset($wname,1)-val,DimOffset($wname,1)-val+(DimSize($wname,1)-1)*DimDelta($wname,1),DimDelta($wname,1)}
	DoWindow/R $window_name
end

Function fs_reconstruction(wname,window_name,val,ctrl)
	String wname
	String window_name
	Variable val
	String ctrl
	
	String img_info,zmin,zmax,color,rev
	img_info=ImageInfo(window_name,wname+"c",0)
	String ctab_list=StringByKey("RECREATION:ctab",img_info,"=",";")
	Variable len=strlen(ctab_list)
	zmin=StringFromList(0,ctab_list[2,len-2],",")
	zmax=StringFromList(1,ctab_list[2,len-2],",")
	color=StringFromList(2,ctab_list[2,len-2],",")
	rev=StringFromList(3,ctab_list[2,len-2],",")
	
	Variable i
	wave tempw=root:$(wname+"c"),datawave=root:$wname,cslc=root:$(wname+"slc")
	if(str2num(ctrl[8])==1)//If by units
		val=round(val/(1000*DimDelta($wname,1)))
		cslc[5]=val
	else
		cslc[7]=val*1000*DimDelta($wname,1)//if by pixel
	endif
	
	if(((cslc[4]-val)<0)||((cslc[4]+val)>=DimSize($wname,1)))
		print "Out of Range "+wname
		print "Process ABORTED!"
		cslc[5]=0
		cslc[7]=0
		return -1
	else
		For(i=-val;i<=val;i+=1)
			tempw+=datawave[p][cslc[4]+i][q]
		Endfor
		if(val)
			tempw/=(2*val+1)
		endif
		Removeimage/W=$window_name $(wname+"c")
		Appendimage/W=$window_name/B=bc /R tempw
		ModifyGraph axisEnab(bc)={0.66,1},freePos(bc)=0;DelayUpdate
		ModifyGraph lblPos(bc)=40
		if((!cmpstr(zmin,"*"))&&(!cmpstr(zmax,"*")))
			ModifyImage/W=$window_name $(wname+"c") ctab={*,*,$color,str2num(rev)}
		elseif(!cmpstr(zmin,"*"))
			ModifyImage/W=$window_name $(wname+"c") ctab={*,str2num(zmax),$color,str2num(rev)}
		elseif(!cmpstr(zmax,"*"))
			ModifyImage/W=$window_name $(wname+"c") ctab={str2num(zmin),*,$color,str2num(rev)}
		else
			ModifyImage/W=$window_name $(wname+"c") ctab={str2num(zmin),str2num(zmax),$color,str2num(rev)}
		endif
		DoWindow/R $window_name
	endif
End