#pragma TextEncoding = "UTF-8"
#pragma rtGlobals=3				// Use modern global access method and strict wave access


//Basic Interface
Window Box_IT_Panel() : Panel
	PauseUpdate; Silent 1		// building window...
	SetUp_Package()
	NewPanel /K=1 /W=(647,148,1289,505) as "Nominal Data Manipulation"
	PopupMenu XWave,pos={45.00,128.00},size={114.00,20.00},proc=SetXWavePopUp
	PopupMenu XWave,title="Wave",fSize=14
	PopupMenu XWave,mode=7,popvalue="Text_A",value= #"wavelist(\"*\",\";\",\"\")"
	PopupMenu Xvar,pos={49.00,169.00},size={134.00,20.00},proc=SetXVarPopUp
	PopupMenu Xvar,title="X Variable",fSize=14
	PopupMenu Xvar,mode=1,popvalue="Data",value= #"pop_up_var_X()"
	PopupMenu Yvar,pos={39.00,296.00},size={134.00,20.00},proc=SetYVariablePopUp
	PopupMenu Yvar,title="Y Variable",fSize=14
	PopupMenu Yvar,mode=1,popvalue="Data",value= #"pop_up_var_Y()"
	Button Box_IT,pos={527.00,37.00},size={75.00,50.00},proc=Run_Do_It
	Button Box_IT,title="Do\rIt",fSize=18,fStyle=1,fColor=(0,0,65535)
	ListBox MarkerPick,pos={273.00,35.00},size={212.00,251.00},disable=2,fSize=14
	ListBox MarkerPick,listWave=root:Packages:Box_It:Markerlabels
	ListBox MarkerPick,selWave=root:Packages:Box_It:SelWave
	ListBox MarkerPick,colorWave=root:Packages:Box_It:MarkerColor,mode= 4
	PopupMenu Markerpop,pos={277.00,301.00},size={100.00,20.00},disable=2,proc=MarkerSet
	PopupMenu Markerpop,title="Marker",fSize=14,mode=17,value= #"\"*MARKERPOP*\""
	PopupMenu MarkerColor,pos={387.00,301.00},size={90.00,20.00},disable=2,proc=SetColor
	PopupMenu MarkerColor,title="Color",fSize=14
	PopupMenu MarkerColor,mode=1,popColor= (65535,32764,16385),value= #"\"*COLORPOP*\""
	GroupBox GroupX,pos={19.00,94.00},size={232.00,120.00},title="X Wave/Variable"
	GroupBox GroupX,fSize=18,fStyle=1
	GroupBox GroupY,pos={25.00,226.00},size={227.00,103.00},title="Y Wave/Variable"
	GroupBox GroupY,fSize=18,fStyle=1
	CheckBox DoMarkers,pos={25.00,45.00},size={56.00,26.00},proc=SetModeCheckBox
	CheckBox DoMarkers,title="\\JLNone\rMarkers",fSize=10,value= 0,mode=1
	CheckBox DoBox,pos={87.00,45.00},size={73.00,26.00},proc=SetModeCheckBox
	CheckBox DoBox,title="\\JLContinuous\rBox Plot",fSize=10,value= 1,mode=1
	CheckBox DoMosaic,pos={165.00,47.00},size={72.00,26.00},proc=SetModeCheckBox
	CheckBox DoMosaic,title="\\JLNominal\rMosaic Plot",fSize=10,value= 0,mode=1
	TitleBox MarkerNote,pos={280.00,329.00},size={156.00,19.00}
	TitleBox MarkerNote,title="Hold Modifier Key to Clear Marker"
	PopupMenu Ywave,pos={39.00,258.00},size={149.00,20.00},proc=SetYWavePopUp
	PopupMenu Ywave,title="Wave",fSize=14
	PopupMenu Ywave,mode=1,popvalue="Single_Var_A",value= #"Pop_up_y_wave()"
	Button SendAnnotationToClip,pos={527.00,96.00},size={75.00,30.00},proc=SaveAnnotationTextButton
	Button SendAnnotationToClip,title="Save Legend\rto Clipboard",fSize=9
	GroupBox ModeGroup,pos={13.00,9.00},size={250.00,81.00},title="Mode Selection"
	GroupBox ModeGroup,fSize=18,fStyle=1
EndMacro

Function SetUp_Package()

	If(!DatafolderExists("root:Packages:Box_It"))
		NewDataFolder/O root:Packages
		NewDataFolder/O root:Packages:Box_It
		NewDataFolder/O root:Packages:Box_It:Mosaic
		Make/O/T /N =7 root:Packages:Box_It:PopUpSelection=""
		Wave/T PopupSelection =root:Packages:Box_It:PopUpSelection
		Setlabels("Xwave;Xvar;Ywave;Yvar;Mode;xType;Ytype",PopUpSelection,0)
		Make/O /N=10 root:Packages:Box_It:MarkerWave
		Make/O/T /N=(10,2) root:Packages:Box_It:Markerlabels
		Make/O/n=(10,2,2) root:packages:box_It:SelWave=0
		Make/W/U/O/n=(10,4) root:packages:box_It:MarkerColor
	endif


end

//Interface Controls
Function SetModeCheckBox(cba) : CheckBoxControl
	STRUCT WMCheckboxAction &cba

	Wave/T PopUpSelection = root:packages:box_it:popupSelection
	String ButtonGroup ="DoMarkers;DoBox;DoMosaic"
	String thepick
	Variable i
	switch( cba.eventCode )
		case 2: // mouse up
			Variable checked = cba.checked
			for(i=0;i<3;i+=1)
				thepick = stringfromlist(i,ButtonGroup)
				checkbox $thepick value=stringmatch(cba.ctrlname,thepick)
			endfor
			popupMenu yvar disable=(stringmatch(cba.ctrlname,"DoMarkers")? 2 : 0)
			popupMenu ywave disable=(stringmatch(cba.ctrlname,"DoMarkers")? 2 : 0)
			popupselection[%mode] = cba.ctrlName
			strswitch(cba.ctrlName)
				case "DoMarkers":
					listbox markerpick disable=0
					popupMenu Markerpop disable=0
					popupMenu MarkerColor disable=0

					break
				case "DoBox":
					listbox markerpick disable=2
					popupMenu Markerpop disable=2
					popupMenu MarkerColor disable=2

					break
				case "DoMosaic":
					listbox markerpick disable=0
					popupMenu Markerpop disable=2
					popupMenu MarkerColor disable=0

					break
			endswitch
			break
		case -1: // control being killed
			break
	endswitch

	return 0
End

//X Wave uses generic wavelist to fill
Function SetXWavePopUp(pa) : PopupMenuControl
	STRUCT WMPopupAction &pa


	Wave/T PopUpSelection = root:packages:box_it:popupSelection
	switch( pa.eventCode )
		case 2: // mouse up
			Variable popNum = pa.popNum
			String popStr = pa.popStr
			//Populate entry into lookup wave
			PopUpSelection[%$pa.ctrlName]=popStr
			Wave TypeTest =$popstr
			PopUpSelection[%xType] = returntype(TypeTest)
			break
		case -1: // control being killed
			break
	endswitch

	return 0
End

Function/T pop_up_var_X()

	//Decision Process: Which is Used Base Data where it is either a text wave or numeric, the data row dimension labels if they exist, or 2d wave the column names
	Variable index,maxindex
	string labelstring=""
	Wave/T PopupSelection =root:Packages:Box_It:PopUpSelection
	wave input=$popupselection[%xwave]
	if(waveExists(input))
		//Does it have row labels
		if(hasRowLabels(input,0))
			labelstring +="Row Labels;"
		endif
		if(waveDims(input)==1)//Used only for 1D waves
			labelstring +="Data;"
		endif
		//Does it Column Labels
		if(hasrowLabels(input,1))
			maxindex=dimsize(input,1)
			for(index=0;index<maxindex;index+=1)
				labelstring +=getdimLabel(input,1,index)+";"
			endfor
		endif
		string filter
	endif
	return labelstring
End


Function SetXVarPopUp(pa) : PopupMenuControl
	STRUCT WMPopupAction &pa

	//This sets the list in the X variable popup
	Wave/T PopUpSelection = root:packages:box_it:popupSelection
	switch( pa.eventCode )
		case 2: // mouse up
			Variable popNum = pa.popNum
			String popStr = pa.popStr
			//Populate entry into lookup wave
			PopUpSelection[%$pa.ctrlName]=popStr
			if(stringMatch(PopUpSelection[%Mode],"DoMarkers"))

				list_Box_Set_Up()
			endif
			break
		case -1: // control being killed
			break
	endswitch

	return 0
End



Function/T pop_up_y_Wave()

	Wave/T PopupSelection =root:Packages:Box_It:PopUpSelection
	controlinfo Xwave
	wave xwave=$S_Value
	string filter=""
	controlinfo DoBox//Check for continuous response
	Variable req_pnts = dimsize(xwave,0)
	if(V_Value)
		sprintf filter,"MAXROWS:%d,MINROWS:%d,TEXT:0",req_pnts,req_pnts
	else
		sprintf filter,"MAXROWS:%d,MINROWS:%d",req_pnts,req_pnts
	endif
	return wavelist("*",";",filter)
End

Function SetYWavePopUp(pa) : PopupMenuControl
	STRUCT WMPopupAction &pa

	Wave/T PopUpSelection = root:packages:box_it:popupSelection
	switch( pa.eventCode )
		case 2: // mouse up
			Variable popNum = pa.popNum
			String popStr = pa.popStr
			//Populate entry into lookup wave
			PopUpSelection[%$pa.ctrlName]=popStr
			Wave TypeTest =$popstr
			PopUpSelection[%yType] = returntype(TypeTest)

			break
		case -1: // control being killed
			break
	endswitch

	return 0
End


Function/T pop_up_var_Y()

	//Decision Process: Which is Used Base Data where it is either a text wave or numeric, the data row dimension labels if they exist, or 2d wave the column names
	Wave/T SL =root:Packages:Box_It:PopUpSelection
	wave input=$sl[%ywave]
	Variable index,maxindex
	string labelstring=""
	if(Waveexists(input))
		//Does it have row labels
		if(hasRowLabels(input,0) && !stringmatch(SL[%mode],"DoBox"))
			labelstring +="Row Labels;"
		endif
		if(waveDims(input)==1)//Used only for 1D waves
			labelstring +="Data;"
		endif
		//Does it Column Labels
		if(hasrowLabels(input,1))
			maxindex=dimsize(input,1)
			for(index=0;index<maxindex;index+=1)
				labelstring +=getdimLabel(input,1,index)+";"
			endfor
		endif
	endif

	return labelstring
End

Function SetYVariablePopUp(pa) : PopupMenuControl
	STRUCT WMPopupAction &pa

	
	Wave/T PopUpSelection = root:packages:box_it:popupSelection

	switch( pa.eventCode )
		case 2: // mouse up
			Variable popNum = pa.popNum
			String popStr = pa.popStr
			//Populate entry into lookup wave
			PopUpSelection[%$pa.ctrlName]=popStr
				list_Box_Set_Up()

			break
		case -1: // control being killed
			break
	endswitch

	return 0
End



Function MarkerSet(pa) : PopupMenuControl
	STRUCT WMPopupAction &pa

	DFREF BI=root:packages:box_It
	switch( pa.eventCode )
		case 2: // mouse up
			Variable popNum = pa.popNum
			String popStr = pa.popStr
			Wave selwave = BI:selwave
			Wave Markerwave = BI:MarkerWave
			Wave/T markerlabels = BI:MarkerLabels
			string markerstring
			sprintf markerstring,"\W5%03d",(popNum-1)
			Variable keys = GetKeyState(0)

			if (keys == 0)
				Markerwave = selwave[p][0][0]? (popNum-1) : Markerwave
				MarkerLabels[][%Marker] =SelectString(Selwave[p],MarkerLabels[p][%Marker],markerstring)
			else
				Markerwave = selwave[p][0][0]? 0 : Markerwave
				MarkerLabels[][%Marker] =SelectString(Selwave[p],MarkerLabels[p][%Marker],"")
			endif
			break
		case -1: // control being killed
			break
	endswitch

	return 0
End

Function SetColor(pa) : PopupMenuControl
	STRUCT WMPopupAction &pa

	switch( pa.eventCode )
		case 2: // mouse up
			Variable popNum = pa.popNum
			String popStr = pa.popStr
			Wave MarkerColor=root:packages:box_it:MarkerColor
			Wave selwave=root:packages:box_it:selwave
			ControlInfo MarkerColor
			MarkerColor[1,][%red] = selwave[p-1][0][0]? V_Red : MarkerColor[p][%red]
			MarkerColor[1,][%Blue] = selwave[p-1][0][0]? V_Blue : MarkerColor[p][%Blue]
			MarkerColor[1,][%Green] = selwave[p-1][0][0]? V_Green : MarkerColor[p][%Green]
			MarkerColor[1,][%Alpha] = selwave[p-1][0][0]? V_Alpha : MarkerColor[p][%Alpha]
			
			break
		case -1: // control being killed
			break
	endswitch

	return 0
End

Function Run_Do_It(ba) : ButtonControl
	STRUCT WMButtonAction &ba

	
	switch( ba.eventCode )
		case 2: // mouse up
			// click code here
			Controlinfo DoMarkers
			If(V_value)
				Make_Markers_Colors()
				break
			endif
			ControlInfo DoBox
			If(V_value)
				Make_Box_Plot()
				break
			endif
			ControlInfo DoMosaic
			If(V_value)
				Make_Mosaic_plot()
				break
			endif

			break
		case -1: // control being killed
			break
	endswitch

	return 0
End

//Wave Manipulation Functions


Function List_Box_Set_Up()


	DFREF BI=root:packages:Box_it
	Wave/T SL = BI:popupSelection
	wave tempX = $SL[%xwave]
	Make/FREE/T /N=(dimsize(tempx,0)) TotalText
	String Which ="y"
	if(stringMatch(SL[%mode],"DoMarkers"))
		Which = "X"
	endif
	String WhichVar=Which+"var"

	//Handle row labels seperately since I don't need to know type
	Wave Subject =$SL[%$(Which+"wave")]

	if(stringMatch(SL[%$WhichVar],"Row Labels"))
		Totaltext =getdimLabel(Subject,0,p)
	else
		if(stringMatch(SL[%$(Which+"Type")],"Numeric"))
			Wave SubNum =$(SL[%$(Which+"wave")])
			if(stringMatch(SL[%$WhichVar],"Data"))
				totaltext = num2str(SubNum[p])
			else

				totaltext[]=num2str(subNum[p][%$SL[%$WhichVar]])
			endif
		else
			Wave/T SubTx=$(SL[%$(Which+"wave")])
			if(stringMatch(SL[%$WhichVar],"Data"))
				totaltext = subtx
			else
				totaltext[]=subtx[p][%$SL[%$WhichVar]]
			endif
		endif
	endif


	Findduplicates/FREE /RT=input Totaltext
	Sort Input,Input
	Duplicate/O Input, BI:MarkerLabels
	Wave/T markerlabels = BI:MarkerLabels
	Redimension /n=(-1,2) markerlabels
	setdimLabel 1,0,$SL[%xwave],MarkerLabels
	setdimLabel 1,1,Marker,Markerlabels

	Make/O/n=(numpnts(input)) BI:MarkerWave=0
	Wave Markerwave = BI:MarkerWave

	Make/O/n=(numpnts(input),2,2) BI:SelWave=0
	Wave selwave = BI:SelWave
	SetDimLabel 2,1,foreColors,SelWave
	selwave[][][1]=p+1

	Make/W/U/O/n=(numpnts(input),4) BI:MarkerColor
	Wave MarkerColor=BI:MarkerColor
	String ColorList="Red;Green;Blue;Alpha"
	SetLabels(ColorList,MarkerColor,1)
	//set default colors
	MarkerColor[][%Red] 		= Mod(p,3)==0? 64000 : 0
	MarkerColor[][%Green]	= Mod((p+1),3)==0? 64000 : 0
	MarkerColor[][%Blue]		= Mod((p+2),3)==0? 64000 : 0
	MarkerColor[][3]= 64000

	String inputlist
	wfprintf inputlist, "%s;", input
	SetLabels(inputlist,markerlabels,0)
	SetLabels(inputlist,MarkerWave,0)
	SetLabels(inputlist,MarkerColor,0)
	SetLabels(inputlist,SelWave,0)
	Insertpoints/M=0 0,1,MarkerColor
	
	strswitch(sl[%mode])
		case "DoMarkers":
			String DefaultMarkers ="\W5008;\W5019;\W5005;\W5016;\W5006;\W5017;\W5022;\W5023"
			markerlabels[][1] = stringFromList(mod(p,8),DefaultMarkers)
			MarkerWave[] = str2num(stringFromList(mod(p,8),DefaultMarkers)[4,5])
			break
		case "DoBox":
			markerlabels[][] = ""
			break
		case "DoMosaic":
			markerlabels[][1] = "\W5016"
			break
	endswitch
End

//Marker Color Functions

Function	Make_Markers_Colors()

	DFREF BI=root:packages:Box_it
	Wave/T SL = BI:popupSelection
	Wave MarkerColor = BI:MarkerColor
	Wave MarkerWave = BI:MarkerWave
	
	//make a list of IDs
	variable index,maxindex
	Maxindex= numpnts(MarkerWave)
	string TheList=""
	For(index=0;index<maxindex;index+=1)
		thelist += GetDimLabel(MarkerWave, 0, index )+";"
	endfor
	String NameBase =SL[%xwave]+"_"+SL[%xvar]
	Wave/T xtemp=textWave_Return("x")
	Make/O/n=(numpnts(xtemp)) $(NameBase+"_MK"),$(NameBase+"_CL")
	Wave MK =$(NameBase+"_MK")
	Wave MC =$(NameBase+"_CL")
	MC = WhichListItem(xtemp[p],thelist)
	MK = MarkerWave[WhichlistItem(xtemp[p],thelist)]
	duplicate/O/R=[1,][] MarkerColor, $(NameBase+"_Key")
	Wave temp=$(NameBase+"_Key")
	setscale/P x,0,1,temp

End


//Box Plot Functions

Function Make_Box_plot()

	Wave/T SL = root:packages:box_it:popupSelection
	If(!stringMatch(SL[%ytype],"Numeric"))
		Abort "Not Numeric Y"
	endif
	
	wave tempX = $SL[%xwave]
	Make/FREE/T /N=(dimsize(tempx,0)) TotalText
	String Which ="x"
	String WhichVar=Which+"var"

	//Handle row labels seperately since I don't need to know type
	Wave Subject =$SL[%$(Which+"wave")]

	if(stringMatch(SL[%$WhichVar],"Row Labels"))
		Totaltext =getdimLabel(Subject,0,p)
	else
		if(stringMatch(SL[%$(Which+"Type")],"Numeric"))
			Wave SubNum =$(SL[%$(Which+"wave")])
			if(stringMatch(SL[%$WhichVar],"Data"))
				totaltext = num2str(SubNum[p])
			else

				totaltext[]=num2str(subNum[p][%$SL[%$WhichVar]])
			endif
		else
			Wave/T SubTx=$(SL[%$(Which+"wave")])
			if(stringMatch(SL[%$WhichVar],"Data"))
				totaltext = subtx
			else
				totaltext[]=subtx[p][%$SL[%$WhichVar]]
			endif
		endif
	endif
	Wave Inwave = $SL[%ywave]
	
	If(StringMatch(SL[%yVar],"Data"))
		NewBox(Inwave,TotalText)
	Else
		Variable thecol
		thecol =findDimLabel(inWave,1,SL[%yVar])
		MAtrixop/O/FREE inputCol=col(InWave,thecol)
		NewBox(inputcol,totaltext)
	
	endif
	
End

Function NewBox(Inwave,LabelWave)
	wave Inwave
	wave/t labelwave
	
	DFREF BI=root:packages:Box_it
	Wave/T SL = BI:popupSelection
	//get then labels
	Findduplicates/FREE /RT=textlabels Labelwave
	sort /A=1 textlabels, textlabels
	variable index,maxindex,points,maxpoints
	maxindex= numpnts(textLabels)
	
	Make/O /n=(numpnts(Inwave),maxindex) BI:Generic
	Wave results = BI:Generic
	results =NaN
	For(index=0;index<maxindex;index+=1)
		SetDimLabel 1,index,$textlabels[index],results
		extract/FREE inWave, tempwave, !cmpstr(labelwave,textlabels[index])
		points = numpnts(tempwave)-1
		results[0,points][index]=tempwave[p]
		maxpoints = max(maxpoints,points)
	endfor
	redimension /N=(maxpoints,-1) results
	doWindow/F Box_Viewer
	if(!V_Flag)
		Display/W=(129,60,980,612)/N=Box_Viewer/k=1 as "Box View";AppendBoxPlot/CATL results
		Label bottom (SL[%xwave]+" "+SL[%Xvar])
		Label Left (SL[%Ywave]+" "+SL[%Yvar])
		Controlbar 50
		Button SaveToLocal title="Save To Local",size={100,20},proc=SaveLocalfromBox_it, pos={14,12}
	endif
end



//Mosaic Functions

Function	Make_Mosaic_plot()

	Make_Mosaic(TextWave_Return("x"),TextWave_Return("y"))
	Mosaic_Graph()

End


Function Make_Mosaic(XText,Ytext)
	wave /T Xtext,Ytext
	
	DFREF Mo=root:Packages:box_it:Mosaic
	Findduplicates /RT=mo:Xitems Xtext
	Findduplicates /RT=Mo:Yitems YText
	Wave/T xItems=Mo:XItems
	Wave/T yItems=Mo:Yitems
	sort xItems,xItems
	sort yItems,yItems
	//Make Convolution Matrix & use free after debug
	Make/O/FREE /N=(Numpnts(Xitems),Numpnts(YItems)) CMatrix=0
	//set the labels
	setlabels(twave_2_list(Xitems),Cmatrix,0)
	setlabels(twave_2_list(Yitems),Cmatrix,1)
	Variable index,maxindex,itext,textmax
	Maxindex= numpnts(Xitems)
	for(index =0;index<maxindex;index+=1)
		extract/FREE/O Ytext, ytemp, stringmatch(Xtext,Xitems[index])
		texthistogram/FREE /DN=TextCount /DT=TextName ytemp
		textmax = numpnts(TextName)
		for(itext=0;itext<textmax;itext+=1)
			CMatrix[%$Xitems[index]][%$TextName[iText]] = TextCount[iText]
		endfor
		
	endfor
	Make_map(cMatrix,Xitems)
end

Function Make_Map(CMatrix,xItems)
	wave CMatrix
	Wave/T xItems
	
	DFREF Mo=root:Packages:box_it:Mosaic
	//Make Base Map
	Make/O /n=(101,101) Mo:Mosaic_Map=0
	Wave Mosaic_Map =Mo:Mosaic_Map
	Variable TotalItems,Xstep,Ystep,maxXstep,maxYstep
	TotalItems = sum(Cmatrix)
	MaxXStep= Dimsize(CMatrix,0)
	MaxYStep= dimsize(CMatrix,1)
	
	Duplicate/O/FREE Cmatrix, CMatrix_col //Use Free after debug
	Integrate/Dim=1 /Meth=2 Cmatrix /D=Cmatrix_col
	Duplicate/O/FREE Cmatrix_col, yLevels
	ylevels[][]=cmatrix_col[p][q]*100/cmatrix_col[p][MaxYstep]
	Make/O Mo:xLevels
	Wave xLevels = Mo:xLevels
	MatrixOp/FREE/O Xtemp=sumrows(cMatrix)
	Integrate/Meth=2 Xtemp /D=xLevels
	xLevels =floor(xLevels[p]*100/sum(cMatrix))
	For(xStep=0;xstep<MaxXstep;Xstep+=1)
		For(Ystep=0;Ystep<maxYstep;Ystep+=1)
		Mosaic_Map[xLevels[xstep],xLevels[Xstep+1]][yLevels[Xstep][Ystep],yLevels[Xstep][Ystep+1]]=Ystep
		endfor
	endfor
	//Make Marker Locations
	Make/O /N=(numpnts(Xitems)) Mo:XLabelPos
	Wave xLabelpos= Mo:xLabelpos
	xlabelpos =(xLevels[p]+xlevels[p+1])/2
	Wave MarkerColor = root:Packages:box_it:markercolor
	Duplicate/O /R=[1,] MarkerColor, Mo:MarkerColor
	Wave temp=Mo:MarkerColor
	setscale/P x,0,1,temp

End

Function  Mosaic_Graph()

	DFREF Mo=root:Packages:box_it:Mosaic
	Wave/T yItems =Mo:yItems
	Make/O /n=(numpnts(yItems)) mo:ypos
	Wave yPos = Mo:yPos
	yPos = p
	Wave xLevels =mo:xlevels
	doWindow/F Mosaic_Plot
	if(!V_Flag)

		Display/K=1 /N=Mosaic_Plot /W=(129,60,980,612)
		Controlbar 50
		Button SaveToLocal title="Save To Local",size={100,20},proc=SaveLocalfromBox_it, pos={14,12}
		AppendImage Mo:Mosaic_Map
		ModifyImage Mosaic_Map cindex= Mo:MarkerColor
		ModifyGraph userticks(bottom)={Mo:XLabelPos,Mo:Xitems}
		ModifyGraph mirror=0
		ModifyGraph axOffset(left)=4.75
		ColorScale /N=text0/F=0/A=MC/X=-60.00/Y=-2.66 cindex=Mo:MarkerColor
		ColorScale/C/N=text0 userTicks={mo:ypos,mo:Yitems}, axisRange={(WaveMin(Mo:Ypos)-0.5),(wavemax(Mo:yPos)+.5),0}
		drawdividers(xlevels)
	endif
End


Function DrawDividers(xlevels)
	wave xLevels
	
	Variable index,maxindex
	Maxindex=numpnts(xLevels)-1
	for (index=1;index<maxindex;index+=1)
		SetDrawEnv xcoord=bottom
		DrawLine (floor(xlevels[index])-.5),0,(floor(xlevels[index])-.5),1
	endfor
End

//Auxiliary Functions 
Function RandomInt(from, to)
	Variable from, to
	Variable amp = to - from
	return floor(from + mod(abs(enoise(100*amp)), amp+1))
End


Function/T twave_2_List(tw)
	wave/T tw

	String list
	wfprintf list, "%s;", tw
	return list
End

Function SetLabels(ListIn,WaveIn,Dim,[strict])
	String ListIn // assume ; delimited string
	Wave WaveIn // Wave to be labeled
	Variable Dim //Which dimension to label
	Variable Strict //Checks length
	
	//Check to see if lengths match
	if(!paramIsDefault(strict))
		If(itemsInList(ListIn)!=Dimsize(WaveIn,Dim))
			Abort "Lengths don't match"
		Endif
	endif
	
	Variable index,maxindex
	Maxindex = ItemsInList(ListIn)
	
	For(index=0;index<maxindex;index+=1)
		Setdimlabel dim, index,$stringFromList(index,ListIn), WaveIn
	endfor
End



Function HasRowLabels(input,Dim)
	wave input
	Variable Dim
	
	return strlen(GetDimLabel(input, Dim, 1 ))>0
end

Function/T MarkerAnnotationText()

	wave/T ML = root:packages:box_it:markerlabels
	wave MC = root:packages:box_it:markerColor
	String Thetext=""
	String ColorText,ColorMarker
	variable index, maxindex
	maxindex = dimsize(ML,0)
	for(index=0;index<maxindex;index+=1)
		sprintf ColorText,"\K(%d,%d,%d)",MC[index+1][%Red],MC[index+1][%Green],MC[index+1][%Blue]
		ColorMarker = ReplaceString("K", Colortext, "k"  , 1 )
		thetext+=colortext+ML[index][0]+"\t"+colormarker+ML[index][%marker]+"\r"
	endfor
	thetext = removeEnding(thetext)
	return thetext
End

Function/T ReturnType(input)
	wave input
	
	If(wavetype(input,1)==1)
		return "Numeric"
	elseif (wavetype(input,1)==2)
		return "Text"
	else
		return "None"
	endif
End



Function SaveLocalfromBox_it(ba) : ButtonControl
	STRUCT WMButtonAction &ba

	DFREF Mo=root:Packages:box_it:Mosaic
	DFREF BI=root:Packages:box_it
	Wave/T SL = BI:popupSelection

	switch( ba.eventCode )
		case 2: // mouse up
			// click code here
			strswitch(ba.win)
				case "Box_Viewer":
					Wave Generic = BI:Generic
					Duplicate/O Generic, $(sl[%xwave]+"_"+SL[%ywave]+"_Box")
					Wave btemp =$(sl[%xwave]+"_"+SL[%ywave]+"_Box")
					
					Note btemp, provenance()

					break
				case "Mosaic_Plot":
					DFREF Current = getDataFolderDFR()
					DuplicateDataFolder MO, Current:$(SL[%xwave]+"_"+Sl[%yWave]+"_map")
					setdataFolder Current:$(SL[%xwave]+"_"+Sl[%yWave]+"_map")
						string history = provenance()
						String thelist = wavelist("*",";","")
						variable index,maxindex
						maxindex = itemsInList(thelist)
						for(index=0;index<maxindex;index+=1)
							wave temp = $stringfromList(index,thelist)
							Note temp, history
						endfor
					SetdataFolder Current
					break
			endswitch
			break
		case -1: // control being killed
			break
	endswitch

	return 0
End

Function SaveAnnotationTextButton(ba) : ButtonControl
	STRUCT WMButtonAction &ba

	switch( ba.eventCode )
		case 2: // mouse up
			// click code here
			putScrapText markerannotationtext()
			break
		case -1: // control being killed
			break
	endswitch

	return 0
End


function DragReorder(STRUCT WMListboxAction &lba):Listboxcontrol
     
    if(lba.eventCode==2) // mouseup
        ListBox $lba.ctrlName, win=$lba.win, userdata(drag)=""
    endif

    if(lba.eventCode==1) // mousedown
        ListBox $lba.ctrlName, win=$lba.win, userdata(drag)=num2str(lba.row)
        //userdata(drag) indicates dragging is active, cleared on mouseup
    endif
              
    if(lba.eventCode==4) // selection of lba.row
        variable dragNum=str2num(GetUserData(lba.win,lba.ctrlName,"drag"))        
        if(numtype(dragNum)!=0 || min(dragNum,lba.row)<0 || max(dragNum,lba.row)>=numpnts(lba.listwave))
            return 0
        endif
        Duplicate /free lba.selwave order
        order[][0] = x
        order[dragNum][0] = (lba.row>dragNum) ? lba.row+0.5 : lba.row-0.5
        Sort order, lba.listwave
        ListBox $lba.ctrlName, win=$lba.win, userdata(drag)=num2str(lba.row)
    endif
end

Function /Wave TextWave_Return(Which)
	String Which
	
	Wave/T SL = root:packages:box_it:popupSelection
	wave tempX = $SL[%xwave]
	Make/FREE/T /N=(dimsize(tempx,0)) TotalText
	String dWave,dVar,dType
	dWave	= SL[%$(Which+"wave")]
	dVar 	= SL[%$Which+"var"]
	dType	= SL[%$(Which+"Type")]

	//Handle row labels seperately since I don't need to know type
	Wave Subject =$dWave

	if(stringMatch(dVar,"Row Labels"))
		Totaltext =getdimLabel(Subject,0,p)
	else
		if(stringMatch(dType,"Numeric"))
			Wave SubNum =$dWave
			if(stringMatch(dVar,"Data"))
				totaltext = num2str(SubNum[p])
			else

				totaltext[]=num2str(subNum[p][%$dVar])
			endif
		else
			Wave/T SubTx=$dWave
			if(stringMatch(dVAr,"Data"))
				totaltext = subtx
			else
				totaltext[]=subtx[p][%$dVar]
			endif
		endif
	endif

	return TotalText
End

Function/S provenance()

	String History=""
	Wave/T SL = root:packages:box_it:popupSelection
	Variable Index,maxindex
	maxindex = numpnts(sl)
	for (index=0;index<maxindex;index+=1)
		history =ReplaceStringByKey((getdimLabel(sl,0,index)),History,sl[index])
	Endfor
	return history
End