#pragma TextEncoding = "UTF-8"
#pragma rtGlobals=3
#pragma version=1.01b

// generic text file (GTF) loader
// https://www.wavemetrics.com/user/tony
// GUI for choosing files to load and editing the names of waves to be created.


static constant kNwaves=3 // number of waves to load from each file
static constant kOptionalX=2 // make one of the columns optional (column number, 1-based).

menu "Macros" // a better place to put this would be in the Load Waves menu.
	"Load lots of text files...", /Q, MakeGTFLoaderPanel()
end


function MakeGTFLoaderPanel()
	
	dowindow /k GTFLoaderPanel
	NewDataFolder /O root:Packages
	NewDataFolder /O root:Packages:GTF
	DFREF dfr=root:Packages:GTF
	
	variable nColumns=1+kNwaves+(kOptionalX>0)
	variable success
	
	make /o /n=(0,nColumns)/T dfr:w_newList /WAVE=w_newList
	make /o/W/U /n=(3,5) dfr:w_color/WAVE=w_color
	w_color={{0,0,0},{65535,0,0},{39321,39321,39321},{0,0,65535},{0,65535,65535}}
	MatrixTranspose w_color	// easier to enter as 3 rows, 5 cols	
	make /o /n=(0,nColumns,3) dfr:w_selection /WAVE=w_selection
	SetDimLabel 2,1,backColors,w_selection	// define plane 1 as background colors
	SetDimLabel 2,2,foreColors,w_selection
	
	make /o /n=(nColumns) /T dfr:w_titles /wave=w_titles
	w_titles=""
	w_titles[0]="file"
	if(kOptionalX)
		w_titles[kOptionalX]="x?"
	endif
	w_titles=selectstring(stringmatch(w_titles, ""), w_titles, "output")
	
	string /G dfr:s_edit=""
	
	success=GTFselectFiles()
	if(!success)
		return 0
	endif
	GTFSanityCheck()
	
	NewPanel /K=1/N=GTFLoaderPanel/W=(20,20,710,380) as "GTF Loader"
	ModifyPanel /W=GTFLoaderPanel fixedSize=1, noedit=1

	button buttonSelectFiles win=GTFLoaderPanel, pos={10,10},size={80,20},title="select files",  proc=GTFButtons
	setvariable setvarLen win=GTFLoaderPanel, fsize=12, pos={450,10},size={230,20},title="character limit for wave names:",value=_NUM:29, limits={10,29,1}, proc=GTFSetvar
	ListBox listboxOut,win=GTFLoaderPanel, mode=9, selwave=w_selection, titlewave=w_titles, pos={10, 40},size={670, 280}, editstyle=1
	ListBox listboxOut,win=GTFLoaderPanel, colorwave=w_color, listwave=w_newList, fsize=12, proc=GTFListBox, userColumnResize=1
	ListBox listboxOut,win=GTFLoaderPanel, widths={10,2}
	Button buttonDoIt win=GTFLoaderPanel,pos={630,330},size={50,20},title="Do It",  proc=GTFButtons
	Button buttonCancel win=GTFLoaderPanel,pos={560,330},size={60,20},title="Cancel",  proc=GTFButtons
end

function GTFSetVar(s) : SetVariableControl
	STRUCT WMSetVariableAction &s
	
	if(s.eventCode==-1)
		return 0
	endif
	
	if(stringmatch(s.ctrlName, "setvarLen"))
		GTFSanityCheck()
	endif	
end

function GTFButtons(ba)
	STRUCT WMButtonAction &ba
	
	DFREF dfr=root:Packages:GTF	
	wave /T w_newList=dfr:w_newList
	wave w_selection=dfr:w_selection
	wave w_color=dfr:w_color
	variable i, j
	
	if(ba.eventCode!=2)
		return 0
	endif
	
	if(stringmatch(ba.ctrlName, "buttonSelectFiles"))	
		variable success=GTFselectFiles()
		if(!success)
			return 0
		endif
		GTFSanityCheck()
	elseif(stringmatch(ba.ctrlName, "buttonDoIt"))		
		// ------  code for loading waves goes here  ------
		string columnInfoStr=""	
		for(i=0;i<dimsize(w_newList, 0);i+=1)
			
			// build columninfostring for each row
			columnInfoStr=""
			for (j=1;j<dimsize(w_newList, 1);j+=1)
				if(kOptionalX)
					if(j==kOptionalX)
						continue
					endif
					if(j==(kOptionalX+1) && !(w_selection[i][j][0]&0x10) )
						sprintf columnInfoStr, "%sN=\"_skip_\";", columnInfoStr
						continue
					endif
				endif
				sprintf columnInfoStr, "%sN=%s,C=1,F=0;", columnInfoStr, w_newList[i][j]	
			endfor
			
			
			// newpath /O/Q loadPath, parsefilepath(1,w_newList[i][0],":",1,0)	
			//sprintf columnInfoStr, "C=1,F=0,N=%s;C=1,F=0,N=%s;", w_newList[i][2]+"_wn", w_newList[i][2]
			//variable wn= (w_selection[i][1][0]&0x10) ? 1 : 0
			loadwave /J/B=columnInfoStr/O/A w_newList[i][0]		
			
		endfor
		// ------------------------------------------------
		dowindow /k GTFLoaderPanel			
	elseif(stringmatch(ba.ctrlName, "buttonCancel"))				
		dowindow /k GTFLoaderPanel
	endif


	return 0
end


function GTFselectFiles()
	
	DFREF dfr=root:Packages:GTF	
	wave /T w_newList=dfr:w_newList
	wave w_selection=dfr:w_selection
	variable j
	
	String fileFilters = "Data Files (*.txt,*.dat,*.csv):.txt,.dat,.csv;All Files:.*;"
	open /D/R/F=fileFilters/MULT=1 refnum
	
	if(strlen(S_fileName)==0)
		return 0
	endif
	
	variable nColumns=1+kNwaves+(kOptionalX>0)		
	redimension /N=(itemsinlist(S_fileName,"\r"), nColumns) w_newList
	redimension /n=(itemsinlist(S_fileName,"\r"),nColumns,3) w_selection
	
	w_newList[][0]=stringfromlist(p,S_fileName,"\r")
	
	variable count=0
	j=1
	do  // j is column count
		//count=0
		if(j!=kOptionalX)
			w_newList[][j]=parsefilepath(3, stringfromlist(p,S_fileName,"\r"), ":", 0,0)
			w_newList[][j]=selectstring (strlen(w_newList[p][j])>28, w_newList[p][j], (w_newList[p][j])[0,27])
			w_newList[][j]=cleanupname(w_newList[p][j],0)
			if(kOptionalX && (j==(kOptionalX+1)))
				w_newList[][j]+="_x"
			else
				
				if(count)
					w_newList[][j]+="_"+num2str(count)
				endif
				count+=1
			endif
			
			w_selection[][j][0]=2
		endif
		j+=1
	while(j<nColumns)
	
	if(kOptionalX)
		w_selection[][kOptionalX][0]=0x30
	endif
	return 1
end


function GTFListBox(lba) : ListBoxControl
	STRUCT WMListboxAction &lba

	Variable row = lba.row
	Variable col = lba.col
	WAVE/T/Z listWave = lba.listWave
	WAVE/Z selWave = lba.selWave
	
	DFREF dfr=root:Packages:GTF
	SVAR s_edit=dfr:s_edit
	
//	if(col==kOptionalX)
//		selWave[row][col+1][%forecolors]= selWave[row][col][0]&0x10 ? 0 : 2
//		GTFSanityCheck()
//	endif
	
	
	switch( lba.eventCode )
		case -1: // control being killed
			break
		case 1:
			selWave[][1,][0]=selWave & ~1
			// stop edit when cell loses focus
			// so that bg color is visible
			break
		case 6: // begin edit
			s_edit=listWave[row][col]
			break
		case 7: // finish edit
			if(col && (col!=kOptionalX))
				listWave[row][col]=CleanupName( listWave[row][col],0)			
				GTFSanityCheck()	
			endif
			break
		case 13: // checkbox
			if(lba.eventMod&2) // shift click
				selWave[][kOptionalX][0]=selWave[row][kOptionalX][0]
			endif
			GTFSanityCheck()
			break
	endswitch

	return 0
end

// check for name conflicts and highlight problematic names
function GTFSanityCheck()

	DFREF dfr=root:Packages:GTF	
	wave /T listWave=dfr:w_newList
	wave selWave=dfr:w_selection
	
	variable i,j,k,m,i_max=dimsize(listWave, 0), k_max=dimsize(listWave, 1)
	
	selWave[][1,][%backcolors]=0
	if(kOptionalX)
		selWave[][kOptionalX+1][%forecolors]= selWave[p][kOptionalX][0]&0x10 ? 0 : 2
	endif
	
	// truncate names
	controlinfo /W=GTFLoaderPanel setvarLen
	listWave[][1,]=selectstring(strlen(listWave[p][q])>v_value, listWave[p][q], (listWave[p][q])[0,v_value-1])
	
	// i = row count, j = remaining row count, k = column count, m = remaining column count
	for (i=0; i<i_max; i+=1)
		for (k=1;k<k_max;k+=1)
			if (k==kOptionalX)	
				continue
			endif
			if(kOptionalX && kOptionalX==(k-1))
				if(!(selWave[i][k-1][0]&0x10))
					continue
				endif
			endif
			
			
			for (j=i; j<i_max; j+=1)
				for (m=1;m<k_max;m+=1)
					if((i==j)&&(k==m))
						continue
					endif
					if(kOptionalX && kOptionalX==(m-1))
						if(!(selWave[j][m-1][0]&0x10))
							continue
						endif
					endif
					if (stringmatch(listWave[i][k], listWave[j][m]))
						selWave[i][k][%backcolors]=1
						selWave[j][m][%backcolors]=1
					endif
				endfor
			endfor
			if(waveexists($listWave[i][k]))
				selWave[i][k][%backcolors]=1
			endif
		endfor
	endfor	
end