#pragma rtGlobals=3		// Use modern global access method and strict wave access.

// Test for managing lots of graph windows. Assign graphs to "groups".
// Can show/hide graphs based on group. Shift-click to select more than one group.
// Use window note to store information on which group the graph belongs to.

// Also show graphs that only have graph macros (graph has been closed)
// When "Show" is clicked, also bring those windows to front.
// Kill graphs that are being hidden that also have a graph macro??? Not done yet.

// Ken Aikin
// NOAA Chemical Sciences Division
// 20151214

Menu "Macros"
	"---"		// separate from other menu items if they are used by other macros that users have.
	"Init Manage Graphs"
	"Tile Graphs"
	"---"
end

macro InitManageGraphs()
	InitGraphGroups()
	ManageGraphsPanel()
	ButtonProc_updateGrList("")	// call the function that updates the list of graphs and populates listbox1
end

// Run once to set up at beginning of session. Creates DF and waves to contain info.
macro InitGraphGroups()
	Silent 1
	NewDataFolder/O root:GraphGroupStuff
	Make/T/O/N=1 root:GraphGroupStuff:GraphGroup_names="_none_"	//waves for Graph Group listbox list0. Init value to "_none_" which is used for clearing assignment to selected graphs.
	Make/O/N=1 root:GraphGroupStuff:GraphGroup_selections
	
	Make/T/O/N=0 root:GraphGroupStuff:grListWave	//waves for Graph listbox list1
	Make/T/O/N=0 root:GraphGroupStuff:grTitleWave
	Make/O/N=0 root:GraphGroupStuff:grSelWave
end

// Loops thru every graph and prompts for which Group to assign it to.
macro AssignGraphsToGroups_All()
	string wname, wlist, GraphGroupList
	
	silent 1

	GraphGroupList = GraphGroupsToList()
	
	wlist = sortlist(WinList("*", ";", "WIN:1"), ";", 16)
	setWindowNotes(GraphGroupList, wlist)
end

// Loops thru all graphs that don't have a graph note and prompts for which Group to assign them to.
function AssignGraphsToGroups()
	variable n,num
	string wname, wlist, GraphGroupList, unAssignedList=""
	
	GraphGroupList = GraphGroupsToList()					// list of all groups in Groups List.
	
	wlist = sortlist(WinList("*", ";", "WIN:1"), ";", 16)	//sort list alpha-numerically
	num = ItemsInList(wlist)

	for(n=0; n<num; n+=1)	//loop through all graphs and find ones with no Group assigned.
		wname = StringFromList(n, wlist)

		GetWindow $wname note		// graph note gets returned in S_Value
		if (strlen(S_Value)==0)	// no graph note
			unAssignedList += wname+";"		// add to list
			//PRINT "Found un-assigned graph ", wname
		endif
	endfor
	
	if (strlen(unAssignedList)>0)
		setWindowNotes(GraphGroupList, unAssignedList)	// pass in list of all Groups, and un-assigned graphs.
	else
		DoAlert 0, "No un-assigned graphs found." 
	endif
end

// Sets window note. Pass in list of Groups and list of graph windows.
function setWindowNotes(GraphGroupList, wlist)
	string GraphGroupList, wlist
	
	variable n, num, origLeft, origRight, origTop, origBottom
	variable tempLeft, tempRight, tempTop, tempBottom
	string wname, groupStr
	
	num = ItemsInList(wlist)
	for(n=0; n<num; n+=1)
		wname = StringFromList(n, wlist)
		getwindow $wname wsize	//get original position and size. Use if I decide to move graphs to upper left corner for viewing while assigning Groups.
		origLeft=V_left; origRight=V_right; origTop=V_top; origBottom=V_bottom
		MoveWindow/W=$wname 10, 10, 400, 200
		ModifyGraph/W=$wname wbRGB=(50000,65535,50000)
		DoWindow/F $wname		// bring window to front.
		Prompt groupStr, wname+": Choose Group: ", popup GraphGroupList
		DoPrompt "Set GraphGroups", groupStr	// Choose one of the Groups for that graph.
		if (V_Flag)
			Movewindow/W=$wname origLeft, origTop, origRight, origBottom	//if use movewindow above, restore here.
			ModifyGraph/W=$wname wbRGB=(65535,65535,65535)			// Do these 2 lines here in case user cancels before the restore can be done below.
			return -1								// User canceled
		endif

		Movewindow/W=$wname origLeft, origTop, origRight, origBottom	//if use movewindow above, restore here.
		ModifyGraph/W=$wname wbRGB=(65535,65535,65535)
		if (cmpstr(groupStr, "_none_")!=0)
			SetWindow $wname note=groupStr	// set window note for graph to the selected group
		else
			SetWindow $wname note=""			// _none_ was selected, so clear the window note.
		endif
	endfor
end

// Get the list of GraphGroups and return it in a list.
function/S GraphGroupsToList()
	variable n, len
	string GroupList=""
	
	wave/T GroupNames = root:GraphGroupStuff:GraphGroup_names
	
	len = numpnts(GroupNames)
	for(n=0; n<len; n+=1)
		GroupList+=GroupNames[n]+";"
	endfor
	return GroupList
end

// Clear graph notes for all graphs in list
function ClearWindowNotes(wlist)
	string wlist
	
	variable n, num
	string wname
	
	num = ItemsInList(wlist)
	for(n=0; n<num; n+=1)
		wname = StringFromList(n, wlist)
		SetWindow $wname note=""
	endfor
end

// Show all the graph windows belonging to the selected Groups
function ShowWindows(GraphGroupName)	//pass in list of Groups to show.
	string GraphGroupName
	
	variable n, num, count
	string wlist, wname
	
	wlist = sortlist(WinList("*", ";", "WIN:1"), ";", 16)
	num = ItemsInList(wlist)

	for(n=0; n<num; n+=1)
		wname = StringFromList(n, wlist)

		GetWindow $wname note
		if (WhichListItem(S_Value, GraphGroupName)!=-1)	// if that graph note is in the list of Groups
			DoWindow/F/HIDE=0 $wname						// show graph and bring to front.
			count+=1
		else
			DoWindow/HIDE=1 $wname							// hide graph
		endif
	endfor
	
	if (count==0)
		Print "No graphs were shown because none were assigned to group", GraphGroupName
	endif
end

// Hide all the graph windows belonging to the selected Group(s)
function HideWindows(GraphGroupName)	//pass in list of Groups to show.
	string GraphGroupName
	
	variable n, num, count
	string wlist, wname
	
	wlist = sortlist(WinList("*", ";", "WIN:1"), ";", 16)
	num = ItemsInList(wlist)

	for(n=0; n<num; n+=1)
		wname = StringFromList(n, wlist)

		GetWindow $wname note
		if (WhichListItem(S_Value, GraphGroupName)!=-1)	// if that graph note is in the list of Groups
			DoWindow/HIDE=1 $wname							// hide graph
			count+=1
		endif
	endfor

	if (count==0)
		Print "No graphs were hidden because none were assigned to group", GraphGroupName
	endif
end

// Make text waves of graph names and corresponding graph note.
function showWindowNotes()
	string wlist, wname
	variable n, num

	wlist = sortlist(WinList("*", ";", "WIN:1"), ";", 16)
	num = ItemsInList(wlist)

	Make/T/O/N=(num) root:GraphGroupStuff:GraphListWave, root:GraphGroupStuff:GraphNoteWave
	wave/T GraphListWave = root:GraphGroupStuff:GraphListWave, GraphNoteWave = root:GraphGroupStuff:GraphNoteWave

	for(n=0; n<num; n+=1)	// loop over all graphs
		wname = StringFromList(n, wlist)
		GetWindow $wname wtitle		// get the graph title
		GraphListWave[n] = S_Value	// put title into text wave
		GetWindow $wname note			// get graph note
		if (strlen(S_Value)>0)
			GraphNoteWave[n] = S_Value	// put graph note into text wave
		else
			GraphNoteWave[n] = ""			// prevents error when there is no graph note.
		endif
	endfor
	Edit GraphListWave, GraphNoteWave		// make table for user to view settings. (Editting table doesn't change graph notes).
end

// Button proc for the "Show" button. Shows all graphs in selected group(s)
Function ButtonProc_Show(ctrlName) : ButtonControl
	String ctrlName

	variable n, len
	string selectedNames=""
	
	wave/T GroupNames = root:GraphGroupStuff:GraphGroup_names
	wave sel = root:GraphGroupStuff:GraphGroup_selections

	len = numpnts(sel)
	for(n=0; n<len; n+=1)	// get list of Group names that are selected in panel.
		if(sel[n]==1)
			selectedNames+=GroupNames[n]+";"
		endif
	endfor
	
	ShowWindows(selectedNames)	//pass the list to the function that shows only the graphs are assigned to that group.
	GetGraphMacros(selectedNames)
End

// Opposite of above. Hides graphs that are in the selected Group.
// Button proc for the "Hide" button. Hides all graphs in selected group(s)
Function ButtonProc_Hide(ctrlName) : ButtonControl
	String ctrlName
	
	variable n, len
	string selectedNames=""
	
	wave/T GroupNames = root:GraphGroupStuff:GraphGroup_names
	wave sel = root:GraphGroupStuff:GraphGroup_selections

	len = numpnts(sel)
	for(n=0; n<len; n+=1)	// create list of selected Groups
		if(sel[n]==1)
			selectedNames+=GroupNames[n]+";"
		endif
	endfor
	HideWindows(selectedNames)
End

// Button proc for "All" to clear all graph notes.
Function ButtonProc_ClearAll(ctrlName) : ButtonControl
	String ctrlName

	string wlist = sortlist(WinList("*", ";", "WIN:1"), ";", 16)
	ClearWindowNotes(wlist)
	Print "Unassigned graphs from all groups."
End

// Button proc for "Selected" to clear graph notes only for graphs assigned to selected group(s).
Function ButtonProc_ClearSelected(ctrlName) : ButtonControl
	String ctrlName
	
	variable n, num, len
	string wlist, wname, selectedGraphGroups="", graphsInSelectedGroups=""
	
	wave/T GroupNames = root:GraphGroupStuff:GraphGroup_names
	wave sel = root:GraphGroupStuff:GraphGroup_selections

	len = numpnts(sel)
	for(n=0; n<len; n+=1)	// create list of selected groups
		if(sel[n]==1)
			selectedGraphGroups+=GroupNames[n]+";"
		endif
	endfor

	wlist = sortlist(WinList("*", ";", "WIN:1"), ";", 16)
	num = ItemsInList(wlist)

	for(n=0; n<num; n+=1)	// loop thru all graphs and see if they belong to selected group.
		wname = StringFromList(n, wlist)

		GetWindow $wname note
		if (WhichListItem(S_Value, selectedGraphGroups)!=-1)	// if that graph note is in the list of groups
			graphsInSelectedGroups += wname+";"					// add to list
		endif
	endfor
	ClearWindowNotes(graphsInSelectedGroups)
	
	Print "Unassigned graphs from group(s) ", selectedGraphGroups
End

// Add a new group to the list.
Function ButtonProc_AddToList(ctrlName) : ButtonControl
	String ctrlName

	variable len
	String Gname
	
	wave/T Gnames = root:GraphGroupStuff:GraphGroup_names
	wave sel = root:GraphGroupStuff:GraphGroup_selections
	
	ControlInfo setvarAddGF
	Gname = S_value
	
	if (strlen(Gname)>0)
		len = numpnts(sel)
		Redimension/N=(len+1) sel, Gnames		// add a new row to waves
		Gnames[len] = Gname						// put new group name into text wave
		SetVariable setvarAddGF value= _STR:""		// clear the text box.
	endif
End

Function ButtonProc_Edit(ctrlName) : ButtonControl
	String ctrlName

	wave/T Gnames = root:GraphGroupStuff:GraphGroup_names
	wave sel = root:GraphGroupStuff:GraphGroup_selections

	Edit Gnames, sel
End

Window ManageGraphsPanel() : Panel
	PauseUpdate; Silent 1		// building window...
	NewPanel /W=(719,44,1294,453)
	SetDrawLayer UserBack
	SetDrawEnv fsize= 10
	DrawText 309,293,"Clear groups:"
	SetDrawEnv fsize= 10
	DrawText 250,268,"Assign graphs to groups:"
	SetDrawEnv fsize= 10
	DrawText 377,135,"Graphs in selected group"
	SetVariable setvarAddGF,pos={380,19},size={168,16},title="New group",fSize=10
	SetVariable setvarAddGF,value= _STR:""
	Button button0,pos={380,38},size={86,20},proc=ButtonProc_AddToList,title="Add To List"
	ListBox list0,pos={245,29},size={105,100}
	ListBox list0,listWave=root:GraphGroupStuff:GraphGroup_names
	ListBox list0,selWave=root:GraphGroupStuff:GraphGroup_selections,mode= 4
	ListBox list0,userColumnResize= 1
	Button button1,pos={377,97},size={50,20},proc=ButtonProc_Show,title="Show"
	Button buttonHide,pos={438,97},size={50,20},proc=ButtonProc_Hide,title="Hide"
	Button buttonAll,pos={381,277},size={50,20},proc=ButtonProc_ClearAll,title="All"
	Button buttonSelected,pos={444,276},size={63,20},proc=ButtonProc_ClearSelected,title="Selected"
	GroupBox group0,pos={232,11},size={131,126},title="Groups",fSize=10,fStyle=1
	Button button2,pos={380,62},size={63,20},proc=ButtonProc_Edit,title="Edit List"
	Button button4,pos={381,251},size={50,20},proc=ButtonProc_AssignAll,title="All"
	Button button5,pos={444,251},size={81,20},proc=ButtonProc_AssignSelected,title="UnAssigned"
	GroupBox group1,pos={239,231},size={313,71},title="Loop through graphs to assign/clear them to/from groups"
	GroupBox group1,fSize=10,fStyle=1
	Button button6,pos={257,319},size={281,20},proc=ButtonProc_viewListOfGraphs,title="View  List of Graph and Group Assignments"
	ListBox list1,pos={12,11},size={200,330},proc=ListBoxProc,frame=2
	ListBox list1,listWave=root:GraphGroupStuff:grListWave
	ListBox list1,selWave=root:GraphGroupStuff:grSelWave,mode= 9,special= {1,0,0}
	Button button3,pos={62,374},size={80,20},proc=ButtonProc_updateGrList,title="Update List"
	Button button7,pos={272,156},size={233,20},proc=ButtonProc_ManAssign,title="Assign Graph(s) to Selected Group"
	CheckBox checkGraphs,pos={57,350},size={48,15},proc=CheckProc_ListboxView,title="Graphs"
	CheckBox checkGraphs,value= 1,mode=1
	CheckBox checkTitles,pos={120,350},size={42,15},proc=CheckProc_ListboxView,title="Titles"
	CheckBox checkTitles,value= 0,mode=1
EndMacro

Function ButtonProc_AssignAll(ctrlName) : ButtonControl
	String ctrlName

	Execute "AssignGraphsToGroups_All()"
End

Function ButtonProc_AssignSelected(ctrlName) : ButtonControl
	String ctrlName

	 AssignGraphsToGroups()
End


Function ButtonProc_viewListOfGraphs(ctrlName) : ButtonControl
	String ctrlName

	showWindowNotes()
End

// Update list of graphs in listbox. Keep list of graph names and graph titles to create the option to show either one in graph list box.
Function ButtonProc_updateGrList(ctrlName) : ButtonControl
	String ctrlName

	wave/T grListWave = root:GraphGroupStuff:grListWave
	wave/T grTitleWave = root:GraphGroupStuff:grTitleWave
	wave grSelWave = root:GraphGroupStuff:grSelWave
	string wname, grList
	variable n, len = ItemsInList(winlist("*",";","win:1"))	//number of graphs
	
	grList = sortlist(winlist("*",";","WIN:1"),";",16)		// sort graphs into alpha numeric list
	Redimension/N=(len) grListWave, grTitleWave, grSelWave	// make  text waves of correct length
	grListWave =  stringfromlist(p,sortlist(winlist("*",";","WIN:1"),";",16))		// populate wave with each item in list for graph names
	for (n=0; n<len; n+=1)								// need to loop to get graph titles. Can't get them all in one line.
		wname = StringFromList(n, grList)
		GetWindow $wname wtitle	// get the graph title
		grTitleWave[n] = S_Value
	endfor
End

//assign selected graph to selected group. (Manually assign rather than looping through graphs).
Function ButtonProc_ManAssign(ctrlName) : ButtonControl
	String ctrlName

	variable len, n, numGroupsSelected
	string groupNameStr, graphNameStr
	wave/T graphListWave = root:GraphGroupStuff:grListWave			// list1 (graphs)
	wave grSelWave = root:GraphGroupStuff:grSelWave

	wave/T groupNamesWave = root:GraphGroupStuff:GraphGroup_names		// list0 (groups)
	wave sel = root:GraphGroupStuff:GraphGroup_selections
	
//	get name of selected group and make sure only 1 is selected. (For now can only assign a graph to one group.)
	len = numpnts(sel)
	for (n=0; n<len; n+=1)
		if (sel[n] ==1)
			numGroupsSelected +=1
			groupNameStr = groupNamesWave[n]
		endif
	endfor
	if (numGroupsSelected>1)
		Abort "Only select one Group to assign a graph to."
	endif

//	Get name of selected graph
	len = numpnts(grSelWave)
	for (n=0; n<len; n+=1)
		if (grSelWave[n] !=0)
			graphNameStr = graphListWave[n]
			if (cmpstr(groupNameStr, "_none_")!=0)
				SetWindow $graphNameStr note=groupNameStr
				Print "Assigning ",graphNameStr," to Group ", groupNameStr
			else
				SetWindow $graphNameStr note=""
				Print "Clearing Group for", graphNameStr
			endif
		endif
	endfor
End

// radio button that toggles view in listbox between graphs and graph titles.
Function CheckProc_ListboxView(ctrlName,checked) : CheckBoxControl
	String ctrlName
	Variable checked

	variable num, n
	string wlist, wname, wtitle
	
	ButtonProc_updateGrList("")
	if (cmpstr(ctrlName, "checkGraphs")==0)	// show graphs
		CheckBox checkTitles value=0

		ListBox list1,listWave=root:GraphGroupStuff:grListWave	// list of graph names
		ListBox list1,special= {1,0,1}								// magically converts names into images of graphs
	else																// show graph titles
		CheckBox checkGraphs value=0

		ListBox list1,listWave=root:GraphGroupStuff:grTitleWave	// show graph titles (not names)
		ListBox list1,special= {0,0,1}								// no graph images
	endif
End

// Bring selected graph to front if user double-clicks on it in listbox list1.
Function ListBoxProc(ctrlName,row,col,event) : ListBoxControl
	String ctrlName
	Variable row
	Variable col
	Variable event	//1=mouse down, 2=up, 3=dbl click, 4=cell select with mouse or keys
					//5=cell select with shift key, 6=begin edit, 7=end
	
	if (event==3)	//only trigger this if double-click
		wave/T grListWave = root:GraphGroupStuff:grListWave
		if (row<numpnts(grListWave))	// It's possible to click white space below last graph in listbox which isn't a real window. Produces index out of range error. So this prevents the problem.
			string grName = grListWave[row]
			DoWindow/F $grName
		endif
	endif
	return 0
End

// Try this as way to organize the graphs that are currently shown.
macro TileGraphs(numRows, numCols, winLeft, winTop, winRight, winBottom)
	variable numRows, numCols, winLeft=10, winTop=10, winRight=500, winBottom=500
	prompt numRows, "Number of rows (0=auto)"
	prompt numCols, "Number of columns (0=auto)"
	prompt winLeft, "Coordinates for left:"
	prompt winTop, "Coordinates for top:"
	prompt winRight, "Coordinates for right:"
	prompt winBottom, "Coordinates for bottom:"

//	PRINT numRows, numCols, winLeft, winTop, winRight, winBottom
	TileWindows /A=(numRows,numCols)/O=1/W=(winLeft, winTop, winRight, winBottom)
end

// Get list of graph recreation macros
function GetGraphMacros(selectedGroups)
	string selectedGroups
	
	variable num, n
	string graphMacroList, graphMacroName, groupName
	
	graphMacroList = MacroList("*", ";", "KIND:4,SUBTYPE:Graph,WIN:Procedure" )
//	print graphMacroList
	num = ItemsInList(graphMacroList)
	for(n=0; n<num; n+=1)
		graphMacroName = StringFromList(n, graphMacroList)
		groupName = SearchProcedureWindow(graphMacroName)
		if (strlen(groupName)>0)
			if (WhichListItem(groupName, selectedGroups)!=-1)	// if that graph note is in the list of Groups
				if (strlen(WinList(graphMacroName, ";", "WIN:1" ))==0)	// graph isn't in current list of graphs
					execute graphMacroName+"()"						// create the graph from the macro.
				endif
				DoWindow/F/HIDE=0 $graphMacroName				// show graph and bring to front
				
			else
				DoWindow/HIDE=1 $graphMacroName				// hide graph
			endif
		else
			Print graphMacroName," is unassigned"
		endif
	endfor
end

// Find graph notes of graph recreation macros
function/S SearchProcedureWindow(graphMacroName)
	string graphMacroName
	
	string procText, line, group="", procName
	variable pos, pos2
	
	procText = ProcedureText(graphMacroName, 0, "Procedure")
	pos = strsearch(procText, "SetWindow kwTopWin,note =", 0)
	if (pos!=-1)
		pos2 = strsearch(procText, "\r", pos)
		line = procText[pos, pos2]
		sscanf line, "SetWindow kwTopWin,note =\"%s", group
		group = RemoveEnding(group)
	endif
	return group
end